select eww window during each eww render

`eww-open-file' (and whatever other rendering tool might be used) uses
the size of the selected window to determine the width of lines in its
rendered output. this commit ensures that (even though eww can only
choose one window among all the windows that may be displaying it) if a
window is displaying an eww buffer, eww will select one of those
windows' sizes to render into, thus ensuring that at least one window
will be rendered correctly. in the common case, only a single window is
used to preview the output, which means this works perfectly.

in other words, the failing case was that if the window displaying a
markdown buffer was a different width than the window displaying the
eww (or other function) buffer, the eww window would render a page
suited for the width of the markdown buffer window, NOT the eww buffer
window. this commit ensures the existing eww buffer window is used to
determine the width of the rendered output, and adds a test to that
effect.

for testing, we could modify the width of the eww buffer window, and
ensure that eww renders to that changed width, which would be more
appropriate, but i don't know how to check what width eww renders
into. the given test should accomplish the same goal, by checking that
the eww buffer window is selected when eww renders into it.

check for libxml when trying to use eww

ensure eww renders to correct size at first export

also refactor duplicated code to display exported buffer into shared
function for sync and async export

Author: Danny McClanahan

markdown-mode.el

@@ -5327,9 +5327,13 @@ buffer. Inverse of `markdown-live-preview-view-buffer'.")
   "Status of sync or async live preview in current buffer.")
 (make-variable-buffer-local 'markdown-live-preview-current-buffer-sync-async)
 
+(defun markdown-live-preview-has-eww-p ()
+  (and (require 'eww nil t)
+       (fboundp 'libxml-parse-html-region)))
+
 (defun markdown-live-preview-window-eww (file)
   "A `markdown-live-preview-window-function' for previewing with `eww'."
-  (if (require 'eww nil t)
+  (if (markdown-live-preview-has-eww-p)
       (progn
         (eww-open-file file)
         (get-buffer "*eww*"))
@@ -5373,28 +5377,41 @@ alive."
     (setq markdown-live-preview-currently-exporting-process nil))
   (message msg))
 
+(defun markdown-live-preview-get-displaying-window (window-data-list)
+  (or (caar window-data-list)
+      ;; if not displaying buf in any window, then make a new window and display
+      ;; it there
+      (markdown-display-buffer-other-window (window-buffer))))
+
+(defun markdown-live-preview-create-display (out-file &optional src-buf)
+  (let* ((src-buf (or src-buf (current-buffer)))
+         (had-view-buffer
+          (with-current-buffer src-buf markdown-live-preview-view-buffer))
+         (window-data-list
+          (with-current-buffer src-buf
+            (markdown-live-preview-window-serialize
+             markdown-live-preview-view-buffer)))
+         (display-win
+          (markdown-live-preview-get-displaying-window window-data-list))
+         (view-buf
+          (save-window-excursion
+            (with-selected-window display-win
+              (funcall markdown-live-preview-window-function out-file)))))
+    (markdown-live-preview-link-source-view-buffers src-buf view-buf)
+    (with-current-buffer view-buf
+      (add-hook 'kill-buffer-hook #'markdown-live-preview-teardown-view t t))
+    (with-current-buffer src-buf
+      (if had-view-buffer
+          (if window-data-list
+              (cl-loop for window-data in window-data-list
+                       do (markdown-live-preview-window-deserialize
+                           window-data view-buf))
+            (delete-window display-win))
+        (set-window-buffer display-win view-buf)))))
+
 (defun markdown-live-preview-async-create-view-display (src-buf out-file msg)
   (unwind-protect
-      (let (had-view-buffer window-data-list)
-        (with-current-buffer src-buf
-          (setq had-view-buffer markdown-live-preview-view-buffer
-                window-data-list (markdown-live-preview-window-serialize
-                                  markdown-live-preview-view-buffer)))
-        (let ((view-buf
-               (save-window-excursion
-                 (funcall
-                  markdown-live-preview-window-function out-file))))
-          (with-current-buffer view-buf
-            (add-hook 'kill-buffer-hook
-                      #'markdown-live-preview-teardown-view t t))
-          (markdown-live-preview-link-source-view-buffers
-           src-buf view-buf)
-          (with-current-buffer src-buf
-            (if had-view-buffer
-                (cl-loop for window-data in window-data-list
-                         do (markdown-live-preview-window-deserialize
-                             window-data view-buf))
-              (markdown-display-buffer-other-window view-buf)))))
+      (markdown-live-preview-create-display out-file src-buf)
     (markdown-live-preview-async-cleanup-export src-buf msg)))
 
 (defmacro markdown-silence-messages (&rest body)
@@ -5452,33 +5469,16 @@ Emacs using `markdown-live-preview-window-function' Return the buffer displaying
 the rendered output."
   (interactive)
   (let* ((markdown-live-preview-currently-exporting t)
-         (src-buf (current-buffer))
-         (export-file (markdown-export (markdown-live-preview-get-filename)))
-         ;; get positions in all windows currently displaying output buffer
-         (window-data
-          (markdown-live-preview-window-serialize
-           markdown-live-preview-view-buffer))
-         (view-buf
-          (save-window-excursion
-            (funcall markdown-live-preview-window-function export-file))))
-    (markdown-live-preview-link-source-view-buffers src-buf view-buf)
-    (with-current-buffer view-buf
-      (add-hook 'kill-buffer-hook
-                #'markdown-live-preview-teardown-view t t))
-    (with-current-buffer src-buf
-      ;; reset all windows displaying output buffer to where they were,
-      ;; now with the new output
-      (mapc (lambda (data)
-              (markdown-live-preview-window-deserialize data view-buf))
-            window-data)
-      ;; delete html editing buffer
-      (let ((buf (get-file-buffer export-file)))
-        (when buf (kill-buffer buf)))
-      (when (and export-file (file-exists-p export-file)
-                 (eq markdown-live-preview-delete-export
-                     'delete-on-export))
-        (delete-file export-file))
-      markdown-live-preview-view-buffer)))
+         (out-file (markdown-export (markdown-live-preview-get-filename))))
+    (markdown-live-preview-create-display out-file)
+    ;; delete html editing buffer
+    (let ((buf (get-file-buffer out-file)))
+      (when buf (kill-buffer buf)))
+    (when (and out-file (file-exists-p out-file)
+               (eq markdown-live-preview-delete-export
+                   'delete-on-export))
+      (delete-file out-file))
+    markdown-live-preview-view-buffer))
 
 (defun markdown-live-preview-update (buf)
   (lambda () (with-current-buffer buf (markdown-live-preview-async-export))))
@@ -5491,8 +5491,7 @@ the rendered output."
       (progn
         (add-hook
          'after-save-hook #'markdown-live-preview-do-sync-preview t t)
-        (markdown-display-buffer-other-window
-         (markdown-live-preview-sync-export)))
+        (markdown-live-preview-sync-export))
     (setq markdown-live-preview-idle-timer
           (run-with-idle-timer
            markdown-live-preview-idle-delay t
@@ -5539,9 +5538,8 @@ the rendered output."
     (markdown-live-preview-teardown-async)))
 
 (defun markdown-display-buffer-other-window (buf)
-  (let ((cur-buf (current-buffer)))
-    (switch-to-buffer-other-window buf)
-    (set-buffer cur-buf)))
+  (let ((pop-up-windows t))
+    (select-window (display-buffer buf t))))
 
 (defun markdown-live-preview-switch-to-output ()
   (interactive)
@@ -5564,10 +5562,7 @@ or `markdown-live-preview-sync-export' and update this buffer's contents."
 
 (defun markdown-live-preview-do-sync-preview ()
   (unless markdown-live-preview-currently-exporting
-    (if (buffer-live-p markdown-live-preview-view-buffer)
-        (markdown-live-preview-sync-export)
-      (markdown-display-buffer-other-window
-       (markdown-live-preview-sync-export)))))
+    (markdown-live-preview-sync-export)))
 
 
 ;;; Links =====================================================================

tests/markdown-test.el

@@ -3290,7 +3290,7 @@ indented the same amount."
 
 (defmacro markdown-temp-eww (&rest body)
   `(progn
-     ,@(if (require 'eww nil t) body
+     ,@(if (markdown-live-preview-has-eww-p) body
          `((ad-enable-advice #'markdown-live-preview-window-eww
                              'around 'markdown-create-fake-eww)
            (ad-activate #'markdown-live-preview-window-eww)
@@ -3324,7 +3324,7 @@ indented the same amount."
 
 (ert-deftest test-markdown-ext/live-preview-exports-sync ()
   (let ((markdown-live-preview-do-sync t))
-    (unless (require 'eww nil t)
+    (unless (markdown-live-preview-has-eww-p)
       (should-error (markdown-live-preview-sync-export)))
     (markdown-test/live-preview-exports)))
 
@@ -3363,6 +3363,98 @@ indented the same amount."
 (ert-deftest test-markdown-ext/live-preview-delete-exports-async ()
   (markdown-test/live-preview-delete-exports))
 
+(defvar markdown-test-eww-window nil)
+(defvar markdown-test-hit-advice nil)
+
+(defadvice eww-open-file (before markdown-test-set-window-width disable)
+  (setq markdown-test-hit-advice t)
+  (should (eq (selected-window) markdown-test-eww-window)))
+
+(defadvice get-buffer-create (before markdown-set-window-width-mock disable)
+  (when (let ((buf (ad-get-arg 0))) (and (stringp buf) (string= buf "*eww*")))
+    (setq markdown-test-hit-advice t)
+    (should (eq (selected-window) markdown-test-eww-window))))
+
+(defmacro markdown-eww-open-file-advice (&rest body)
+  (if (markdown-live-preview-has-eww-p)
+      `(progn
+         (ad-enable-advice #'eww-open-file 'before
+                           'markdown-test-set-window-width)
+         (ad-activate #'eww-open-file)
+         ,@body
+         (ad-disable-advice #'eww-open-file 'before
+                            'markdown-test-set-window-width)
+         (ad-activate #'eww-open-file))
+    `(progn
+       (ad-enable-advice #'get-buffer-create 'before 
+                         'markdown-set-window-width-mock)
+       (ad-activate #'get-buffer-create)
+       ,@body
+       (ad-disable-advice #'get-buffer-create 'before
+                          'markdown-set-window-width-mock)
+       (ad-activate #'get-buffer-create))))
+
+(defadvice markdown-live-preview-get-displaying-window
+    (after markdown-test-get-test-window disable)
+  (setq markdown-test-eww-window ad-return-value))
+
+(defmacro markdown-initial-window-create-advice (&rest body)
+  `(progn
+     (ad-enable-advice #'markdown-live-preview-get-displaying-window
+                       'after 'markdown-test-get-test-window)
+     (ad-activate #'markdown-live-preview-get-displaying-window)
+     ,@body
+     (ad-disable-advice #'markdown-live-preview-get-displaying-window
+                        'after 'markdown-test-get-test-window)
+     (ad-activate #'markdown-live-preview-get-displaying-window)))
+
+(defun markdown-test/test-window-usage-live-preview ()
+  (setq markdown-test-hit-advice nil)
+  (save-window-excursion
+    (markdown-test-temp-file "inline.text"
+      (let ((markdown-live-preview-idle-delay .01)
+            (windows (window-list))
+            (md-buf (current-buffer)))
+        (cl-loop for win in windows
+                 unless (eq win (selected-window))
+                 do (delete-window win))
+        ;; note that advices are used in this test to supply `should' conditions
+        (markdown-temp-eww
+         ;; test that first window created by
+         ;; `markdown-live-preview-get-displaying-window' is the same window
+         ;; that is used to finally render the buffer, on the first try
+         (markdown-eww-open-file-advice
+          (markdown-initial-window-create-advice
+           (if markdown-live-preview-do-sync
+               (markdown-live-preview-sync-export)
+             (markdown-live-preview-async-export))
+           (markdown-test/live-preview-wait)
+           (should (eq t markdown-test-hit-advice))
+           (setq markdown-test-hit-advice nil))
+          (setq markdown-test-eww-window
+                (get-buffer-window (get-buffer "*eww*")))
+          (should markdown-live-preview-view-buffer)
+          (with-selected-window (get-buffer-window md-buf)
+            (if markdown-live-preview-do-sync
+                (markdown-live-preview-sync-export)
+              (markdown-live-preview-async-export))
+            (markdown-test/live-preview-wait)
+            ;; at this point, `eww-render' should have finished, and eww should
+            ;; have redisplayed. the advice checks that, since there was a
+            ;; single window displaying the *eww* buffer, that window was used
+            ;; as the selected window so that eww renders with a width
+            ;; equal to the width of its window
+            (should (eq t markdown-test-hit-advice))))))))
+  (setq markdown-test-hit-advice nil))
+
+(ert-deftest test-markdown-ext/live-preview-window-size-sync ()
+  (let ((markdown-live-preview-do-sync t))
+    (markdown-test/test-window-usage-live-preview)))
+
+(ert-deftest test-markdown-ext/live-preview-window-size-async ()
+  (let ((markdown-live-preview-do-sync nil))
+    (markdown-test/test-window-usage-live-preview)))
+
 (provide 'markdown-test)
 
 ;;; markdown-test.el ends here