blueman: use arch PKGBUILD

Author: Kirek

blueman/PKGBUILD

@@ -1,41 +1,49 @@
-# Maintainer: Ramon Buldó <rbuldo at gmail.com>
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributer: Arthur Zamarin <[email protected]>
+# Contributer: Martin Wimpress <[email protected]>
 
 pkgname=blueman
 pkgver=2.0.1
 _pkgver=2.0
-pkgrel=2
-pkgdesc="A GTK+ Bluetooth Manager (BlueZ 5)"
+pkgrel=3
+pkgdesc="GTK+ Bluetooth Manager"
 arch=('i686' 'x86_64')
-license=('GPL')
 url="https://github.com/blueman-project/blueman"
-depends=('bluez' 'bluez-libs' 'dbus-glib' 'gconf' 'gdk-pixbuf2' 'glib2' 
-         'gtk3' 'notification-daemon' 'libnotify' 'polkit' 'pango' 
-         'python-cairo' 'python-dbus' 'python-gobject' 'python-pybluez')
-optdepends=('dnsmasq: DHCP server for Network Access Point'
-            'pulseaudio: for some audio support')
-makedepends=('cython' 'intltool' 'libtool')
-conflicts=('blueman-git' 'blueman-bzr')
-source=("https://github.com/blueman-project/${pkgname}/releases/download/${_pkgver}/${pkgname}-${_pkgver}.tar.xz")
-sha256sums=('81a5ca95124f12bfb62d2d2d0d265af70cdae1d43b0c6e4fc6d2bad8f82958f1')
-install=${pkgname}.install
+license=('GPL')
+depends=('bluez' 'bluez-libs' 'gtk3' 'libnotify' 'python-cairo' 'python-dbus' 'python-gobject')
+makedepends=('cython' 'intltool')
+optdepends=('dnsmasq: Network Access Point (NAP) support'
+            'networkmanager: Dial Up Networking (DUN) and Personal Area Networking (PAN) support'
+            'pulseaudio-bluetooth: audio devices support')
+install=$pkgname.install
+source=($pkgname-$_pkgver.tar.gz::https://github.com/blueman-project/$pkgname/archive/$_pkgver.tar.gz)
+sha256sums=('3f6dc827c4410f128f75a15672af8dc76c5c041f6d639d5ab19b15abeb42ff74')
 
 prepare() {
-    cd "${srcdir}/${pkgname}-${_pkgver}"
-    NOCONFIGURE=1 ./autogen.sh
+  cd $pkgname-$_pkgver
+
+  # Fix path for bluetoothd
+  sed -i 's|/usr/sbin/bluetoothd|/usr/lib/bluetooth/bluetoothd|' apps/blueman-report
+
+  # Fix non-standard icon names
+  sed -i 's/gtk-find/edit-find/' data/ui/device-list-widget.ui
+  sed -i 's/mouse/input-mouse/' blueman/services/Input.py
+
+  NOCONFIGURE=1 ./autogen.sh
 }
 
 build() {
-    cd "${srcdir}/${pkgname}-${_pkgver}"
-    ./configure \
-        --prefix=/usr \
-        --sysconfdir=/etc \
-        --libexecdir=/usr/lib/${pkgname} \
-        --disable-static \
-        --disable-schemas-compile
-    make
+  cd $pkgname-$_pkgver
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-schemas-compile
+  make
 }
 
 package() {
-    cd "${srcdir}/${pkgname}-${_pkgver}"
-    make DESTDIR="${pkgdir}" install
+  cd $pkgname-$_pkgver
+  make DESTDIR="$pkgdir" install
 }

blueman/blueman.install

@@ -1,12 +1,12 @@
 post_install() {
-    gtk-update-icon-cache -q -t -f /usr/share/icons/hicolor
-    glib-compile-schemas /usr/share/glib-2.0/schemas
+  glib-compile-schemas usr/share/glib-2.0/schemas
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
 }
 
 post_upgrade() {
-    post_install
+  post_install
 }
 
 post_remove() {
-    post_install
+  post_install
 }