Tests: basic QUIC key update tests.

Author: pluknet

lib/Test/Nginx/HTTP3.pm

@@ -65,6 +65,7 @@ sub new {
 sub init {
 	my ($self) = @_;
 	$self->{keys} = [];
+	$self->{key_phase} = 0;
 	$self->{pn} = [[-1, -1, -1, -1], [-1, -1, -1, -1]];
 	$self->{crypto_in} = [[],[],[],[]];
 	$self->{stream_in} = [];
@@ -1775,7 +1776,9 @@ sub encrypt_aead_f {
 sub encrypt_aead {
 	my ($self, $payload, $level) = @_;
 	my $pn = ++$self->{pn}[0][$level];
-	my $ad = pack("C", $level == 3 ? 0x40 : 0xc + $level << 4) | "\x03";
+	my $ad = pack("C", $level == 3
+		? 0x40 | ($self->{key_phase} << 2)
+		: 0xc + $level << 4) | "\x03";
 	$ad .= "\x00\x00\x00\x01" unless $level == 3;
 	$ad .= $level == 3 ? $self->{dcid} :
 		pack("C", length($self->{dcid})) . $self->{dcid}
@@ -1867,6 +1870,26 @@ sub set_traffic_keys {
 	$self->{keys}[$level]{$direction}{hp} = $hp;
 }
 
+sub key_update {
+	my ($self) = @_;
+	my ($prk, $key, $iv);
+	my $klen = $self->{cipher} == 0x1301 || $self->{cipher} == 0x1304
+		? 16 : 32;
+	my ($hash, $hlen) = $self->{cipher} == 0x1302 ?
+		('SHA384', 48) : ('SHA256', 32);
+	$self->{key_phase} ^= 1;
+
+	for my $direction ('r', 'w') {
+		$prk = $self->{keys}[3]{$direction}{prk};
+		$prk = hkdf_expand_label("tls13 quic ku", $hash, $hlen, $prk);
+		$key = hkdf_expand_label("tls13 quic key", $hash, $klen, $prk);
+		$iv = hkdf_expand_label("tls13 quic iv", $hash, 12, $prk);
+		$self->{keys}[3]{$direction}{prk} = $prk;
+		$self->{keys}[3]{$direction}{key} = $key;
+		$self->{keys}[3]{$direction}{iv} = $iv;
+	}
+}
+
 sub hmac_finished {
 	my ($hash, $hlen, $key, $digest) = @_;
 	my $expand = hkdf_expand_label("tls13 finished", $hash, $hlen, $key);

quic_key_update.t

@@ -0,0 +1,99 @@
+#!/usr/bin/perl
+
+# (C) Sergey Kandaurov
+# (C) Nginx, Inc.
+
+# Tests for QUIC key update.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+use Test::Nginx::HTTP3;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+my $t = Test::Nginx->new()->has(qw/http http_v3 cryptx/)
+	->has_daemon('openssl')->plan(3);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    ssl_certificate_key localhost.key;
+    ssl_certificate localhost.crt;
+
+    server {
+        listen       127.0.0.1:%%PORT_8980_UDP%% quic;
+        server_name  localhost;
+
+        location / { }
+    }
+}
+
+EOF
+
+$t->write_file('openssl.conf', <<EOF);
+[ req ]
+default_bits = 2048
+encrypt_key = no
+distinguished_name = req_distinguished_name
+[ req_distinguished_name ]
+EOF
+
+my $d = $t->testdir();
+
+foreach my $name ('localhost') {
+	system('openssl req -x509 -new '
+		. "-config $d/openssl.conf -subj /CN=$name/ "
+		. "-out $d/$name.crt -keyout $d/$name.key "
+		. ">>$d/openssl.out 2>&1") == 0
+		or die "Can't create certificate for $name: $!\n";
+}
+
+$t->run();
+
+###############################################################################
+
+my ($s, $sid, $frames, $frame);
+
+$s = Test::Nginx::HTTP3->new();
+ok(get($s), 'request');
+
+# sets the Key Phase bit
+
+$s->key_update();
+ok(get($s), 'key update 1');
+
+# clears the Key Phase bit
+
+$s->key_update();
+ok(get($s), 'key update 2');
+
+###############################################################################
+
+sub get {
+	my ($s) = @_;
+	my $frames = $s->read(all => [{ sid => $s->new_stream(), fin => 1 }]);
+	grep { $_->{type} eq "HEADERS" } @$frames;
+}
+
+###############################################################################