Move to Gradle Kotlin DSL & maven-publish plugin

Author: slonopotamus

build.gradle

@@ -0,0 +1,164 @@
+import com.github.benmanes.gradle.versions.VersionsPlugin
+import org.gradle.api.tasks.testing.logging.TestExceptionFormat
+
+val ossrhUsername: String? = System.getenv("OSSRH_USERNAME")
+val ossrhPassword: String? = System.getenv("OSSRH_PASSWORD")
+val signingPassword: String? = System.getenv("SIGNING_PASSWORD")
+val gitCommit = System.getenv("TRAVIS_COMMIT") ?: ""
+
+tasks.wrapper {
+    gradleVersion = "5.4"
+    distributionType = Wrapper.DistributionType.ALL
+}
+
+plugins {
+    id("com.github.ben-manes.versions") version "0.21.0"
+    idea
+}
+
+allprojects {
+    apply<IdeaPlugin>()
+    apply<VersionsPlugin>()
+
+    repositories {
+        mavenCentral()
+    }
+}
+
+val javaVersion = JavaVersion.VERSION_1_8
+
+idea {
+    project.jdkName = javaVersion.name
+}
+
+subprojects {
+    group = "ru.bozaro.gitlfs"
+    version = "0.13.0-SNAPSHOT"
+
+    apply<JavaPlugin>()
+    apply<MavenPublishPlugin>()
+
+    configure<JavaPluginExtension> {
+        sourceCompatibility = javaVersion
+        targetCompatibility = javaVersion
+    }
+
+    val compile by configurations
+    val testCompile by configurations
+
+    dependencies {
+        compile("org.jetbrains:annotations:17.0.0")
+
+        testCompile("com.google.guava:guava:27.1-jre")
+        testCompile("org.testng:testng:6.14.3")
+    }
+
+    idea {
+        module {
+            isDownloadJavadoc = true
+            isDownloadSources = true
+
+            // Workaround for https://youtrack.jetbrains.com/issue/IDEA-175172
+            outputDir = file("build/classes/main")
+            testOutputDir = file("build/classes/test")
+        }
+    }
+
+    tasks.withType<JavaCompile> {
+        options.encoding = "UTF-8"
+    }
+
+    tasks.withType<Test> {
+        useTestNG {
+            testLogging {
+                exceptionFormat = TestExceptionFormat.FULL
+                showStandardStreams = true
+            }
+        }
+    }
+
+    val javadoc by tasks.getting(Javadoc::class) {
+        (options as? CoreJavadocOptions)?.addStringOption("Xdoclint:none", "-quiet")
+    }
+
+    val javadocJar by tasks.creating(Jar::class) {
+        from(javadoc)
+        archiveClassifier.set("javadoc")
+    }
+
+    val sourcesJar by tasks.creating(Jar::class) {
+        val sourceSets: SourceSetContainer by project
+        from(sourceSets["main"].allSource)
+        archiveClassifier.set("sources")
+    }
+
+    val secretKeyRingFile = "${rootProject.projectDir}/secring.gpg"
+
+    if (signingPassword != null && file(secretKeyRingFile).exists()) {
+        extra["signing.secretKeyRingFile"] = secretKeyRingFile
+        extra["signing.keyId"] = "4B49488E"
+        extra["signing.password"] = signingPassword
+
+        configure<SigningExtension> {
+            val publications: PublicationContainer by project
+            sign(publications)
+        }
+    }
+
+    configure<PublishingExtension> {
+        publications {
+            create<MavenPublication>(project.name) {
+                from(components["java"])
+
+                artifact(sourcesJar)
+                artifact(javadocJar)
+
+                pom {
+                    url.set("https://github.com/bozaro/git-lfs-java")
+
+                    scm {
+                        connection.set("scm:git:git://github.com/bozaro/git-lfs-java.git")
+                        tag.set(gitCommit)
+                        url.set("https://github.com/bozaro/git-lfs-java")
+                    }
+
+                    licenses {
+                        license {
+                            name.set("Lesser General Public License, version 3 or greater")
+                            url.set("http://www.gnu.org/licenses/lgpl.html")
+                        }
+                    }
+
+                    developers {
+                        developer {
+                            id.set("bozaro")
+                            name.set("Artem V. Navrotskiy")
+                            email.set("[email protected]")
+                        }
+
+                        developer {
+                            id.set("slonopotamus")
+                            name.set("Marat Radchenko")
+                            email.set("[email protected]")
+                        }
+                    }
+                }
+            }
+        }
+
+        if (ossrhUsername != null) {
+            repositories {
+                maven {
+                    val releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
+                    val snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
+                    url = uri(if (version.toString().endsWith("SNAPSHOT")) snapshotsRepoUrl else releasesRepoUrl)
+
+                    credentials {
+                        username = ossrhUsername
+                        password = ossrhPassword
+                    }
+                }
+            }
+        }
+    }
+}

build.gradle.kts

@@ -0,0 +1,10 @@
+description = "Java Git-LFS client library"
+
+dependencies {
+    compile(project(":gitlfs-common"))
+    compile("org.apache.httpcomponents:httpclient:4.5.8")
+    compile("org.slf4j:slf4j-api:1.7.26")
+
+    testCompile("org.yaml:snakeyaml:1.24")
+    testRuntimeOnly("org.slf4j:slf4j-simple:1.7.26")
+}

gitlfs-client/build.gradle

@@ -0,0 +1,6 @@
+description = "Java Git-LFS common structures"
+
+dependencies {
+    compile("com.fasterxml.jackson.core:jackson-databind:2.9.8")
+    compile("com.google.guava:guava:27.1-jre")
+}

gitlfs-client/build.gradle.kts

@@ -0,0 +1,10 @@
+description = "Java Git-LFS server implementation-free library"
+
+dependencies {
+    compile(project(":gitlfs-common"))
+    compile("javax.servlet:javax.servlet-api:4.0.1")
+
+    testCompile(project(":gitlfs-client"))
+    testCompile("org.eclipse.jetty:jetty-servlet:9.4.15.v20190215")
+    testRuntimeOnly("org.slf4j:slf4j-simple:1.7.26")
+}