build.gradle

plugins {
    id 'idea'
    id 'io.spring.dependency-management' version "1.0.11.RELEASE"
    id 'org.springframework.boot' version '2.6.1' apply false
    id 'com.google.cloud.tools.jib' version '3.1.4' apply false
}

idea {
    project {
        languageLevel = 17
    }
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

allprojects {
    group "ru.petrelevich"

    repositories {
        mavenCentral()
    }

    apply plugin: "io.spring.dependency-management"
    dependencyManagement {
        dependencies {
            imports {
                mavenBom("org.springframework.boot:spring-boot-dependencies:2.6.1")
            }
            dependency "io.projectreactor:reactor-test:${Versions.reactorTest}"
            dependency "org.testcontainers:junit-jupiter:${Versions.testcontainers}"
            dependency "org.testcontainers:kafka:${Versions.testcontainers}"
        }
    }

    configurations.all {
        resolutionStrategy {
            failOnVersionConflict()
        }
    }

    task managedVersions {
        doLast {
            dependencyManagement.managedVersions.each {
                println it
            }
        }
    }
}