Test a different smearing fix

lib/plausible/stats/table_decider.ex

@@ -5,7 +5,9 @@ defmodule Plausible.Stats.TableDecider do
   """
 
   import Enum, only: [empty?: 1]
-  import Plausible.Stats.Filters, only: [dimensions_used_in_filters: 1]
+
+  import Plausible.Stats.Filters,
+    only: [dimensions_used_in_filters: 1, filtering_on_dimension?: 2]
 
   alias Plausible.Stats.{Query, QueryError}
 
@@ -134,7 +136,11 @@ defmodule Plausible.Stats.TableDecider do
   # :TRICKY: For time:minute dimension we prefer sessions over events as there
   # might be minutes where no events occurred but the session was active.
   defp metric_partitioner(query, metric) when metric in [:visitors, :visits] do
-    if "time:minute" in query.dimensions, do: :session, else: :either
+    if "time:minute" in query.dimensions and not filtering_on_dimension?(query, "event:goal") do
+      :session
+    else
+      :either
+    end
   end
 
   defp metric_partitioner(_, :conversion_rate), do: :either

test/plausible/stats/query/query_test.exs

@@ -317,4 +317,55 @@ defmodule Plausible.Stats.QueryTest do
              ]
     end
   end
+
+  describe "group_conversion_rate with time:minute and time:hour dimensions" do
+    test "unique conversions are not smeared when querying visitors without conversion_rate",
+         %{site: site} do
+      insert(:goal, site: site, event_name: "Signup")
+
+      populate_stats(site, [
+        build(:pageview, user_id: 1, timestamp: ~N[2021-01-01 00:00:00]),
+        build(:event, name: "Signup", user_id: 1, timestamp: ~N[2021-01-01 00:05:00]),
+        build(:pageview, user_id: 2, timestamp: ~N[2021-01-01 00:00:00])
+      ])
+
+      {:ok, query} =
+        QueryBuilder.build(site, %ParsedQueryParams{
+          metrics: [:visitors],
+          input_date_range: {:datetime_range, ~U[2021-01-01 00:00:00Z], ~U[2021-01-01 00:10:00Z]},
+          dimensions: ["time:minute"],
+          filters: [[:is, "event:goal", ["Signup"]]],
+          skip_goal_existence_check: true
+        })
+
+      %Stats.QueryResult{results: results} = Stats.query(site, query)
+
+      assert [%{dimensions: ["2021-01-01 00:05:00"], metrics: [1]}] = results
+    end
+
+    test "unique conversions are not smeared across all session minutes via timeSlots",
+         %{site: site} do
+      insert(:goal, site: site, event_name: "Signup")
+
+      populate_stats(site, [
+        build(:pageview, user_id: 1, timestamp: ~N[2021-01-01 00:00:00]),
+        build(:event, name: "Signup", user_id: 1, timestamp: ~N[2021-01-01 00:05:00]),
+        build(:pageview, user_id: 2, timestamp: ~N[2021-01-01 00:00:00]),
+        build(:pageview, user_id: 3, timestamp: ~N[2021-01-01 00:05:00])
+      ])
+
+      {:ok, query} =
+        QueryBuilder.build(site, %ParsedQueryParams{
+          metrics: [:visitors, :group_conversion_rate],
+          input_date_range: {:datetime_range, ~U[2021-01-01 00:00:00Z], ~U[2021-01-01 00:10:00Z]},
+          dimensions: ["time:minute"],
+          filters: [[:is, "event:goal", ["Signup"]]],
+          skip_goal_existence_check: true
+        })
+
+      %Stats.QueryResult{results: results} = Stats.query(site, query)
+
+      assert [%{dimensions: ["2021-01-01 00:05:00"], metrics: [1, 50.0]}] = results
+    end
+  end
 end