flake with packaging for ilia

flake.nix

@@ -0,0 +1,26 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    systems.url = "github:nix-systems/default";
+  };
+
+  outputs = { self, nixpkgs, systems }:
+    let
+      perSystem = callback: nixpkgs.lib.genAttrs (import systems) (system: callback (initPkgs system));
+      initPkgs = system: nixpkgs.legacyPackages.${system};
+    in
+    {
+      packages = perSystem (pkgs: rec {
+        # Run ilia in the project repo with:
+        #
+        #     $ nix run
+        #
+        # or run without cloning the repo with:
+        #
+        #     $ nix run github:regolith-linux/ilia
+        #
+        default = ilia;
+        ilia = pkgs.callPackage ./nix/ilia.nix { source = ./.; };
+      });
+    };
+}

nix/ilia.nix

@@ -0,0 +1,51 @@
+{ source # source must be given explicitly when calling callPackage
+
+  # callPackage automatically populates all of these arguments from nixpkgs
+, atk
+, cairo
+, gobject-introspection
+, gtk3
+, gtk-layer-shell
+, json-glib
+, lib
+, libgee
+, meson
+, ninja
+, pkg-config
+, stdenv
+, tinysparql
+, uncrustify
+, vala
+, wrapGAppsHook3
+}:
+
+stdenv.mkDerivation {
+  name = "ilia";
+  src = source;
+  postPatch = ''
+    patchShebangs meson_scripts
+  '';
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    uncrustify
+    vala
+    wrapGAppsHook3 # wraps the executable to register gsettings-schemas files
+  ];
+  buildInputs = [
+    atk
+    cairo
+    gobject-introspection # avoids error, "Package Gtk-3.0 not found in Vala API directories or Ggobject-introspection GIR directories"
+    gtk3
+    gtk-layer-shell
+    json-glib
+    libgee
+    tinysparql
+  ];
+  meta = {
+    homepage = "https://github.com/regolith-linux/ilia?tab=readme-ov-file";
+    license = [ lib.licenses.asl20 ];
+  };
+}
+