How to resolve a symlinked file in extra-source-files

[johnhampton]

I'm trying to override the haskell-effectfu/effectful packages with latest commits from GitHub. I'm getting an error that the README.md file is not found when building the source dist. The README in the effectful-core directory is a symlink to the README.md in the project root.

Any suggestions on how to resolve this?

Thanks!

flake.nix

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    
    flake-parts.url = "github:hercules-ci/flake-parts";
    haskell-flake.url = "github:srid/haskell-flake";
    systems.url = "github:nix-systems/default";

    effectful = {
      url = "github:haskell-effectful/effectful";
      flake = false;
    };
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = import inputs.systems;
      imports = [ inputs.haskell-flake.flakeModule];
      perSystem = { self', inputs', pkgs, config, ... }: {
        checks = self'.packages;

        haskellProjects.default = {
          defaults.settings.default = { haddock = true; };
          packages = {
            effectful-core.source = "${inputs.effectful}/effectful-core";
            effectful.source = "${inputs.effectful}/effectful";
          };
          # Project settings here
        };
      };
    }
  ;
}

Error

error: builder for '/nix/store/yfidlxqg253nf8g9gaihlzxz5kshaawa-effectful-core-source-2.3.1.0.drv' failed with exit code 1;
       last 10 log lines:
       > /nix/store/ivklia9w69144iys517bvbc0d8paj2ai-gnutar-1.35/bin/tar
       > No uhc found
       > Running phase: buildPhase
       > Distribution quality warnings:
       > 'ghc-options: -O2' is rarely needed. Check that it is giving a real benefit
       > and not just imposing longer compile times on your users.
       > In 'extra-source-files': the pattern 'README.md' does not match any files.
       > Building source dist for effectful-core-2.3.1.0...
       > Error: Setup: filepath wildcard 'README.md' does not match any files.
       >
       For full logs, run 'nix log /nix/store/yfidlxqg253nf8g9gaihlzxz5kshaawa-effectful-core-source-2.3.1.0.drv'.
error: 1 dependencies of derivation '/nix/store/419k639sgrbwj61zl88jl79cfk2zk1wr-effectful-core-2.3.1.0.drv' failed to build
error: 1 dependencies of derivation '/nix/store/wialmipqpgzv9gwbzj3ic3xzddcbklxx-ghc-9.4.8-with-packages.drv' failed to build
error: 1 dependencies of derivation '/nix/store/d623apdpcs7nfg2w0lipzfnxnhfdlr3s-ghc-shell-for-effectful-errors-0.1.0.0-0-env.drv' failed to build

[srid]

You can build packages.<name>.source path yourself, by copying the symlinks.

cf. https://github.com/kowainik/summoner/pull/335/files#diff-245563af9e34754739b12b294f3324c1d42c116ace7ce8735e21dfbc82d8e064R19-R26

[johnhampton]

Thanks,

I ended with this:

        haskellProjects.default = let 
          srcDrv = pkgs.stdenv.mkDerivation {
            name = "effectful-src";
            src = inputs.effectful;
            installPhase = ''
              mkdir -p $out
              cp -r . $out/
              cp --remove-destination $out/README.md $out/effectful/README.md
              cp --remove-destination $out/README.md $out/effectful-core/README.md
              cp --remove-destination $out/README.md $out/effectful-th/README.md
            '';
          };

        in {
          defaults.settings.default = { haddock = true; };
          packages = {
            effectful-core.source = "${srcDrv}/effectful-core";
            effectful.source = "${srcDrv}/effectful";
            effectful-th.source = "${srcDrv}/effectful-th";
            effectful-plugin.source = "${srcDrv}/effectful-plugin";
          };
        };