build.gradle.kts

buildscript {
  repositories {
    google()
    mavenCentral()
    maven { url = uri("https://plugins.gradle.org/m2/") }
  }

  // TODO migrate these as well
  dependencies {
    classpath("com.android.tools.build:gradle:8.2.0")
    classpath("com.google.gms:google-services:4.4.0")
    classpath("de.mannodermaus.gradle.plugins:android-junit5:1.8.2.1")
  }
}

plugins {
  // TODO migrate these as well
  id("com.diffplug.spotless") version "6.23.3"
  kotlin("android") version libs.versions.kotlin apply false
  kotlin("plugin.serialization") version libs.versions.kotlin apply false
  kotlin("multiplatform").version(libs.versions.kotlin) apply false
  kotlin("jvm") version libs.versions.kotlin apply false
  id("org.jetbrains.kotlinx.kover") version "0.7.0-Beta"
  id("org.jetbrains.compose").version(libs.versions.jetbrains.compose) apply false
}

allprojects {
  repositories {
    google()
    mavenCentral()
  }
}

spotless {
  kotlin {
    target("build.gradle.kts")
    ktfmt()
    lineEndings = com.diffplug.spotless.LineEnding.UNIX
  }
}

/** Applies spotless to app projects */
subprojects {
  apply(plugin = "com.diffplug.spotless")
  spotless {
    kotlin {
      target("build.gradle.kts", "**/*.kt")
      ktfmt()
      lineEndings = com.diffplug.spotless.LineEnding.UNIX
    }
  }
}

dependencies { kover(project(":domain")) }