initial sdks

Author: CrowdHailer

.github/workflows/test.yml

@@ -0,0 +1,23 @@
+name: test
+
+on:
+  push:
+    branches:
+      - master
+      - main
+  pull_request:
+
+jobs:
+  test:
+    runs-on: ubuntu-latest
+    steps:
+      - uses: actions/checkout@v4
+      - uses: erlef/setup-beam@v1
+        with:
+          otp-version: "26.0.2"
+          gleam-version: "1.4.1"
+          rebar3-version: "3"
+          # elixir-version: "1.15.4"
+      - run: gleam deps download
+      - run: gleam test
+      - run: gleam format --check src test

.gitignore

@@ -0,0 +1 @@
+/build

README.md

@@ -0,0 +1,30 @@
+# midas_sdk
+
+[![Package Version](https://img.shields.io/hexpm/v/midas_sdk)](https://hex.pm/packages/midas_sdk)
+[![Hex Docs](https://img.shields.io/badge/hex-docs-ffaff3)](https://hexdocs.pm/midas_sdk/)
+
+A set of SDK's for building tasks with midas.
+Note this is not meant to be an exhaustive set for any given usecase.
+Instead if functions as quick implemetations of scripts and automations,
+this is the usecase midas wants to champion using Gleam for.
+This package can also be used as examples for how to implement sdk's that work with midas.
+
+```sh
+gleam add midas_sdk@1
+```
+```gleam
+import midas_sdk
+
+pub fn main() {
+  // TODO: An example of the project in use
+}
+```
+
+Further documentation can be found at <https://hexdocs.pm/midas_sdk>.
+
+## Development
+
+```sh
+gleam run   # Run the project
+gleam test  # Run the tests
+```

gleam.toml

@@ -0,0 +1,18 @@
+name = "midas_sdk"
+version = "0.1.0"
+target = "javascript"
+
+description = "A bag of SDK's that can be used with midas."
+licences = ["Apache-2.0"]
+repository = { type = "github", user = "midas-framework", repo = "midas_sdk" }
+links = [{ title = "midas", href = "https://github.com/midas-framework/midas" }]
+
+[dependencies]
+gleam_stdlib = ">= 0.34.0 and < 2.0.0"
+gleam_http = ">= 3.7.0 and < 4.0.0"
+midas = ">= 1.0.0 and < 2.0.0"
+gleam_json = ">= 1.0.0 and < 3.0.0"
+snag = ">= 0.3.0 and < 1.0.0"
+
+[dev-dependencies]
+gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -0,0 +1,19 @@
+# This file was generated by Gleam
+# You typically do not need to edit this file
+
+packages = [
+  { name = "gleam_http", version = "3.7.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_http", source = "hex", outer_checksum = "EA66440C2269F7CED0F6845E5BD0DB68095775D627FA709A841CA78A398D6D56" },
+  { name = "gleam_json", version = "2.0.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "CB10B0E7BF44282FB25162F1A24C1A025F6B93E777CCF238C4017E4EEF2CDE97" },
+  { name = "gleam_stdlib", version = "0.40.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "86606B75A600BBD05E539EB59FABC6E307EEEA7B1E5865AFB6D980A93BCB2181" },
+  { name = "gleeunit", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "F7A7228925D3EE7D0813C922E062BFD6D7E9310F0BEE585D3A42F3307E3CFD13" },
+  { name = "midas", version = "0.4.7", build_tools = ["gleam"], requirements = ["gleam_http", "gleam_json", "gleam_stdlib", "snag"], otp_app = "midas", source = "hex", outer_checksum = "B0B547EA5139E63B79B3CE3246098F9EA1162E2B96A7D4938E3EB8736FF3AE9E" },
+  { name = "snag", version = "0.3.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "snag", source = "hex", outer_checksum = "54D32E16E33655346AA3E66CBA7E191DE0A8793D2C05284E3EFB90AD2CE92BCC" },
+]
+
+[requirements]
+gleam_http = { version = ">= 3.7.0 and < 4.0.0" }
+gleam_json = { version = ">= 2.0.0 and < 3.0.0" }
+gleam_stdlib = { version = ">= 0.34.0 and < 2.0.0" }
+gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
+midas = { version = ">= 0.4.7 and < 1.0.0" }
+snag = { version = ">= 0.3.0 and < 1.0.0" }

src/midas/sdk/google.gleam

@@ -0,0 +1,110 @@
+import gleam/bit_array
+import gleam/dynamic
+import gleam/http/request
+import gleam/http/response
+import gleam/int
+import gleam/json
+import gleam/list
+import gleam/option.{None, Some}
+import gleam/result.{try}
+import gleam/string
+import gleam/uri.{Uri}
+import midas/task as t
+import snag
+
+pub type App {
+  App(client_id: String, redirect_uri: String)
+}
+
+const auth_host = "accounts.google.com"
+
+const auth_path = "/o/oauth2/auth"
+
+pub fn authenticate(app, scopes) {
+  let App(client_id, redirect_uri) = app
+  let state = int.to_string(int.random(1_000_000_000))
+  let url = auth_url(client_id, redirect_uri, scopes, state)
+  use redirect <- t.do(t.follow(url))
+  use #(access_token, token_type, returned_state) <- t.try(
+    auth_redirect(redirect) |> result.map_error(snag.new),
+  )
+  use Nil <- t.try(case returned_state == state {
+    True -> Ok(Nil)
+    False -> Error(snag.new("returned state was not equal to sent state"))
+  })
+
+  use Nil <- t.try(case token_type == "Bearer" {
+    True -> Ok(Nil)
+    False -> Error(snag.new("returned token_type was not 'Bearer'"))
+  })
+  t.Done(access_token)
+}
+
+fn auth_url(client_id, redirect_uri, scopes, state) {
+  let query = [
+    #("client_id", client_id),
+    #("response_type", "token"),
+    #("redirect_uri", redirect_uri),
+    #("state", state),
+    #("scope", string.join(scopes, " ")),
+  ]
+  let query = Some(uri.query_to_string(query))
+  Uri(Some("https"), None, Some(auth_host), None, auth_path, query, None)
+  |> uri.to_string
+}
+
+pub fn auth_redirect(redirect) {
+  let Uri(fragment: fragment, ..) = redirect
+  use hash <- try(case fragment {
+    Some(hash) -> Ok(hash)
+    None -> Error("uri did not have a fragment")
+  })
+  use parts <- try(
+    uri.parse_query(hash)
+    |> result.replace_error("Failed to parse query: " <> hash),
+  )
+  use access_token <- try(key_find(parts, "access_token"))
+  use token_type <- try(key_find(parts, "token_type"))
+  use returned_state <- try(key_find(parts, "state"))
+  // other parts expires_in and scope
+  Ok(#(access_token, token_type, returned_state))
+}
+
+fn key_find(items, key) {
+  list.key_find(items, key)
+  |> result.replace_error("Did not find key: " <> key)
+}
+
+const openid_host = "openidconnect.googleapis.com"
+
+const userinfo_path = "/v1/userinfo"
+
+pub fn userinfo(token) {
+  let request = userinfo_request(token)
+  use response <- t.do(t.fetch(request))
+  use response <- t.try(userinfo_response(response))
+  t.Done(response)
+}
+
+pub fn userinfo_request(token) {
+  request.new()
+  |> request.set_host(openid_host)
+  |> request.prepend_header("Authorization", string.append("Bearer ", token))
+  |> request.set_path(userinfo_path)
+  |> request.set_body(<<>>)
+}
+
+pub fn userinfo_response(response: response.Response(BitArray)) {
+  use json <- try(
+    bit_array.to_string(response.body)
+    |> result.replace_error(snag.new("not utf8 encoded")),
+  )
+  use message <- try(
+    json.decode_bits(response.body, dynamic.field("email", dynamic.string))
+    |> result.map_error(fn(reason) {
+      snag.new(string.inspect(reason))
+      |> snag.layer("failed to decode message")
+    }),
+  )
+  Ok(message)
+}

src/midas/sdk/google/gmail.gleam

@@ -0,0 +1,112 @@
+import gleam/bit_array
+import gleam/dynamic
+import gleam/http
+import gleam/http/request
+import gleam/http/response
+import gleam/json
+import gleam/result.{try}
+import gleam/string
+import midas/task as t
+import snag
+
+const api_host = "gmail.googleapis.com"
+
+fn base_request(token) {
+  request.new()
+  |> request.set_host(api_host)
+  |> request.prepend_header("Authorization", string.append("Bearer ", token))
+}
+
+fn get(token, path) {
+  base_request(token)
+  |> request.set_path(path)
+  |> request.set_body(<<>>)
+}
+
+fn post(token, path, mime, content) {
+  base_request(token)
+  |> request.set_method(http.Post)
+  |> request.set_path(path)
+  |> request.prepend_header("content-type", mime)
+  |> request.set_body(content)
+}
+
+pub fn send(token, from, to, message) {
+  let request = send_request(token, from, to, message)
+  use response <- t.do(t.fetch(request))
+  use response <- t.try(send_response(response))
+  t.Done(response)
+}
+
+pub fn send_request(token, from, to, message) {
+  let path = "/gmail/v1/users/" <> from <> "/messages/send"
+  let mime = "application/json; charset=UTF-8"
+  let email =
+    "From: "
+    <> from
+    <> "\r\nTo: "
+    <> to
+    <> "\r\nContent-Type: text/html; charset=utf-8 "
+    <> "\r\n"
+    <> message
+  let raw = bit_array.base64_encode(<<email:utf8>>, True)
+  let body = json.object([#("raw", json.string(raw))]) |> json.to_string
+  post(token, path, mime, <<body:utf8>>)
+  |> request.set_query([#("alt", "json")])
+}
+
+pub fn send_response(response: response.Response(BitArray)) {
+  use json <- try(
+    bit_array.to_string(response.body)
+    |> result.replace_error(snag.new("not utf8 encoded")),
+  )
+  use message <- try(
+    json.decode_bits(response.body, message_decoder)
+    |> result.map_error(fn(reason) {
+      snag.new(string.inspect(reason))
+      |> snag.layer("failed to decode message")
+    }),
+  )
+  Ok(message)
+}
+
+pub type Message {
+  Message(id: String, thread_id: String)
+}
+
+fn message_decoder(raw) {
+  dynamic.decode2(
+    Message,
+    dynamic.field("id", dynamic.string),
+    dynamic.field("threadId", dynamic.string),
+    // dynamic.field("labelIds", dynamic.list(dynamic.string)),
+  )(raw)
+}
+
+pub fn list_messages(token, user_id) {
+  let request = list_messages_request(token, user_id)
+  use response <- t.do(t.fetch(request))
+  use response <- t.try(list_messages_response(response))
+  t.Done(response)
+}
+
+pub fn list_messages_request(token, user_id) {
+  let path = "/gmail/v1/users/" <> user_id <> "/messages"
+  get(token, path)
+}
+
+pub fn list_messages_response(response: response.Response(BitArray)) {
+  use json <- try(
+    bit_array.to_string(response.body)
+    |> result.replace_error(snag.new("not utf8 encoded")),
+  )
+  let decoder = dynamic.field("messages", dynamic.list(message_decoder))
+  use message <- try(
+    json.decode_bits(response.body, decoder)
+    |> result.map_error(fn(reason) {
+      snag.new(string.inspect(reason))
+      |> snag.layer("failed to decode messages")
+    }),
+  )
+  Ok(message)
+}