select eww window during each eww render

`eww-open-file' (and whatever other rendering tool might be used) uses
the size of the selected window to determine the width of lines in its
rendered output. this commit ensures that (even though eww can only
choose one window among all the windows that may be displaying it) if a
window is displaying an eww buffer, eww will select one of those
windows' sizes to render into, thus ensuring that at least one window
will be rendered correctly. in the common case, only a single window is
used to preview the output, which means this works perfectly.

in other words, the failing case was that if the window displaying a
markdown buffer was a different width than the window displaying the
eww (or other function) buffer, the eww window would render a page
suited for the width of the markdown buffer window, NOT the eww buffer
window. this commit ensures the existing eww buffer window is used to
determine the width of the rendered output, and adds a test to that
effect.

for testing, we could modify the width of the eww buffer window, and
ensure that eww renders to that changed width, which would be more
appropriate, but i don't know how to check what width eww renders
into. the given test should accomplish the same goal, by checking that
the eww buffer window is selected when eww renders into it.

Author: Danny McClanahan

markdown-mode.el

@@ -5373,6 +5373,9 @@ alive."
     (setq markdown-live-preview-currently-exporting-process nil))
   (message msg))
 
+(defun markdown-live-preview-get-displaying-window (window-data-list)
+  (or (caar window-data-list) (selected-window)))
+
 (defun markdown-live-preview-async-create-view-display (src-buf out-file msg)
   (unwind-protect
       (let (had-view-buffer window-data-list)
@@ -5382,8 +5385,11 @@ alive."
                                   markdown-live-preview-view-buffer)))
         (let ((view-buf
                (save-window-excursion
-                 (funcall
-                  markdown-live-preview-window-function out-file))))
+                 (with-selected-window
+                     (markdown-live-preview-get-displaying-window
+                      window-data-list)
+                   (funcall
+                    markdown-live-preview-window-function out-file)))))
           (with-current-buffer view-buf
             (add-hook 'kill-buffer-hook
                       #'markdown-live-preview-teardown-view t t))
@@ -5456,11 +5462,15 @@ the rendered output."
          (export-file (markdown-export (markdown-live-preview-get-filename)))
          ;; get positions in all windows currently displaying output buffer
          (window-data
-          (markdown-live-preview-window-serialize
-           markdown-live-preview-view-buffer))
+          (with-current-buffer src-buf
+            (markdown-live-preview-window-serialize
+             markdown-live-preview-view-buffer)))
          (view-buf
           (save-window-excursion
-            (funcall markdown-live-preview-window-function export-file))))
+            (with-selected-window
+                (markdown-live-preview-get-displaying-window window-data)
+              (funcall markdown-live-preview-window-function
+                       export-file)))))
     (markdown-live-preview-link-source-view-buffers src-buf view-buf)
     (with-current-buffer view-buf
       (add-hook 'kill-buffer-hook

tests/markdown-test.el

@@ -3363,6 +3363,61 @@ indented the same amount."
 (ert-deftest test-markdown-ext/live-preview-delete-exports-async ()
   (markdown-test/live-preview-delete-exports))
 
+(defvar markdown-test-eww-window nil)
+(defvar markdown-test-hit-advice nil)
+
+(defadvice eww-open-file (before markdown-set-window-width disable)
+  (setq markdown-test-hit-advice t)
+  (should (eq (selected-window) markdown-test-eww-window)))
+
+(defmacro markdown-eww-open-file-advice (&rest body)
+  `(progn
+     (ad-enable-advice #'eww-open-file 'before 'markdown-set-window-width)
+     (ad-activate #'eww-open-file)
+     ,@body
+     (ad-disable-advice #'eww-open-file 'before 'markdown-set-window-width)
+     (ad-activate #'eww-open-file)))
+
+(defun markdown-test/test-window-size-eww ()
+  (setq markdown-test-hit-advice nil)
+  (save-window-excursion
+    (markdown-test-temp-file "inline.text"
+      (let ((markdown-live-preview-idle-delay .01)
+            (windows (window-list))
+            (md-buf (current-buffer)))
+        (cl-loop for win in windows
+                 unless (eq win (selected-window))
+                 do (delete-window win))
+        (markdown-temp-eww
+         ;; below should create separate window to display eww
+         (markdown-live-preview-mode)
+         (markdown-test/live-preview-wait)
+         (setq markdown-test-eww-window
+               (get-buffer-window (get-buffer "*eww*")))
+         (should markdown-live-preview-view-buffer)
+         (with-selected-window (get-buffer-window md-buf)
+           (markdown-eww-open-file-advice
+            (if markdown-live-preview-do-sync
+                (markdown-live-preview-sync-export)
+              (markdown-live-preview-async-export))
+            (markdown-test/live-preview-wait)
+            (sit-for .1)
+            ;; at this point, `eww-render' should have finished, and eww should
+            ;; have redisplayed. the advice checks that, since there was a
+            ;; single window displaying the *eww* buffer, that window was used
+            ;; as the selected window so that eww renders with a width
+            ;; equal to the width of its window
+            (should (eq t markdown-test-hit-advice))))))))
+  (setq markdown-test-hit-advice nil))
+
+(ert-deftest test-markdown-ext/live-preview-window-size-sync ()
+  (let ((markdown-live-preview-do-sync t))
+    (markdown-test/test-window-size-eww)))
+
+(ert-deftest test-markdown-ext/live-preview-window-size-async ()
+  (let ((markdown-live-preview-do-sync nil))
+    (markdown-test/test-window-size-eww)))
+
 (provide 'markdown-test)
 
 ;;; markdown-test.el ends here