build.gradle

plugins {
    id 'org.springframework.boot' version '2.1.4.RELEASE'
    id 'org.jetbrains.kotlin.jvm' version '1.2.71'
    id 'org.jetbrains.kotlin.plugin.spring' version '1.2.71'
}

def env = project.hasProperty('env') ? project.property('env') : 'local'

apply plugin: 'io.spring.dependency-management'

group = 'com.neshant'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.github.javafaker:javafaker:0.17.2'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    implementation 'org.springframework.kafka:spring-kafka'
    implementation 'io.github.microutils:kotlin-logging:1.6.10'

    implementation 'com.fasterxml.jackson.module:jackson-module-kotlin'
    implementation 'org.jetbrains.kotlin:kotlin-reflect'
    implementation 'org.jetbrains.kotlin:kotlin-stdlib-jdk8'
    runtimeOnly 'org.springframework.boot:spring-boot-devtools'


    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'io.projectreactor:reactor-test'
    testImplementation 'org.springframework.kafka:spring-kafka-test'
}

compileKotlin {
    kotlinOptions {
        freeCompilerArgs = ['-Xjsr305=strict']
        jvmTarget = '1.8'
    }
}

compileTestKotlin {
    kotlinOptions {
        freeCompilerArgs = ['-Xjsr305=strict']
        jvmTarget = '1.8'
    }
}

task startServices(type: Exec) {
    group = 'Docker Services'
    description = 'Start docker containers used for development.'

    commandLine 'docker-compose', 'up', '-d'
}

task stopServices(type: Exec) {
    group = 'Docker Services'
    description = 'Stop docker containers used for development.'

    commandLine 'docker-compose', 'down'
}

// make sure services are running for bootRun in a local environment
if (env == 'local') {
    test.dependsOn(startServices)
    bootRun.dependsOn(startServices)
}