configure.in

dnl Process this file with autoconf to produce a configure script.
AC_REVISION($Revision $)
AC_INIT
AC_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_CHECK_TOOL(AR, ar, [#])
AC_CHECK_TOOL(RANLIB, ranlib, [#])

DC_PROG_GCC

dnl Check for largefile support
AC_SYS_LARGEFILE
AC_FUNC_FSEEKO
AC_TYPE_OFF_T

dnl Check host OS info.
DC_CHK_OS_INFO

dnl Determine how to make shared objects
DC_GET_SHOBJFLAGS

dnl Checks for libraries.
DC_CHK_DLOPEN
DC_CHK_MODULE(z, comp_zlib.c comp_mzlib.c comp_mzlib2.c, HAVE_LIBZ)
DC_CHK_MODULE(bz2, comp_bzlib.c, HAVE_LIBBZ2)
DC_CHK_MODULE(mcrypt, cipher_serpent.c, HAVE_LIBMCRYPT)
DC_CHK_MODULE_VAR(lzo, comp_lzoox.c comp_lzooy.c comp_lzota.c, HAVE_LIBLZO, MODLIBSCOND)

DC_ASK_CHKVERS
DC_ASK_NETWORK
DC_ASK_DEBUG
DC_ASK_MODULE
DC_ASK_DEBIAN
DC_CHK_URANDOM

dnl Checks for header files.
AC_CHECK_HEADERS(zlib.h getopt.h stdio.h strings.h string.h unistd.h stdint.h inttypes.h bzlib.h sys/time.h sys/utsname.h sys/socket.h sys/wait.h lzoconf.h lzo1x.h lzo1y.h lzo2a.h dirent.h mcrypt.h dlfcn.h stdarg.h netinet/in.h arpa/inet.h netdb.h errno.h)
AC_HEADER_TIME

dnl Checks for typedefs.
AC_CHECK_TYPE(uint, unsigned int)

dnl Checks for structures.

dnl Checks for compiler characteristics.
AC_C_INLINE
AC_CHECK_SIZEOF(long long, 8)
AC_CHECK_SIZEOF(long, 4)
AC_CHECK_SIZEOF(int, 4)
AC_CHECK_SIZEOF(short, 2)

DC_DO_TYPE(uint64_t, unsigned, 8)
DC_DO_TYPE(int64_t, signed, 8)
DC_DO_TYPE(uint32_t, unsigned, 4)
DC_DO_TYPE(int32_t, signed, 4)
DC_DO_TYPE(uint16_t, unsigned, 2)
DC_DO_TYPE(int16_t, signed, 2)

dnl Checks for library functions.
AC_CHECK_LIB(z, compress2, AC_DEFINE(HAVE_COMPRESS2, [], [Have more versatile compress2() ?]))
AC_CHECK_LIB(z, gzdopen, AC_DEFINE(HAVE_GZDOPEN, [], [Have gzdopen() ?]))
AC_CHECK_LIB(bz2, bzBuffToBuffCompress, AC_DEFINE(HAVE_OLD_BZ2, [], [Do not have BZ2_ prefixed to all bzip2 symbols?]))
AC_CHECK_LIB(bz2, BZ2_bzBuffToBuffCompress, AC_DEFINE(HAVE_NEW_BZ2, [], [Have BZ2_ prefixed to all bzip2 symbols?]))
AC_CHECK_LIB(bz2, bzdopen, AC_DEFINE(HAVE_BZDOPEN, [], [Have bzdopen() ?]))
AC_CHECK_LIB(bz2, BZ2_bzdopen, AC_DEFINE(HAVE_NEW_BZDOPEN, [], [Have BZ2_bzdopen() ?]))
AC_REPLACE_FUNCS(getopt strsep getpass mkstemp uname)

dnl Checks for system services.
DC_DO_WIN32

dnl Sync the SHLIBOBJS with LIBOBJS
DC_SYNC_SHLIBOBJS

AC_OUTPUT(Makefile)