add support to reopen files from the previous session

Author: rfindler

gui-doc/scribblings/framework/frame.scrbl

@@ -77,6 +77,13 @@
 
     Returns @racket[#f].
   }
+ @defmethod[(get-all-open-files) (listof path?)]{
+  Indicates the files that are currently open in this frame.
+
+  Returns @racket['()].
+
+  @history[#:added "1.74"]
+ }
   @defmethod*[(((get-filename (temp (or/c #f (box boolean?)) #f)) (or/c #f path?)))]{
     This returns the filename that the frame is currently being saved as,
     or @racket[#f] if there is no appropriate filename.
@@ -607,10 +614,16 @@
     @method[frame:editor<%> get-editor].
   }
 
-  @defmethod*[#:mode override (((editing-this-file? (filename path?)) boolean?))]{
+  @defmethod[#:mode override (editing-this-file? [filename path?]) boolean?]{
     Returns @racket[#t] if the filename is the file that this frame is editing.
   }
 
+ @defmethod[#:mode override (get-all-open-files) (listof path?)]{
+  Returns a list of all the paths for files that are open in this frame.
+
+  @history[#:added "1.74"]
+ }
+
   @defmethod*[#:mode augment (((on-close) void?))]{
     Calls the @racket[editor:basic<%>]'s method @method[editor:basic<%>
     on-close].

gui-lib/framework/main.rkt

@@ -450,6 +450,20 @@
   ()
   @{Adds a font selection preferences panel to the preferences dialog.})
 
+ (proc-doc/names
+  preferences:add-boolean-option-with-ask-me
+  (-> (or/c (is-a?/c area-container<%>) #f)
+      string?
+      string?
+      string?
+      symbol?
+      void?)
+  (parent label option1 option2 pref-key)
+
+  @{Adds a checkbox to @racket[parent] with three options; the first two are given by @racket[option1] and @racket[option2], and
+the third is "Ask me". The preference named by@racket[pref-key] is updated based on the selection in the checkbox.
+})
+
  (proc-doc/names
   preferences:show-dialog
   (-> void?)

gui-lib/framework/private/editor-misc.rkt

@@ -213,6 +213,8 @@
                        (file-or-directory-modify-seconds filename))))))
 
       (set! can-save-file-filename #f)
+
+      (handler:update-currently-open-files)
       (inner (void) after-save-file success?))
 
     (define/augment (after-load-file success?)
@@ -223,7 +225,8 @@
           (set! last-saved-file-time
                 (and filename
                      (file-exists? filename)
-                     (file-or-directory-modify-seconds filename)))))
+                     (file-or-directory-modify-seconds filename))))
+        (handler:update-currently-open-files))
       (inner (void) after-load-file success?))
 
     (define/public (save-file-out-of-date?)
@@ -688,6 +691,7 @@
 
     (define/augment (on-close)
       (remove-autosave)
+      (handler:update-currently-open-files)
       (set! do-autosave? #f)
       (inner (void) on-close))
     (define/augment (on-change)

gui-lib/framework/private/frame.rkt

@@ -186,6 +186,8 @@
         [(b) #f]))
 
     (define/public (editing-this-file? filename) #f)
+
+    (define/public (get-all-open-files) '())
 
     (define/override (on-superwindow-show shown?)
       (send (group:get-the-frame-group) frame-shown/hidden this)
@@ -510,7 +512,8 @@
     (define/override (on-activate on?)
       (super on-activate on?)
       (when on?
-        (send (group:get-the-frame-group) set-active-frame this)))
+        (send (group:get-the-frame-group) set-active-frame this))
+      (handler:update-currently-open-files))
 
     (super-new)
     (send (group:get-the-frame-group) insert-frame this)))
@@ -1449,6 +1452,10 @@
         (let ([this-fn (get-filename)])
           (and this-fn
                (path-equal? filename (get-filename))))))
+
+    (define/override (get-all-open-files)
+      (with-handlers ((exn:fail? (λ (x) '())))
+        (list (normalize-path (get-filename)))))
 
     (define/augment (on-close)
       (send (get-editor) on-close)

gui-lib/framework/private/group.rkt

@@ -263,6 +263,13 @@
                  (if (test-frame frame)
                      frame
                      (loop (cdr frames))))]))))
+
+      (define/public (get-all-open-files)
+        (define the-frames (map frame-frame frames))
+        (when (member active-frame the-frames)
+          (set! the-frames (cons active-frame (remove active-frame the-frames))))
+        (for/list ([frame (in-list the-frames)])
+          (send frame get-all-open-files)))
 
       (super-new)))
 

gui-lib/framework/private/handler.rkt

@@ -10,6 +10,7 @@
          string-constants)
 
 (import mred^
+        [prefix exit: framework:exit^]
         [prefix finder: framework:finder^]
         [prefix group: framework:group^]
         [prefix frame: framework:frame^])
@@ -126,6 +127,13 @@
                                 (preferences:get 'framework:recent-max-count)))
   (preferences:set 'framework:recently-opened-files/pos new-recent))
 
+(define (update-currently-open-files)
+  (unless (exit:exiting?)
+    (preferences:set
+     'framework:last-opened-files
+     (send (group:get-the-frame-group)
+           get-all-open-files))))
+
 ;; same-enough-path? : path path -> boolean
 ;; used to determine if the open-recent-files menu item considers two paths to be the same
 (define (recently-opened-files-same-enough-path? p1 p2)

gui-lib/framework/private/interfaces.rkt

@@ -74,6 +74,7 @@
     make-root-area-container
     close
     editing-this-file?
+    get-all-open-files
     get-filename
     make-visible))
 

gui-lib/framework/private/main.rkt

@@ -27,6 +27,11 @@
 
 (application-preferences-handler (λ () (preferences:show-dialog)))
 
+(preferences:set-default 'framework:last-opened-files '() (listof (listof path?)))
+(preferences:set-un/marshall 'framework:last-opened-files
+                             (λ (x) (map (λ (x) (map path->bytes x)) x))
+                             (λ (x) (map (λ (x) (map bytes->path x)) x)))
+
 (preferences:set-default 'framework:caret-blink-disable? #f boolean?)
 
 (preferences:set-default 'framework:editor-x-selection-mode #t boolean?)

gui-lib/framework/private/preferences.rkt

@@ -567,6 +567,31 @@ the state transitions / contracts are:
                                (cadr current)))))
   (update-tf-bkg))
 
+(define (add-boolean-option-with-ask-me parent label option1 option2 pref-key)
+  (define rb
+    (new radio-box%
+         [label label]
+         [parent parent]
+         [choices (list option1
+                        option2
+                        (string-constant ask-me-each-time))]
+         [callback
+          (λ (rb evt)
+            (preferences:set pref-key
+                             (case (send rb get-selection)
+                               [(0) #t]
+                               [(1) #f]
+                               [(2) 'ask])))]))
+  (define (update-rb what)
+    (send rb set-selection
+          (case what
+            [(#t) 0]
+            [(#f) 1]
+            [(ask) 2])))
+  (update-rb (preferences:get pref-key))
+  (preferences:add-callback pref-key (λ (p v) (update-rb v)))
+  (void))
+
 (define (add-general-checkbox-panel) (add-general-checkbox-panel/real))
 (define (add-general-checkbox-panel/real)
   (set! add-general-checkbox-panel/real void)
@@ -579,28 +604,12 @@ the state transitions / contracts are:
                 (string-constant backup-unsaved-files))
      (add-check editor-panel 'framework:backup-files? (string-constant first-change-files))
 
-     (define auto-load-rb
-       (new radio-box%
-            [label (string-constant autoload-automatically-reload)]
-            [parent editor-panel]
-            [choices (list (string-constant autoload-when-the-editor-isnt-dirty)
-                           (string-constant autoload-never-revert)
-                           (string-constant autoload-ask-about-reverting))]
-            [callback
-             (λ (rb evt)
-               (preferences:set 'framework:autoload
-                                (case (send rb get-selection)
-                                  [(0) #t]
-                                  [(1) #f]
-                                  [(2) 'ask])))]))
-     (define (update-auto-load-rb what)
-       (send auto-load-rb set-selection
-             (case what
-               [(#t) 0]
-               [(#f) 1]
-               [(ask) 2])))
-     (update-auto-load-rb (preferences:get 'framework:autoload))
-     (preferences:add-callback 'framework:autoload (λ (p v) (update-auto-load-rb v)))
+     (add-boolean-option-with-ask-me
+      editor-panel
+      (string-constant autoload-automatically-reload)
+      (string-constant autoload-when-the-editor-isnt-dirty)
+      (string-constant autoload-never-revert)
+      'framework:autoload)
 
      (unless (equal? (system-type) 'unix)
        (define (bool->pref b) (if b 'std 'common))

gui-lib/framework/private/sig.rkt

@@ -111,7 +111,7 @@
      add-can-close-dialog-callback
 
      add-check
-     
+     add-boolean-option-with-ask-me
      show-dialog
      hide-dialog))
 
@@ -289,6 +289,7 @@
      open-file
      install-recent-items
      add-to-recent
+     update-currently-open-files ;; not provided outside of the unit
      set-recent-position
      set-recent-items-frame-superclass
      size-recently-opened-files))

gui-lib/info.rkt

@@ -34,7 +34,7 @@
 
 (define pkg-authors '(mflatt robby))
 
-(define version "1.73")
+(define version "1.74")
 
 (define license
   '(Apache-2.0 OR MIT))