Support for Indy components

Author: wlandgraf

Dist/OpenApiIndy.pas

@@ -0,0 +1,131 @@
+unit OpenApiIndy;
+
+interface
+
+uses
+  SysUtils, Classes, OpenApiRest, IdHTTP;
+
+type
+  TIndyHTTP = class(TIdHTTP)
+  end;
+
+  TClientCreatedEvent = procedure(Client: TIdHttp) of object;
+
+  TIndyRestRequest = class(TRestRequest)
+  strict private
+    FOnClientCreated: TClientCreatedEvent;
+  public
+    constructor Create(AOnClientCreated: TClientCreatedEvent);
+    function Execute: IRestResponse; override;
+  end;
+
+  TIndyRestResponse = class(TInterfacedObject, IRestResponse)
+  strict private
+    FClient: TIndyHTTP;
+    FResponseBody: TBytes;
+  public
+    constructor Create(Client: TIndyHTTP; const ResponseBody: TBytes);
+    destructor Destroy; override;
+    function StatusCode: Integer;
+    function ContentAsString: string;
+    function ContentAsBytes: TBytes;
+    function GetHeader(const Name: string): string;
+  end;
+
+  TIndyRestRequestFactory = class(TInterfacedObject, IRestRequestFactory)
+  private
+    FOnClientCreated: TClientCreatedEvent;
+  public
+    function CreateRequest: IRestRequest;
+    property OnClientCreated: TClientCreatedEvent read FOnClientCreated write FOnClientCreated;
+  end;
+
+implementation
+
+{ TIndyRestRequestFactory }
+
+function TIndyRestRequestFactory.CreateRequest: IRestRequest;
+begin
+  Result := TIndyRestRequest.Create(FOnClientCreated);
+end;
+
+{ TIndyRestRequest }
+
+constructor TIndyRestRequest.Create(AOnClientCreated: TClientCreatedEvent);
+begin
+  inherited Create;
+  FOnClientCreated := AOnClientCreated;
+end;
+
+function TIndyRestRequest.Execute: IRestResponse;
+var
+  Client: TIndyHTTP;
+  I: Integer;
+  RequestBody: TStringStream;
+  ResponseBody: TBytesStream;
+begin
+  Client := TIndyHTTP.Create;
+  try
+    if Assigned(FOnClientCreated) then
+      FOnClientCreated(Client);
+
+    Client.HTTPOptions := Client.HTTPOptions + [hoNoProtocolErrorException, hoWantProtocolErrorContent];
+    RequestBody := nil;
+    if Body <> '' then
+      RequestBody := TStringStream.Create(Body, TEncoding.UTF8, False);
+    try
+      ResponseBody := TBytesStream.Create;
+      try
+        Client.Request.Accept := '';
+        for I := 0 to Headers.Count - 1 do
+          Client.Request.CustomHeaders.AddValue(Headers.Names[I], Headers.ValueFromIndex[I]);
+        Client.DoRequest(Self.Method, BuildUrl, RequestBody, ResponseBody, []);
+        Result := TIndyRestResponse.Create(Client, Copy(ResponseBody.Bytes, 0, ResponseBody.Size));
+        Client := nil;
+      finally
+        ResponseBody.Free;
+      end;
+    finally
+      RequestBody.Free;
+    end;
+  finally
+    Client.Free;
+  end;
+end;
+
+{ TIndyRestResponse }
+
+constructor TIndyRestResponse.Create(Client: TIndyHTTP; const ResponseBody: TBytes);
+begin
+  inherited Create;
+  FClient := Client;
+  FResponseBody := ResponseBody;
+end;
+
+destructor TIndyRestResponse.Destroy;
+begin
+  FClient.Free;
+  inherited;
+end;
+
+function TIndyRestResponse.GetHeader(const Name: string): string;
+begin
+  Result := FClient.Response.RawHeaders.Values[Name];
+end;
+
+function TIndyRestResponse.StatusCode: Integer;
+begin
+  Result := FClient.ResponseCode;
+end;
+
+function TIndyRestResponse.ContentAsBytes: TBytes;
+begin
+  Result := FResponseBody;
+end;
+
+function TIndyRestResponse.ContentAsString: string;
+begin
+  Result := TEncoding.UTF8.GetString(ContentAsBytes);
+end;
+
+end.

Dist/OpenApiSparkle.pas

@@ -102,7 +102,7 @@ function TSparkleRestResponse.ContentAsBytes: TBytes;
 
 function TSparkleRestResponse.ContentAsString: string;
 begin
-  Result := TEncoding.UTF8.GetString(FResponse.ContentAsBytes);
+  Result := TEncoding.UTF8.GetString(ContentAsBytes);
 end;
 
 end.

README.md

@@ -103,7 +103,39 @@ It will set the `Authorization` HTTP header with the token value prefixed by `Be
 
 ### Client compatibility
 
-Current the generated code doesn't require any dependency on 3rd party units, working with a plain Delphi install. The code is currently using `THttpClient` class from unit `System.Net.HttpClient` to perform the HTTP requests, so the client will only compile on Delphi versions that provide such class. An update is planned to support Indy in older Delphi versions.
+Current the generated code doesn't require any dependency on 3rd party units, working with a plain Delphi install. The code is currently using `THttpClient` class from unit `System.Net.HttpClient` to perform the HTTP requests, so the client will only compile on Delphi versions that provide such class.
+
+Alternatively, you can force the client to use Indy components to perform HTTP requests. For that, can use the following code snippet.
+
+```delphi
+uses {...}, OpenApiRest, OpenApiIndy;
+
+begin
+  // At the beginning of your application, set the DefaultRequestFactory
+  DefaultRequestFactory := TIndyRestRequestFactory.Create;
+end;
+```
+
+You can intercept the moment where a new `TIdHTTP` client is created - in case you want to setup specific properties like proxy or IO handlers. For that you can use a code like this:
+
+```delphi
+uses {...}, OpenApiRest, OpenApiIndy, IdHTTP;
+
+procedure TMainDataModule.IndyClientCreated(Client: TIdHTTP);
+begin
+  // Set extra Client properties here
+end;
+
+procedure TMainDataModule.DataModuleCreate(Sender: TObject);
+var
+  Factory: TIndyRestRequestFactory;
+begin
+  // At the beginning of your application, set the DefaultRequestFactory
+  Factory := TIndyRestRequestFactory.Create;
+  DefaultRequestFactory := Factory;
+  Factory.OnClientCreated := IndyClientCreated;
+end;
+```
 
 ## Compiling and running tests
 

Tests/PetStore3/PetStore3Client.pas

@@ -5,6 +5,7 @@ interface
 uses
   SysUtils, 
   OpenApiRest, 
+  OpenApiUtils, 
   PetStore3Json, 
   PetStore3Dtos;
 

Tests/TestPetStoreClient.pas

@@ -7,6 +7,8 @@ interface
 
 type
   TPetStoreClientTests = class(TTestCase)
+  public
+    procedure SetUp; override;
   published
     procedure CreateAndGetPet;
   end;
@@ -87,6 +89,11 @@ procedure TPetStoreClientTests.CreateAndGetPet;
   end;
 end;
 
+procedure TPetStoreClientTests.SetUp;
+begin
+  inherited;
+end;
+
 initialization
   RegisterTest(TPetStoreClientTests.Suite);