Add support for accessing some playercond info

Author: nosoop

gamedata/tf2.utils.nosoop.txt

@@ -2,6 +2,21 @@
 {
 	"tf"
 	{
+		"Addresses"
+		{
+			"&TF_COND_LAST"
+			{
+				"signature"		"CTFPlayerShared::RemoveAllCond()"
+				"linux"
+				{
+					"offset"	"37"
+				}
+				"windows"
+				{
+					"offset"	"147"
+				}
+			}
+		}
 		"Offsets"
 		{
 			// virtual offsets
@@ -57,6 +72,34 @@
 				"linux"		"3540"
 				"windows"	"3520"
 			}
+			"CTFPlayerShared::m_ConditionData"
+			{
+				"linux"		"8"
+				"windows"	"8"
+			}
+			"CTFPlayerShared::m_flBurnDuration"
+			{
+				// after unique xref to string "mult_wpn_burntime"
+				"linux"		"520"
+				"windows"	"520"
+			}
+			
+			"TFCondInfo_t::m_flDuration"
+			{
+				"linux"		"8"
+				"windows"	"8"
+			}
+			"TFCondInfo_t::m_hProvider"
+			{
+				"linux"		"12"
+				"windows"	"12"
+			}
+			
+			"sizeof(TFCondInfo_t)"
+			{
+				"linux"		"20"
+				"windows"	"20"
+			}
 		}
 		"Signatures"
 		{
@@ -88,6 +131,13 @@
 				"linux"			"@_ZN15CTFPlayerShared18GetMaxBuffedHealthEbb"
 				"windows"		"\x55\x8B\xEC\x83\xEC\x08\x56\x8B\xF1\x57\x8B\x8E\x2A\x01\x00\x00"
 			}
+			"CTFPlayerShared::RemoveAllCond()"
+			{
+				// first non-virtual call after semi-unique xref to "Player.Spawn"
+				"library"		"server"
+				"linux"			"@_ZN15CTFPlayerShared13RemoveAllCondEv"
+				"windows"		"\x55\x8B\xEC\x51\x53\x56\x57\x8B\xF9\x8D\x8F\xE0\x00\x00\x00"
+			}
 			"PointInRespawnRoom()"
 			{
 				"library"		"server"

scripting/include/tf2utils.inc

@@ -48,6 +48,59 @@ native int TF2Util_GetPlayerMaxAmmo(int client, int iAmmoIndex,
 native int TF2Util_GetPlayerMaxHealth(int client, bool bIgnoreAttributes = false,
 		bool bIgnoreOverheal = false);
 
+/**
+ * Returns the number of conditions currently available in the game.  This value will be one
+ * higher than the last valid condition.
+ */
+native int TF2Util_GetConditionCount();
+
+/**
+ * Returns the remaining time on a player condition, or 0.0 if the condition is not active.
+ * 
+ * This is just a wrapper around the internal condition list; some conditions may not accurately
+ * report their duration here (such as burning).
+ */
+native float TF2Util_GetPlayerConditionDuration(int client, TFCond cond);
+
+/**
+ * Sets the remaining time on a player condition without reapplying the condition.
+ * 
+ * @error Condition is not active.
+ */
+native void TF2Util_SetPlayerConditionDuration(int client, TFCond cond, float duration);
+
+/**
+ * Returns the entity providing a player condition, or INVALID_ENT_REFERENCE if the condition is
+ * not active.  0 is returned for "no inflictor".
+ * 
+ * (This is the entity described as the "inflictor" for `TF2_AddCondition`.)
+ */
+native int TF2Util_GetPlayerConditionProvider(int client, TFCond cond);
+
+/**
+ * Sets the entity providing a player condition without reapplying the condition.
+ * 
+ * (This is the entity described as the "inflictor" for `TF2_AddCondition`.)
+ * 
+ * @error Condition is not active.
+ */
+native void TF2Util_SetPlayerConditionProvider(int client, TFCond cond, int inflictor);
+
+/**
+ * Returns the remaining burn time on a given player.  By default this decreases at a fixed rate
+ * over time; the rate may change based on fire resistances (such as while cloaked).
+ * 
+ * If the player is not burning, 0.0 is returned.
+ */
+native float TF2Util_GetPlayerBurnDuration(int client);
+
+/**
+ * Updates the remaining burn time on a given player.  This does not ignite players.
+ * 
+ * @error Player is not already burning.
+ */
+native void TF2Util_SetPlayerBurnDuration(int client, float duration);
+
 /**
  * Returns the player's shoot position.
  */

scripting/tf2utils.sp

@@ -7,11 +7,11 @@
 #pragma newdecls required
 
 #include <sdkhooks>
-#include <sdktools>
+#include <tf2_stocks>
 
 #include <stocksoup/memory>
 
-#define PLUGIN_VERSION "0.11.0"
+#define PLUGIN_VERSION "0.12.0"
 public Plugin myinfo = {
 	name = "TF2 Utils",
 	author = "nosoop",
@@ -42,6 +42,16 @@ Handle g_SDKCallPointInRespawnRoom;
 
 Address offs_CTFPlayer_hMyWearables;
 
+Address offs_CTFPlayerShared_flBurnDuration;
+Address offs_CTFPlayerShared_ConditionData;
+
+Address offs_TFCondInfo_flDuration;
+Address offs_TFCondInfo_hProvider;
+
+int sizeof_TFCondInfo;
+
+int g_nConditions;
+
 public APLRes AskPluginLoad2(Handle self, bool late, char[] error, int maxlen) {
 	RegPluginLibrary("nosoop_tf2utils");
 
@@ -50,6 +60,14 @@ public APLRes AskPluginLoad2(Handle self, bool late, char[] error, int maxlen) {
 	CreateNative("TF2Util_GetPlayerMaxHealth", Native_GetMaxHealth);
 	CreateNative("TF2Util_GetPlayerMaxAmmo", Native_GetMaxAmmo);
 
+	CreateNative("TF2Util_GetPlayerConditionCount", Native_GetPlayerConditionCount);
+	CreateNative("TF2Util_GetPlayerConditionDuration", Native_GetPlayerConditionDuration);
+	CreateNative("TF2Util_SetPlayerConditionDuration", Native_SetPlayerConditionDuration);
+	CreateNative("TF2Util_GetPlayerConditionProvider", Native_GetPlayerConditionProvider);
+	CreateNative("TF2Util_SetPlayerConditionProvider", Native_SetPlayerConditionProvider);
+	CreateNative("TF2Util_GetPlayerBurnDuration", Native_GetPlayerBurnDuration);
+	CreateNative("TF2Util_SetPlayerBurnDuration", Native_SetPlayerBurnDuration);
+	
 	CreateNative("TF2Util_IsEntityWearable", Native_IsEntityWearable);
 	CreateNative("TF2Util_GetPlayerWearable", Native_GetPlayerWearable);
 	CreateNative("TF2Util_GetPlayerWearableCount", Native_GetPlayerWearableCount);
@@ -161,6 +179,38 @@ public void OnPluginStart() {
 				"CTFPlayer::m_hMyWearables");
 	}
 
+	// TODO: use FindSendPropInfo("CTFPlayer", "m_ConditionData")
+	if (offs_CTFPlayerShared_ConditionData <= Address_Null) {
+		offs_CTFPlayerShared_ConditionData = GameConfGetAddressOffset(hGameConf,
+				"CTFPlayerShared::m_ConditionData");
+	}
+	
+	offs_CTFPlayerShared_flBurnDuration = GameConfGetAddressOffset(hGameConf,
+			"CTFPlayerShared::m_flBurnDuration");
+	
+	sizeof_TFCondInfo = GameConfGetOffset(hGameConf, "sizeof(TFCondInfo_t)");
+	
+	offs_TFCondInfo_flDuration = GameConfGetAddressOffset(hGameConf,
+			"TFCondInfo_t::m_flDuration");
+	
+	offs_TFCondInfo_hProvider = GameConfGetAddressOffset(hGameConf,
+			"TFCondInfo_t::m_hProvider");
+	
+	Address pNumConds = GameConfGetAddress(hGameConf, "&TF_COND_LAST");
+	if (!pNumConds) {
+		LogError("Could not determine location to read TF_COND_LAST from.  "
+				... "Condition bounds checking will produce false positives and condition "
+				... "count native will report incorrect values.");
+		g_nConditions = 0xFF;
+	} else if (!(g_nConditions = LoadFromAddress(pNumConds, NumberType_Int32))
+			|| g_nConditions != g_nConditions & 0xFF) {
+		// we expect the value to be within [1, 255]; if it isn't, then our address is invalid
+		LogError("TF_COND_LAST is not within expected bounds (found %08x).  "
+				... "Condition bounds checking will produce false positives and condition "
+				... "count native will report incorrect values.", g_nConditions);
+		g_nConditions = 0xFF;
+	}
+	
 	delete hGameConf;
 }
 
@@ -374,6 +424,99 @@ int Native_GetPlayerLoadoutEntity(Handle plugin, int numParams) {
 	return SDKCall(g_SDKCallPlayerGetEntityForLoadoutSlot, client, loadoutSlot, check_wearable);
 }
 
+// int();
+int Native_GetPlayerConditionCount(Handle plugin, int numParams) {
+	return g_nConditions;
+}
+
+// float(int client, TFCond cond);
+any Native_GetPlayerConditionDuration(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	TFCond cond = GetNativeCell(2);
+	
+	if (!IsConditionValid(cond)) {
+		return ThrowNativeError(SP_ERROR_NATIVE, "Condition index %d is invalid", cond);
+	} else if (!TF2_IsPlayerInCondition(client, cond)) {
+		return 0.0;
+	}
+	
+	Address pData = GetConditionData(client, cond);
+	return LoadFromAddress(pData + offs_TFCondInfo_flDuration, NumberType_Int32);
+}
+
+// void(int client, TFCond cond, float duration);
+any Native_SetPlayerConditionDuration(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	TFCond cond = GetNativeCell(2);
+	float duration = GetNativeCell(3);
+	
+	if (!IsConditionValid(cond)) {
+		ThrowNativeError(SP_ERROR_NATIVE, "Condition index %d is invalid", cond);
+	} else if (!TF2_IsPlayerInCondition(client, cond)) {
+		ThrowNativeError(SP_ERROR_NATIVE, "Player is not in condition %d", cond);
+	}
+	
+	Address pData = GetConditionData(client, cond);
+	StoreToAddress(pData + offs_TFCondInfo_flDuration, view_as<any>(duration),
+			NumberType_Int32);
+}
+
+// int(int client, TFCond cond);
+any Native_GetPlayerConditionProvider(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	TFCond cond = GetNativeCell(2);
+	
+	if (!IsConditionValid(cond)) {
+		return ThrowNativeError(SP_ERROR_NATIVE, "Condition index %d is invalid", cond);
+	} else if (!TF2_IsPlayerInCondition(client, cond)) {
+		return INVALID_ENT_REFERENCE;
+	}
+	
+	Address pData = GetConditionData(client, cond);
+	return LoadEntityHandleFromAddress(pData + offs_TFCondInfo_hProvider);
+}
+
+// void(int client, TFCond cond, int provider);
+any Native_SetPlayerConditionProvider(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	TFCond cond = GetNativeCell(2);
+	int provider = GetNativeCell(3);
+	
+	if (!IsConditionValid(cond)) {
+		ThrowNativeError(SP_ERROR_NATIVE, "Condition index %d is invalid", cond);
+	} else if (!TF2_IsPlayerInCondition(client, cond)) {
+		ThrowNativeError(SP_ERROR_NATIVE, "Player is not in condition %d", cond);
+	} else if (!IsValidEntity(provider)) {
+		ThrowNativeError(SP_ERROR_NATIVE, "Entity %d is invalid", provider);
+	}
+	
+	Address pData = GetConditionData(client, cond);
+	StoreEntityHandleToAddress(pData + offs_TFCondInfo_hProvider, provider);
+}
+
+// float(int client);
+any Native_GetPlayerBurnDuration(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	if (!TF2_IsPlayerInCondition(client, TFCond_OnFire)) {
+		return 0.0;
+	}
+	int pOffsSharedBurnDuration = FindSendPropInfo("CTFPlayer", "m_Shared")
+			+ view_as<int>(offs_CTFPlayerShared_flBurnDuration);
+	return GetEntDataFloat(client, pOffsSharedBurnDuration);
+}
+
+// void(int client, float duration);
+any Native_SetPlayerBurnDuration(Handle plugin, int numParams) {
+	int client = GetNativeCell(1);
+	float duration = GetNativeCell(2);
+	if (!TF2_IsPlayerInCondition(client, TFCond_OnFire)) {
+		return;
+	}
+	int pOffsSharedBurnDuration = FindSendPropInfo("CTFPlayer", "m_Shared")
+			+ view_as<int>(offs_CTFPlayerShared_flBurnDuration);
+	SetEntDataFloat(client, pOffsSharedBurnDuration, duration);
+}
+
 bool IsEntityWeapon(int entity) {
 	if (!IsValidEntity(entity)) {
 		ThrowNativeError(SP_ERROR_NATIVE, "Entity %d (%d) is invalid", entity,
@@ -390,6 +533,17 @@ bool IsEntityWearable(int entity) {
 	return SDKCall(g_SDKCallIsEntityWearable, entity);
 }
 
+static Address GetConditionData(int client, TFCond cond) {
+	Address pCondMemory = DereferencePointer(GetEntityAddress(client)
+			+ view_as<Address>(FindSendPropInfo("CTFPlayer", "m_Shared"))
+			+ offs_CTFPlayerShared_ConditionData);
+	return pCondMemory + view_as<Address>(view_as<int>(cond) * sizeof_TFCondInfo);
+}
+
+static bool IsConditionValid(TFCond cond) {
+	return 0 <= view_as<any>(cond) < g_nConditions;
+}
+
 static Address GameConfGetAddressOffset(Handle gamedata, const char[] key) {
 	Address offs = view_as<Address>(GameConfGetOffset(gamedata, key));
 	if (offs == view_as<Address>(-1)) {