programs/yazi: add more config options

Author: HigherOrderLogic

modules/collection/programs/yazi.nix

@@ -4,8 +4,12 @@
   pkgs,
   ...
 }: let
+  inherit (builtins) isPath;
+
   inherit (lib.modules) mkIf;
-  inherit (lib.options) mkOption mkEnableOption mkPackageOption;
+  inherit (lib.attrsets) mapAttrs' nameValuePair;
+  inherit (lib.options) mkOption mkEnableOption mkPackageOption literalExpression;
+  inherit (lib.types) attrsOf nullOr either path lines package;
 
   toml = pkgs.formats.toml {};
 
@@ -68,21 +72,72 @@ in {
         [yazi's theming configuration documentation]: https://yazi-rs.github.io/docs/configuration/theme
       '';
     };
+
+    initLua = mkOption {
+      type = nullOr (either lines path);
+      default = null;
+      example = literalExpression "./init.lua";
+      description = ''
+        The init.lua file for Yazi.
+      '';
+    };
+
+    plugins = mkOption {
+      type = attrsOf (either path package);
+      default = {};
+      example = literalExpression ''
+        {
+          foo = ./foo;
+          git = pkgs.yaziPlugins.git;
+        };
+      '';
+      description = ''
+        A list of plugins for Yazi, which would be placed in the {file}`$XDG_CONFIG_HOME/yazi/plugins/` folder.
+        Please reference [yazi's plugins documentation] to get a better understanding of plugins.
+
+        [yazi's plugins documentation]: https://yazi-rs.github.io/docs/plugins/overview/
+      '';
+    };
+
+    flavors = mkOption {
+      type = attrsOf (either path package);
+      default = {};
+      example = literalExpression ''
+        {
+          foo = ./foo;
+          git = fetchFromGitHub { ... };
+        };
+      '';
+      description = ''
+        A list of "flavors", or pre-made themes for Yazi, which would be placed in the {file}`$XDG_CONFIG_HOME/yazi/flavors` folder.
+        Please reference [yazi's flavors documentation] to get a better understanding of flavors.
+
+        [yazi's flavors documentation]: https://yazi-rs.github.io/docs/flavors/overview
+      '';
+    };
   };
 
   config = mkIf cfg.enable {
     packages = mkIf (cfg.package != null) [cfg.package];
 
-    xdg.config.files = {
-      "yazi/yazi.toml".source = mkIf (cfg.settings != {}) (
-        toml.generate "yazi-config.toml" cfg.settings
-      );
-      "yazi/keymap.toml".source = mkIf (cfg.keymap != {}) (
-        toml.generate "yazi-keymap-config.toml" cfg.keymap
-      );
-      "yazi/theme.toml".source = mkIf (cfg.theme != {}) (
-        toml.generate "yazi-theme-config.toml" cfg.theme
-      );
-    };
+    xdg.config.files =
+      {
+        "yazi/yazi.toml".source = mkIf (cfg.settings != {}) (
+          toml.generate "yazi-config.toml" cfg.settings
+        );
+        "yazi/keymap.toml".source = mkIf (cfg.keymap != {}) (
+          toml.generate "yazi-keymap-config.toml" cfg.keymap
+        );
+        "yazi/theme.toml".source = mkIf (cfg.theme != {}) (
+          toml.generate "yazi-theme-config.toml" cfg.theme
+        );
+        "yazi/init.lua" = mkIf (cfg.initLua != null) (
+          if isPath cfg.initLua
+          then {source = cfg.initLua;}
+          else {text = cfg.initLua;}
+        );
+      }
+      // (mapAttrs' (name: plugin: nameValuePair "yazi/plugins/${name}.yazi" {source = plugin;}) cfg.plugins)
+      // (mapAttrs' (name: flavor: nameValuePair "yazi/flavors/${name}.yazi" {source = flavor;}) cfg.flavors);
   };
 }

modules/tests/collection/programs/yazi.nix

@@ -24,6 +24,7 @@
             light = "gruvbox";
           };
         };
+        plugins = {inherit (pkgs.yaziPlugins) git;};
       };
     };
   };
@@ -39,11 +40,13 @@
       yaziConfPath = confDir + "/yazi.toml"
       keymapConfPath = confDir + "/keymap.toml"
       themeConfPath = confDir + "/theme.toml"
+      pluginsDir = confDir + "/plugins/"
 
       # Checks if the yazi config files exists in the expected place.
       machine.succeed("[ -r %s ]" % yaziConfPath)
       machine.succeed("[ -r %s ]" % keymapConfPath)
       machine.succeed("[ -r %s ]" % themeConfPath)
+      machine.succeed("[ -d %s ]" % pluginsDir)
 
       # Checks if the yazi config files are valid
       machine.succeed("su bob -c 'taplo check --schema https://yazi-rs.github.io/schemas/yazi.json %s'" % yaziConfPath)