Add native 'IsCustomDamageTypeDOT'

Author: nosoop

gamedata/tf2.utils.nosoop.txt

@@ -56,6 +56,16 @@
 				}
 			}
 		}
+		"Keys"
+		{
+			// space-separated set of hex values corresponding to damage types that are 'damage over time'
+			// the game inlines this functionality so we'll have to implement this ourselves
+			// 0x03 = TF_CUSTOM_BURNING
+			// 0x08 = TF_CUSTOM_BURNING_FLARE
+			// 0x11 = TF_CUSTOM_BURNING_ARROW
+			// 0x22 = TF_CUSTOM_BLEEDING
+			"DOTDamageTypes"		"03 08 11 22"
+		}
 		"Offsets"
 		{
 			// virtual offsets

scripting/include/tf2utils.inc

@@ -339,6 +339,17 @@ native void TF2Util_UpdatePlayerSpeed(int client, bool immediate = false);
 native bool TF2Util_IsPointInRespawnRoom(const float position[3],
 		int entity = INVALID_ENT_REFERENCE, bool bRestrictToSameTeam = false);
 
+/**
+ * Returns whether or not the given custom damage type is for a "damage over time" effect.
+ * This is provided to allow plugins to identify periodic damage events without hardcoding that
+ * information themselves.
+ * 
+ * @param damagecustom    Custom damage type.  This is provided by the SDKHooks OnTakeDamage
+ *                        set of hooks as 'damagecustom', among other places.
+ * @return                True if the given value matches a known DOT effect; false otherwise.
+ */
+native bool TF2Util_IsCustomDamageTypeDOT(int damagecustom);
+
 /**
  * Given the address of a CTFPlayerShared instance, returns the player associated with it.
  * 

scripting/tf2utils.sp

@@ -12,7 +12,7 @@
 #include <stocksoup/convars>
 #include <stocksoup/memory>
 
-#define PLUGIN_VERSION "1.0.0"
+#define PLUGIN_VERSION "1.1.0"
 public Plugin myinfo = {
 	name = "TF2 Utils",
 	author = "nosoop",
@@ -67,6 +67,9 @@ int sizeof_TFCondInfo;
 
 int g_nConditions;
 
+#define MAX_DOT_DAMAGE_TYPES    16
+int g_nDOTDamageTypes, g_DOTDamageTypes[MAX_DOT_DAMAGE_TYPES];
+
 public APLRes AskPluginLoad2(Handle self, bool late, char[] error, int maxlen) {
 	RegPluginLibrary("nosoop_tf2utils");
 
@@ -114,6 +117,8 @@ public APLRes AskPluginLoad2(Handle self, bool late, char[] error, int maxlen) {
 
 	CreateNative("TF2Util_IsPointInRespawnRoom", Native_IsPointInRespawnRoom);
 
+	CreateNative("TF2Util_IsCustomDamageTypeDOT", Native_IsCustomDamageTypeDOT);
+	
 	CreateNative("TF2Util_GetPlayerFromSharedAddress", Native_GetPlayerFromSharedAddress);
 
 	// deprecated name for backcompat
@@ -364,6 +369,26 @@ public void OnPluginStart() {
 	offs_CTFPlayer_flLastDamageTime = GameConfGetAddressOffset(hGameConf,
 			"CTFPlayer::m_flLastDamageTime");
 
+	// allocate 5 chars for each value + delimiter
+	char damageTypes[MAX_DOT_DAMAGE_TYPES * 5];
+	if (!GameConfGetKeyValue(hGameConf, "DOTDamageTypes", damageTypes, sizeof(damageTypes))) {
+		SetFailState("Could not retrieve DOTDamageTypes values");
+	} else for (int c, i, res; (i = StringToIntEx(damageTypes[c], res, 0x10)); c += i) {
+		/**
+		 * Parse numeric values from the list.
+		 * I don't expect the game to ever have as many DOT damage types as the hardcoded
+		 * limit of 16 I've initally assigned here, but if it does, don't silently fail.
+		 */
+		if (g_nDOTDamageTypes == MAX_DOT_DAMAGE_TYPES) {
+			SetFailState("Not enough space allocated to parse damage types (limit %d) - "
+					... "update MAX_DOT_DAMAGE_TYPES and recompile", MAX_DOT_DAMAGE_TYPES);
+		} else if (res == 0) {
+			continue;
+		}
+		
+		g_DOTDamageTypes[g_nDOTDamageTypes++] = res;
+	}
+	
 	delete hGameConf;
 
 	CreateVersionConVar("tf2utils_version", "TF2 Utils version.");
@@ -865,6 +890,17 @@ any Native_SetPlayerRespawnTimeOverride(Handle plugin, int numParams) {
 	return;
 }
 
+// bool(int damagecustom);
+any Native_IsCustomDamageTypeDOT(Handle plugin, int numParams) {
+	int damagecustom = GetNativeCell(1);
+	for (int i; i < g_nDOTDamageTypes; i++) {
+		if (g_DOTDamageTypes[i] == damagecustom) {
+			return true;
+		}
+	}
+	return false;
+}
+
 // int(Address pShared);
 any Native_GetPlayerFromSharedAddress(Handle plugin, int numParams) {
 	Address pShared = GetNativeCell(1);