Add a new API: /changes/by_releases

Author: gugod

lib/MetaCPAN/Document/Release/Set.pm

@@ -20,6 +20,7 @@ has query_release => (
             author_status
             by_author
             by_author_and_name
+            by_author_and_names
             get_contributors
             get_files
             latest_by_author

lib/MetaCPAN/Query/Release.pm

@@ -357,6 +357,51 @@ sub by_author_and_name {
     };
 }
 
+sub by_author_and_names {
+    my ( $self, $releases ) = @_;
+
+    # $releases: ArrayRef[ Dict[ author => Str, name => Str ] ]
+
+    my $body = {
+        query => {
+            bool => {
+                should => [
+                    map { +{
+                        query => {
+                            bool => {
+                                must => [
+                                    { term => { author => uc($_->{author}) } },
+                                    { term => { 'name' => $_->{name} } },
+                                ]
+                            }
+                        }
+                    } } @$releases
+                ]
+            }
+        }
+    };
+
+    my $ret = $self->es->search(
+        index => $self->index_name,
+        type  => 'release',
+        body  => $body,
+    );
+    return unless $ret->{hits}{total};
+
+    my @releases;
+    for my $hit (@{ $ret->{hits}{hits} }) {
+        my $src = $hit->{_source};
+        single_valued_arrayref_to_scalar($src);
+        push @releases, $src;
+    }
+
+    return {
+        took    => $ret->{took},
+        total   => $ret->{hits}{total},
+        releases => \@releases,
+    };
+}
+
 sub by_author {
     my ( $self, $pauseid, $size ) = @_;
     $size //= 1000;

lib/MetaCPAN/Server/Controller/Changes.pm

@@ -65,4 +65,38 @@ sub all : Chained('index') : PathPart('') : Args(0) {
     $c->detach('not_found');
 }
 
+sub by_releases : Path('by_releases') : Args(0) {
+    my ( $self, $c ) = @_;
+
+    # ArrayRef[ Dict[ author => Str, name => Str ] ]
+    my $arg = $c->read_param("releases");
+    my $ret = $c->model('CPAN::Release')->by_author_and_names( $arg );
+
+    my @changes;
+    for my $release (@{$ret->{releases}}) {
+        my ($author, $name, $path) = @{$release}{ qw(author name changes_file) };
+        my $source = $c->model('Source')->path( $author, $name, $path ) // '';
+
+        my $content;
+        try {
+            local $/;
+            $content = Encode::decode(
+                'UTF-8',
+                (scalar $source->openr->getline),
+                Encode::FB_CROAK | Encode::LEAVE_SRC
+            );
+        } catch {
+            $content = undef;
+        };
+
+        push @changes, {
+            author => $author,
+            release => $name,
+            changes_text => $content,
+        }
+    }
+
+    $c->stash({ changes => \@changes });
+}
+
 1;