update shout

Author: ytlm

erlang/shout/id3_tag_lengths.erl

@@ -0,0 +1,78 @@
+-module(id3_tag_lengths).
+
+-compile(export_all).
+
+-import(lists, [foreach/2, map/2]).
+
+test() ->
+    Files = lib_files_find:files(".", "*.mp3", true),
+    map(fun(F) -> file(F) end, Files).
+
+file(F) ->
+    (catch read_id3_tag(F)).
+
+read_id3_tag(File) ->
+    case file:open(File, [read, binary, raw]) of
+        {ok, S} ->
+            Size = filelib:file_size(File),
+            Result = analyse(S, Size),
+            file:close(S),
+            Result;
+        _Error ->
+            error
+    end.
+
+analyse(S, Size) ->
+    case (catch analyse1(S, Size)) of
+        {'EXIT', _Why} ->
+            io:format("_Why = ~p~n", [_Why]),
+            error;
+        StartStop ->
+            StartStop
+    end.
+
+analyse1(S, Size) ->
+    {ok, Bin} = file:pread(S, 0, 10000),
+    {ok, StartTrust} = mp3_sync:find_sync(Bin, 1),
+    {Type, StartUntrust} = parse_start_tag(Bin),
+    Stop = parse_end_tag(S, Size),
+    if
+        StartTrust == StartUntrust ->
+            true;
+        true ->
+            io:format("** error in header code: real=~p, type=~p, val=~p~n",
+                      [StartTrust, Type, StartUntrust])
+    end,
+    {StartTrust, Stop}.
+
+parse_start_tag(<<$I, $D, $3, 3, 0, _Unsync:1, _Extended:1, _:5, K:32, _/binary>>) ->
+    Tag = "ID3v2.3.0",
+    Size = syncsafe2int(K),
+    {Tag, Size + 10};
+parse_start_tag(<<$I, $D, $3, 4, 0, _Unsync:1, _Extended:1, Footer:1,
+                  _:4, K:32, _/binary>>) ->
+    Tag = "ID3v2.3.0",
+    Size = syncsafe2int(K),
+    Size1 = case Footer of
+                1 -> 10 + Size;
+                0 -> Size
+            end,
+    {Tag, Size1};
+parse_start_tag(<<X:10/binary,_/binary>>) ->
+    io:format("strange start tag~p~n",[X]),
+    {error, 1}.
+
+parse_end_tag(S, Size) ->
+    {ok, B2} = file:pread(S, Size-128, 128),
+    parse_v1_tag(B2, Size).
+
+parse_v1_tag(<<$T,$A,$G,_/binary>>, Size) ->
+    Size - 128;
+parse_v1_tag(_, Size) ->
+    Size.
+
+syncsafe2int(N) ->
+    <<_:1,N1:7,_:1,N2:7,_:1,N3:7,_:1,N4:7>> = <<N:32>>,
+    <<I:32>> = <<0:4,N1:7,N2:7,N3:7,N4:7>>,
+    I.
+

erlang/shout/mp3_sync.erl

@@ -0,0 +1,98 @@
+-module(mp3_sync).
+
+-export([find_sync/2]).
+
+find_sync(Bin, N) ->
+    case is_header(N, Bin) of
+	{ok, Len1, _} ->
+	    case is_header(N + Len1, Bin) of
+		{ok, Len2, _} ->
+		    case is_header(N + Len1 + Len2, Bin) of
+			{ok, _, _} ->
+			    {ok, N};
+			error ->
+			    find_sync(Bin, N+1)
+		    end;
+		error ->
+		    find_sync(Bin, N+1)
+	    end;
+	error ->
+	    find_sync(Bin, N+1)
+    end.
+
+
+is_header(N, Bin) ->
+    unpack_header(get_word(N, Bin)).
+
+get_word(N, Bin) ->
+    {_,<<C:4/binary,_/binary>>} = split_binary(Bin, N),
+    C.
+
+unpack_header(X) ->
+    try decode_header(X)
+    catch
+	_:_ -> error
+    end.
+
+decode_header(<<2#11111111111:11,B:2,C:2,_D:1,E:4,F:2,G:1,Bits:9>>) ->
+    Vsn = case B of
+	      0 -> {2,5};
+	      1 -> exit(badVsn);
+	      2 -> 2;
+	      3 -> 1
+	  end,
+    Layer = case C of
+		0 -> exit(badLayer);
+		1 -> 3;
+		2 -> 2;
+		3 -> 1
+	    end,
+    %% Protection = D,
+    BitRate = bitrate(Vsn, Layer, E) * 1000,
+    SampleRate = samplerate(Vsn, F),
+    Padding = G,
+    FrameLength = framelength(Layer, BitRate, SampleRate, Padding),
+    if
+	FrameLength < 21 ->
+	    exit(frameSize);
+	true ->
+	    {ok, FrameLength, {Layer,BitRate,SampleRate,Vsn,Bits}}
+    end;
+decode_header(_) ->
+    exit(badHeader).
+
+
+bitrate(_,_,15) -> exit(1);
+bitrate(1,1,E) ->
+    element(E+1, {free,32,64,96,128,160,192,224,256,288,
+		  320,352,384,416,448});
+bitrate(1,2,E) ->
+    element(E+1, {free,32,48,56,64,80,96,112,128,160,
+		  192,224,256,320,384});
+bitrate(1,3,E) ->
+    element(E+1, {free,32,40,48,56,64,80,96,112,128,160,192,
+		  224,256,320});
+bitrate(2,1,E) ->
+    element(E+1, {free,32,48,56,64,80,96,112,128,144,160,
+		  176,192,224,256});
+bitrate(2,2,E) ->
+    element(E+1, {free,8,16,24,32,40,48,56,64,80,96,112,
+		  128,144,160});
+bitrate(2,3,E) -> bitrate(2,2,E);
+bitrate({2,5}, L, E) -> bitrate(2, L, E).
+
+%% samplerate Vsn F
+samplerate(1, 0) -> 44100;
+samplerate(1, 1) -> 48000;
+samplerate(1, 2) -> 32000;
+samplerate(2, 0) -> 22050;
+samplerate(2, 1) -> 24000;
+samplerate(2, 2) -> 16000;
+samplerate({2,5}, 0) -> 11025;
+samplerate({2,5}, 1) -> 12000;
+samplerate({2,5}, 2) -> 8000.
+
+framelength(1, BitRate, SampleRate, Padding) ->
+    ((12*BitRate div SampleRate) + Padding) * 4;
+framelength(_, BitRate, SampleRate, Padding) ->
+    (144 * BitRate div SampleRate) + Padding.