MODULE.bazel

module(
    name = "pybind11_abseil",
    version = "head",
)

# Only direct dependencies need to be listed below.
# Please keep the versions in sync with the versions in the WORKSPACE file.
# see https://registry.bazel.build/
bazel_dep(name = "bazel_skylib", version = "1.7.1")
bazel_dep(name = "abseil-cpp", version = "20240722.1", repo_name = "com_google_absl")
bazel_dep(name = "platforms", version = "0.0.10")
bazel_dep(name = "rules_cc", version = "0.1.1")
bazel_dep(name = "rules_python", version = "0.40.0")
bazel_dep(name = "pybind11_bazel", version = "2.13.6")

#### DEV ONLY DEPENDENCIES BELOW HERE ####

SUPPORTED_PYTHON_VERSIONS = [
    "3.12",
    "3.11",
    "3.10",
    "3.9",
    "3.8",
]

DEFAULT_PYTHON = "3.11"

python = use_extension("@rules_python//python/extensions:python.bzl", "python", dev_dependency = True)

[
    python.toolchain(
        ignore_root_user_error = True,  # needed for CI
        is_default = version == DEFAULT_PYTHON,
        python_version = version,
    )
    for version in SUPPORTED_PYTHON_VERSIONS
]

use_repo(python, python = "python_versions")

pip = use_extension("@rules_python//python/extensions:pip.bzl", "pip", dev_dependency = True)

[
    pip.parse(
        hub_name = "pypi",
        python_version = version,
        requirements_lock = "//pybind11_abseil/requirements:requirements_lock_" + version.replace(".", "_") + ".txt",
    )
    for version in SUPPORTED_PYTHON_VERSIONS
]

use_repo(pip, "pypi")