Add nix flow for creating project development shell

Add instructions for deploying vivado through nix
- This is not enabled by default, but still present in the project.

Add missing dependencies to nixpkgs verilator
- zlib and libelf were needed for our simulation, probably missing or optional
from the upstream package.

Add ascii-art to 'nix develop' splash

Add instructions for loading packages from USB cache

Author: hcallahan-lowrisc

README.md

@@ -0,0 +1,12 @@
+           ╓╗Φ╬╬╫╫╬╬Æ╗w
+        ╔╬╫╫╫╫╫╫╫╫M   "╣╬╗
+      ╔╣╫╫╫╫╣╝╝╣╫╫╕    ╬╫╫╫╗
+     ╬╫Å╝╝╝╛    ╟╫╫╬ ß╣╫╫╫╫╫▌    .╓,
+    ╔╜╓╬╬╬╬N   ,╣╫╫╫⌐╢╫╫╫╫╫╫╣^   ║█▌                   ║█████▓⌐ ╫█▌ ╓▓████▌  ▄▓████▌
+    ╔╬╫╫Å╜╙╝╫╫╫╫╫╫╫Å,╬╫╫╫╫▌"╔╣   ║█▌ ╓▄▓▓#  Φ▓⌐ ▓▓  ▓▓ ╫█▌  ▓█▌ ▓█▌ ▀█▌▄╓,  ▓█▌
+    ╣╫╫M    ╟╫╫╫╫M,Φ╫╫╫╫Å`╔╣╫╫   ║█▌ █▌  '█M╙█▌╓██▌║█▌ ╫█████▀  ▓█▌  `╙▀██▓ ██▌
+    ╙╫╣╜╓,,╔╣╫╣╜╓╬╫╫╫╫M,╗▓╫╫╫M   ║█▌ ▀█▄▄▓█  ╢██▌╙██▌  ╫█▌ ╙██▄ ▓█▌ ╣▓▄▄▓█▀ ╙██▓▄▓▓▌
+     "╔╣╫╫╫╫▌╨╔╬╫Å╝╣╜╓╬╫╫╫╫╫Å     ``   ``     ``  ``   ```   `  ```   ```      """`
+      ╙╣╫╫Å"╔╣╫╬    ╙╫╫╫╫╫╫╜
+        "`╗╣╫╫╫╬,   ╔╫╫╫╣╜
+           `╙╝╝Φ╣╣ΦÅ╝╜"

data/lowrisc.art

@@ -0,0 +1,15 @@
+{ lib, buildPythonPackage, fetchPypi,
+  jinja2, setuptools_scm, simplesat
+}:
+buildPythonPackage rec {
+  pname = "edalize";
+  version = "0.3.3";
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1734aprwzm0z2l60xapqrfxxw747n9h9fflv3n0x4iaradf75abj";
+  };
+  SETUPTOOLS_SCM_PRETEND_VERSION = "${version}";
+  nativeBuildInputs = [ setuptools_scm ];
+  propagatedBuildInputs = [ jinja2 simplesat ];
+  doCheck = false;
+}

dependencies/edalize.nix

@@ -0,0 +1,104 @@
+{
+  description = "ibex simple_system dependencies";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-22.11";
+    lowrisc_fusesoc_src = { url = "github:lowRISC/fusesoc?ref=ot-0.2"; flake = false; };
+    lowrisc_edalize_src = { url = "github:lowRISC/edalize?ref=ot-0.2"; flake = false; };
+  };
+
+  outputs = {self, nixpkgs,
+              lowrisc_fusesoc_src, lowrisc_edalize_src,
+  }:
+    let
+      system = "x86_64-linux";
+      pkgs = import nixpkgs {
+        inherit system;
+        config = { allowUnfree = true; };
+      };
+
+      lowRISC_python_overrides = pfinal: pprev: {
+        fusesoc = pprev.fusesoc.overridePythonAttrs (oldAttrs: {
+          version = "0.3.3.dev";
+          src = lowrisc_fusesoc_src;
+        });
+        edalize = pprev.edalize.overridePythonAttrs (oldAttrs: {
+          version = "0.3.3.dev";
+          src = lowrisc_edalize_src;
+        });
+      };
+
+      lowRISC_spike_override = final: prev: {
+        riscv-isa-sim = prev.riscv-isa-sim.overrideAttrs (oldAttrs: rec {
+          version = "ibex-cosim-v0.3";
+          src = pkgs.fetchFromGitHub {
+            owner = "lowrisc";
+            repo = oldAttrs.pname;
+            rev = version;
+            sha256 = "sha256-pKuOpzybOI8UqWV1TSFq4hqTHf7Bft/3WL19fRpwmfU=";
+          };
+        });
+      };
+
+      # Using requireFile prevents rehashing each time.
+      # This saves much seconds during rebuilds.
+      vivado_bundled_installer_src = pkgs.requireFile rec {
+        name = "vivado_bundled.tar.gz";
+        sha256 = "1yxx6crvawhzvary9js0m8bzm35vv6pzfqdkv095r84lb13fyp7b";
+        # Print the following message if the name / hash are not
+        # found in the store.
+        message = ''
+          requireFile :
+          file/dir not found in /nix/store
+          file = ${name}
+          hash = ${sha256}
+
+          This nix expression requires that ${name} is already part of the store.
+          - Login to xilinx.com
+          - Download Unified Installer from https://www.xilinx.com/support/download.html,
+          - Run installer, specify a 'Download Image (Install Seperately)'
+          - Gzip the bundled installed image directory
+          - Rename the file to ${name}
+          - Add it to the nix store with
+              nix-prefetch-url --type sha256 file:/path/to/${name}
+          - Change the sha256 key above to $HASH
+        '';
+      };
+
+      vivado = pkgs.callPackage (import ./vivado.nix) {
+        # We need to prepare the pre-downloaded installer to
+        # execute within a nix build. Make use of the included java deps,
+        # but we still need to do a little patching to make it work.
+        vivado-src = pkgs.stdenv.mkDerivation rec {
+          pname = "vivado_src";
+          version = "2022.2";
+          src = vivado_bundled_installer_src;
+          postPatch = ''
+            patchShebangs .
+            patchelf \
+              --set-interpreter $(cat ${pkgs.stdenv.cc}/nix-support/dynamic-linker) \
+              tps/lnx64/jre*/bin/java
+          '';
+          dontBuild = true; dontFixup = true;
+          installPhase = ''
+            mkdir -p $out
+            cp -R * $out
+          '';
+        };
+      };
+
+    in
+      {
+        overlay_pkgs = pkgs.lib.composeManyExtensions [
+          (import ./overlay.nix)
+          lowRISC_spike_override
+          (final: prev: {
+            inherit vivado;
+          })
+        ];
+        overlay_python = pkgs.lib.composeManyExtensions [
+          (import ./python-overlay.nix)
+          lowRISC_python_overrides
+        ];
+      };
+}

dependencies/flake.lock

@@ -0,0 +1,15 @@
+{ lib, buildPythonPackage, fetchPypi,
+  setuptools_scm, pyparsing, pyyaml, simplesat, ipyxact, edalize
+}:
+buildPythonPackage rec {
+  pname = "fusesoc";
+  version = "1.12.0";
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1065arwk1hylf4lqmgqb77fw9izgh7jaib5qnl2dqwdic11c2w44";
+  };
+  SETUPTOOLS_SCM_PRETEND_VERSION = "${version}"; # Hack
+  nativeBuildInputs = [ setuptools_scm ];
+  propagatedBuildInputs = [ pyparsing pyyaml simplesat ipyxact edalize ];
+  doCheck = false;
+}

dependencies/flake.nix

@@ -0,0 +1,12 @@
+{ lib, buildPythonPackage, fetchPypi,
+  pyyaml }:
+buildPythonPackage rec {
+  pname = "ipyxact";
+  version = "0.3.1";
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "09rv8zn6gqwhdnwgx246mz9biln0q71hsxjf6sb9ilhan75fsn0z";
+  };
+  propagatedBuildInputs = [ pyyaml ];
+  doCheck = false;
+}

dependencies/fusesoc.nix

@@ -0,0 +1,12 @@
+{ lib, buildPythonPackage, fetchPypi,
+  attrs, jsonschema, six, zipfile2, distro }:
+buildPythonPackage rec {
+  pname = "okonomiyaki";
+  version = "1.3.2";
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1dw9di7s92z201lwq7aqy5h9h53af73ffx6pnl5iz3lnfi0zf85p";
+  };
+  propagatedBuildInputs = [ attrs jsonschema six zipfile2 distro ];
+  doCheck = false;
+}

dependencies/ipyxact.nix

@@ -0,0 +1,4 @@
+final: prev: {
+  riscv-gcc-toolchain-lowrisc = prev.callPackage ./riscv-gcc-toolchain-lowrisc.nix {};
+  riscv-isa-sim = prev.callPackage ./riscv-isa-sim.nix {};
+}

dependencies/okonomiyaki.nix

@@ -0,0 +1,8 @@
+pfinal: pprev: {
+  ipyxact = pfinal.callPackage ./ipyxact.nix {};
+  zipfile2 = pfinal.callPackage ./zipfile2.nix {};
+  simplesat = pfinal.callPackage ./simplesat.nix {};
+  okonomiyaki = pfinal.callPackage ./okonomiyaki.nix {};
+  fusesoc = pfinal.callPackage ./fusesoc.nix {};
+  edalize = pfinal.callPackage ./edalize.nix {};
+}

dependencies/overlay.nix

@@ -0,0 +1,32 @@
+{ pkgs, lib, stdenv,
+  fetchzip, zlib, ncurses5,
+}:
+
+# Used for reference...
+# https://github.com/NixOS/nixpkgs/blob/master/pkgs/development/compilers/gcc-arm-embedded/10/default.nix
+
+stdenv.mkDerivation rec {
+  name = "riscv-gcc-toolchain";
+  version = "20220210-1";
+  src = fetchzip {
+    url = "https://github.com/lowRISC/lowrisc-toolchains/releases/download/${version}/lowrisc-toolchain-gcc-rv32imc-${version}.tar.xz";
+    sha256 = "1m708xfdzf3jzclm2zw51my3nryvlsfwqkgps3xxa0xnhq4ly1bl";
+  };
+
+  dontConfigure = true;
+  dontBuild = true;
+  dontPatchELF = true; # We will do this manually in preFixup
+  dontStrip = true;
+
+  installPhase = ''
+    mkdir -p $out
+    cp -R * $out
+  '';
+  preFixup = ''
+    find $out -type f ! -name ".o" | while read f; do
+      patchelf "$f" > /dev/null 2>&1                                                             || continue
+      patchelf --set-interpreter $(cat ${stdenv.cc}/nix-support/dynamic-linker) "$f"             || true
+      patchelf --set-rpath ${lib.makeLibraryPath [ "$out" stdenv.cc.cc ncurses5 ]} "$f" || true
+    done
+  '';
+}

dependencies/python-overlay.nix

@@ -0,0 +1,32 @@
+{ lib, stdenv, fetchFromGitHub,
+  dtc
+}:
+
+stdenv.mkDerivation rec {
+  name = "spike";
+  pname = "riscv-isa-sim";
+  version = "1.1.1-dev";
+
+  src = fetchFromGitHub {
+    owner = "riscv-software-src";
+    repo = pname;
+    rev = "ac466a21df442c59962589ba296c702631e041b5";
+    sha256 = "sha256-1OLGEdj0dGnNREKZOrkAyKET7d2L+VFebOGm2oxtkHw=";
+  };
+
+  enableParallelBuilding = true;
+  # buildInputs = [ ];
+  nativeBuildInputs = [ dtc ];
+  configureFlags = [ "--enable-commitlog" "--enable-misaligned" ];
+
+  doCheck = false;
+  dontInstall = false;
+
+  meta = with lib; {
+    description = "Riscv golden-reference simulator Spike";
+    homepage    = "https://github.com/riscv-software-src/riscv-isa-sim";
+    license     = with licenses; [];
+    platforms   = platforms.unix;
+    maintainers = with maintainers; [];
+  };
+}

dependencies/riscv-gcc-toolchain-lowrisc.nix

@@ -0,0 +1,46 @@
+{ # Chosen toolchain subarchitecture, e.g. 'rv32imc'
+  riscv-arch
+
+  # Package set
+, pkgs
+}:
+
+# --------------------------
+# RISC-V GCC Toolchain Setup
+
+let
+  riscv-toolchain-ver = "8.2.0";
+  riscv-src = pkgs.fetchFromGitHub {
+    owner  = "lowRISC";
+    repo   = "lowrisc-toolchains";
+    rev    = "2cac2b9797d96a5c46d86d463c71e0a66926f473";
+    sha256 = "sha256-DNEkdJ5G8wpN2nQbD+nzvAQixWWGCG5RbJrXg5IRteg=";
+  };
+  #
+  # given an architecture like 'rv32i', this will generate the given
+  # toolchain derivation based on the above source code.
+  make-riscv-toolchain = arch:
+    pkgs.stdenv.mkDerivation rec {
+      name    = "riscv-${arch}-toolchain-${version}";
+      version = "${riscv-toolchain-ver}-${builtins.substring 0 7 src.rev}";
+      src     = riscv-src;
+
+      configureFlags   = [ "--with-arch=${arch}" ];
+      installPhase     = ":"; # 'make' installs on its own
+      # installPhase = ''
+      #   mkdir -p $out
+      #   cp -r * $out
+      # '';
+      hardeningDisable = [ "all" ];
+      enableParallelBuilding = true;
+
+      # Stripping/fixups break the resulting libgcc.a archives, somehow.
+      # Maybe something in stdenv that does this...
+      dontStrip = true;
+      dontFixup = true;
+
+      nativeBuildInputs = with pkgs; [ curl gawk texinfo bison flex gperf ];
+      buildInputs = with pkgs; [ libmpc mpfr gmp expat ];
+    };
+
+in make-riscv-toolchain riscv-arch

dependencies/riscv-isa-sim.nix

@@ -0,0 +1,13 @@
+{ lib, buildPythonPackage, fetchPypi,
+  okonomiyaki, attrs, six, enum34
+}:
+buildPythonPackage rec {
+  pname = "simplesat";
+  version = "0.8.2";
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0n6qm2gzwji19ykp3i6wm6vjw7dnn92h2flm42708fxh6lkz6hqr";
+  };
+  propagatedBuildInputs = [ okonomiyaki attrs six enum34 ];
+  doCheck = false;
+}