new

Author: kodamail

allclose.gs

@@ -0,0 +1,47 @@
+*
+* Help is in the end of this script.
+*
+function allclose( args )
+  _version='0.01r1'
+
+*  if( args = '' )
+*    help()
+*    return
+*  endif
+
+* serach for the largest file number
+  'q files'
+  i = 1
+  fmax = 0
+  while( 1 )
+    line = sublin( result, i )
+    if( line = '' ) ; break ; endif
+    num  = subwrd( line, 2 )
+    if( num = fmax + 1 ) ; fmax = fmax + 1 ; endif
+    i = i + 1
+  endwhile
+
+* close
+  say 'closing 'fmax' files'
+  f = fmax
+  while( f >= 1 )
+    'close 'f
+    f = f - 1
+  endwhile
+
+return
+
+*
+* help
+*
+function help()
+  say ' Name:'
+  say '   allclose '_version' - close all the opened files'
+  say ' '
+  say ' Usage:'
+  say '   allclose'
+  say ''
+  say ' Copyright (C) 2010 Chihiro Kodama'
+  say ' Distributed under GNU GPL (http://www.gnu.org/licenses/gpl.html)'
+  say ''
+return

allcolor.gs

@@ -0,0 +1,53 @@
+*
+* Help is in the end of this script.
+*
+function allcolor(args)
+  _version='0.01r1'
+
+  if( args = '' )
+    help()
+  endif
+
+  imax = 20
+  jmax = 10
+
+  c = 0
+  while( c <= 255 )
+    'set line 'c
+    i = math_fmod( c, imax )
+    j = ( c - i ) / imax
+
+    x1 = 0.5 + 0.5 * i
+    x2 = 0.5 + 0.5 * (i+1)
+    xmed = ( x1 + x2 ) / 2.0
+
+    y1 = 7.5 - 0.5 * j
+    y2 = 7.5 - 0.5 * (j-1)
+    ymed = ( y1 + y2 ) / 2.0
+
+    'draw recf 'x1' 'y1' 'x2' 'y2
+
+    'set strsiz 0.1 0.15'
+    'set string 0 c 0.15'
+    'draw string 'xmed' 'ymed' 'c
+
+    c = c + 1
+  endwhile
+
+return
+
+
+*
+* help
+*
+function help()
+  say ' Name:'
+  say '   allcolor '_version' - display all the colors'
+  say ' '
+  say ' Usage:'
+  say '   allcolor'
+  say ''
+  say ' Copyright (C) 2009-2011 Chihiro Kodama'
+  say ' Distributed under GNU GPL (http://www.gnu.org/licenses/gpl.html)'
+  say ''
+return

arg.gsf

@@ -0,0 +1,16 @@
+* get argument of z=x+iy in radian.
+function arg( x, y )
+  pi = 4 * math_atan(1.0)
+  if( x > 0 & y > 0 ) ; ret = math_atan( y / x )            ; endif
+  if( x < 0 & y > 0 ) ; ret = _pi - math_atan( y / (-x) )   ; endif
+  if( x < 0 & y < 0 ) ; ret = _pi + math_atan( y / x )      ; endif
+  if( x > 0 & y < 0 ) ; ret = 2*_pi - math_atan( (-y) / x ) ; endif
+
+  if( x = 0 & y > 0 ) ; ret = 0.5*_pi; endif
+  if( x = 0 & y < 0 ) ; ret = 1.5*_pi; endif
+  if( x > 0 & y = 0 ) ; ret = 0.0*_pi; endif
+  if( x < 0 & y = 0 ) ; ret = 1.0*_pi; endif
+  if( x = 0 & y = 0 ) ; ret = 9999; endif
+*say 'arg: ' % x % ' - ' % y % ' - ' % ret
+
+return ret

arrow.gs

@@ -0,0 +1,90 @@
+*
+* Help is in the end of this script
+*
+function clave( args )
+  _version='0.01r2'
+
+  if( args = '' )
+    help()
+    return
+  endif
+
+***** Default value *****
+  x1 = -1
+  y1 = -1
+  x2 = -1
+  y2 = -1
+  angle = 30
+  head = '20%'
+
+***** Arguement *****
+  i = 1
+  while( 1 )
+    arg = subwrd( args, i )
+    i = i + 1;
+    if( arg = '' ); break; endif
+
+    while(1)
+*** option
+      if( arg = '-angle'); angle=subwrd(args,i); i=i+1; break; endif
+      if( arg = '-head');  head=subwrd(args,i);  i=i+1; break; endif
+
+*** x1, y1, x2, y2
+      if( x1 = -1 ); x1 = arg; break; endif
+      if( y1 = -1 ); y1 = arg; break; endif
+      if( x2 = -1 ); x2 = arg; break; endif
+      if( y2 = -1 ); y2 = arg; break; endif
+
+      say 'syntax error : 'arg
+      return
+
+    endwhile
+  endwhile
+
+  if( substr( head, math_strlen(head), 1 ) = '%' )
+    head = substr( head, 1, math_strlen(head)-1 )
+    head = math_sqrt( (x2-x1)*(x2-x1) + (y2-y1)*(y2-y1) ) * head / 100.0
+  endif
+
+***** Draw *****
+  pi = 3.14159
+  alpha = math_atan2( y2-y1, x2-x1 )
+
+  'draw line 'x1' 'y1' 'x2' 'y2
+
+  x = x2 + head * math_cos( (180+angle)*pi/180 + alpha )
+  y = y2 + head * math_sin( (180+angle)*pi/180 + alpha )
+  'draw line 'x2' 'y2' 'x' 'y
+
+  x = x2 + head * math_cos( (180-angle)*pi/180 + alpha )
+  y = y2 + head * math_sin( (180-angle)*pi/180 + alpha )
+  'draw line 'x2' 'y2' 'x' 'y
+
+return
+
+
+*
+* help
+*
+function help()
+  say ' Name:'
+  say '   arrow '_version' - draw arrow '
+  say ' '
+  say ' Usage:'
+  say '   arrow x1 y1 x2 y2 [-angle angle] [-head head[%]]'
+  say ''
+  say '     x1 y1    : start point'
+  say '     x2 y2    ; end point'
+  say '     angle    : arrow head angle. default=30.'
+  say '     head[%]  : arrow head length. default=20%'
+  say '                If you specify %, '
+  say '                then the length will be set relative to the arrow length.'
+  say ''
+  say ' Note:'
+  say '     [arg-name]       : specify if needed'
+  say '     (arg1 | arg2)    : arg1 or arg2 must be specified'
+  say ''
+  say ' Copyright (C) 2009 Chihiro Kodama'
+  say ' Distributed under GNU GPL (http://www.gnu.org/licenses/gpl.html)'
+  say ''
+return

atoi.gsf

@@ -0,0 +1,17 @@
+***** char -> integer *****
+function atoi( char )
+  rc = gsfallow( 'on' )
+
+* avoid bug in GrADS 1.9 or less ('e' and '+' are assumed to be same)
+  a='1'char'5'
+  if( a = 1e+5 )  ; return 101 ; endif
+  if( a = '1+5' ) ; return 43  ; endif
+
+if( char = a ) ; return 43 ; endif
+  if( char = 'e' ) ; return 101 ; endif
+  i = 32
+  while( i <= 126 )
+    if( itoa(i) = char ) ; return i ; endif
+    i = i + 1
+  endwhile
+return -1

chcase.gsf

@@ -0,0 +1,25 @@
+* type = 'upper' or 'lower' or 'upper-first'
+function chcase( str, type )
+  ret = ''
+  i = 1
+  length = math_strlen( str )
+  while( i <= length )
+    c = substr( str, i, 1 )
+    c = atoi( c )
+    if( type = 'upper' & c >= 97 & c <= 122 )
+      c = c - 32
+    endif
+    if( type = 'upper_first' & c >= 97 & c <= 122 & i = 1 )
+      c = c - 32
+    endif
+    if( type = 'lower' & c >= 65 & c <= 90 )
+      c = c + 32
+    endif
+    if( type = 'upper_first' & c >= 65 & c <= 90 & i != 1 )
+      c = c + 32
+    endif
+    c = itoa( c )
+    ret = ret % c
+    i = i + 1
+  endwhile
+return ret