database: Build with nix

There are quite a few finer detailed points worth exploring.

* Ignoring .git and nix directories, as well as any gitignored files
  ensures that the null-db binary is not built more than necessary
  when iterating in development.

* RUSTC_BOOTSTRAP is a workaround - you can use an unstable toolchain
  if you want to using some other overlay or something, but caveat
  emptor.

* The layout with a default.nix in the top-level directory is a
  personal idiom, not exactly worldwide. I like to expose the whole
  package set from the top-level and use the --attr flag to access
  things in there.

Author: jsoo1

.gitignore

@@ -33,3 +33,7 @@ ENV/
 env.bak/
 venv.bak/
 
+# nix creates symlinks like these after nix-build or nix build.
+# They can be nice to have for reference
+result*
+result*/

database/default.nix

@@ -0,0 +1,37 @@
+{ lib, nix-gitignore, rustPlatform, openssl, pkg-config, protobuf }:
+
+let
+  version = "0.1.0";
+in
+
+rustPlatform.buildRustPackage {
+  name = "null-db-${version}";
+  inherit version;
+  src = nix-gitignore.gitignoreSourcePure [
+    ''
+      nix/*
+      .git/*
+    ''
+    # I think this is a workaround for a bug in gitignoreSourcePure
+    ../.gitignore
+  ] ../.;
+
+  cargoHash = "sha256-J5YJhxqOwub/k17RYsIhu5iZSz5AUmOSeEBWLRcU7Ck=";
+
+  # disk_io uses some unstable feature for some reason - workaround
+  # here by pretending to be compiling rustc
+  RUSTC_BOOTSTRAP = 1;
+
+  nativeBuildInputs = [ pkg-config protobuf ];
+  buildInputs = [ openssl ];
+
+  cargoBuildHook = "cd database";
+
+  # Don't compile atm
+  doCheck = false;
+
+  postInstall = ''
+    mkdir -p $out/libexec
+    mv $out/bin/null-db $out/libexec
+  '';
+}

default.nix

@@ -0,0 +1,21 @@
+{ system ? builtins.currentSystem }:
+
+let
+  rev = "2d2a9ddbe3f2c00747398f3dc9b05f7f2ebb0f53";
+
+  nixpkgs = builtins.fetchTarball {
+    url = "https://github.com/NixOS/nixpkgs/archive/${rev}.tar.gz";
+    sha256 = "sha256-B5WRZYsRlJgwVHIV6DvidFN7VX7Fg9uuwkRW9Ha8z+w=";
+  };
+in
+
+import nixpkgs {
+  inherit system;
+  # If `config` is not provided, things in $HOME or other places get
+  # picked up, causing nondeterminism :(
+  #
+  # This is an unfortunate historical wart that might even eventually
+  # get fixed.
+  config = { };
+  overlays = [ (import ./nix/overlay.nix) ];
+}

nix/overlay.nix

@@ -0,0 +1,3 @@
+final: prev: {
+  null-db = final.callPackage ../database { };
+}