Add nix flake for building extension

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -3,3 +3,5 @@ dist
 node_modules
 .vscode-test/
 *.vsix
+.direnv/
+result/

README.md

@@ -81,6 +81,18 @@ Allows user to specify the denied commands using glob syntax, eg:
 
 Defaults to `[]` (doesn't deny anything).
 
+## Building
+
+### Nix
+
+The extension can be built using the `flake.nix` file using the following command:
+
+```bash
+nix build
+```
+
+The resulting `.vsix` file will be placed in the `result/` folder.
+
 ## Troubleshooting
 
 ## Known issues

flake.nix

@@ -0,0 +1,60 @@
+{
+  description = "A Nix-flake-based development environment for command-server";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+  outputs = { self, nixpkgs }:
+    let
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+      forEachSupportedSystem = f: nixpkgs.lib.genAttrs supportedSystems (system: f {
+        pkgs = import nixpkgs { inherit system; };
+      });
+    in
+    {
+      packages = forEachSupportedSystem
+        ({ pkgs, ... }:
+          let
+            attrs = with builtins; fromJSON (readFile ./package.json);
+            name = attrs.name;
+            version = attrs.version;
+          in
+          {
+            default = pkgs.mkYarnPackage {
+              pname = "${name}-${version}";
+              src = ./.;
+
+              buildPhase = ''
+                # yarn tries to create a .yarn file in $HOME. There's probably a
+                # better way to fix this but setting HOME to cwd works for now.
+                export HOME="."
+                yarn --offline run compile
+                # non-existent symlink errors during packaging
+                rm ./deps/command-server/command-server
+                # need node_modules for vsce, so don't use symlink
+                rm ./deps/command-server/node_modules
+                cp -R ./node_modules ./deps/command-server
+                pushd ./deps/command-server
+                echo y | yarn --offline vsce package --yarn -o ./$pname.vsix
+                popd
+              '';
+
+              installPhase = ''
+                mkdir $out
+                mv ./deps/command-server/$pname.vsix $out;
+              '';
+
+              distPhase = "true";
+
+            };
+          });
+
+      devShells = forEachSupportedSystem
+        ({ pkgs }: {
+          default = pkgs.mkShell
+            {
+              packages = with pkgs;
+                [ yarn typescript ];
+            };
+        });
+    };
+}

package.json

@@ -129,6 +129,7 @@
     "glob": "^7.1.6",
     "mocha": "^8.1.3",
     "typescript": "^4.1.2",
+    "vsce": "^2.15.0",
     "vscode-test": "^1.4.1"
   },
   "dependencies": {