forked from WDR/WDR
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathwdr.bat
276 lines (240 loc) · 9.74 KB
/
wdr.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
@echo off
call :main %* & exit /b
:err
setlocal
echo %* 1>&2
exit /b
:usage
setlocal
call :err Usage:
call :err wdr environment [script] [script-args]
exit /b
:file_runtimes
call :err ######################################################################
call :err ## Runtime setup using runtimes.bat is deprecated ##
call :err ## and will be removed in the next version ##
call :err ######################################################################
call %WDR_HOME%\runtimes.default.bat
call %WDR_HOME%\runtimes.bat
if [%WAS_RUNTIME%] == [was61] set RUNTIME_NAME=was61
if [%WAS_RUNTIME%] == [was61_client] set RUNTIME_NAME=was61
if [%WAS_RUNTIME%] == [was7] set RUNTIME_NAME=was70
if [%WAS_RUNTIME%] == [was7_client] set RUNTIME_NAME=was70
if [%WAS_RUNTIME%] == [was70] set RUNTIME_NAME=was70
if [%WAS_RUNTIME%] == [was70_client] set RUNTIME_NAME=was70
if [%WAS_RUNTIME%] == [was8] set RUNTIME_NAME=was80
if [%WAS_RUNTIME%] == [was8_client] set RUNTIME_NAME=was80
if [%WAS_RUNTIME%] == [was80] set RUNTIME_NAME=was80
if [%WAS_RUNTIME%] == [was80_client] set RUNTIME_NAME=was80
if [%WAS_RUNTIME%] == [was85] set RUNTIME_NAME=was85
if [%WAS_RUNTIME%] == [was85_client] set RUNTIME_NAME=was85
if [%WAS_RUNTIME%] == [was855] set RUNTIME_NAME=was855
if [%WAS_RUNTIME%] == [was855_client] set RUNTIME_NAME=was855
if [%WAS_RUNTIME%] == [was90] set RUNTIME_NAME=was90
if [%WAS_RUNTIME%] == [was90_client] set RUNTIME_NAME=was90
if [%RUNTIME_NAME%] == [was61] (
set WAS_HOME=%WAS61_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS61_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS61_RUNTIME_HOME%\runtimes\com.ibm.ws.admin.client_6.1.0.jar;%WAS61_RUNTIME_HOME%\plugins\com.ibm.ws.security.crypto_6.1.0.jar
set JYTHON_VERSION=%WAS61_JYTHON_VERSION%
) else if [%RUNTIME_NAME%] == [was70] (
set WAS_HOME=%WAS70_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS70_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS70_JAVA_HOME%\runtimes\com.ibm.ws.admin.client_7.0.0.jar;%WAS70_JAVA_HOME%\plugins\com.ibm.ws.security.crypto.jar
set JYTHON_VERSION=%WAS70_JYTHON_VERSION%
) else if [%RUNTIME_NAME%] == [was80] (
set WAS_HOME=%WAS80_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS80_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS80_JAVA_HOME%\runtimes\com.ibm.ws.admin.client_8.0.0.jar;%WAS80_JAVA_HOME%\plugins\com.ibm.ws.security.crypto.jar
set JYTHON_VERSION=%WAS80_JYTHON_VERSION%
) else if [%RUNTIME_NAME%] == [was85] (
set WAS_HOME=%WAS85_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS85_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS85_RUNTIME_HOME%\runtimes\com.ibm.ws.admin.client_8.5.0.jar;%WAS85_RUNTIME_HOME%\plugins\com.ibm.ws.security.crypto.jar
set JYTHON_VERSION=%WAS85_JYTHON_VERSION%
) else if [%RUNTIME_NAME%] == [was855] (
set WAS_HOME=%WAS855_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS855_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS855_RUNTIME_HOME%\runtimes\com.ibm.ws.admin.client_8.5.0.jar;%WAS855_RUNTIME_HOME%\plugins\com.ibm.ws.security.crypto.jar
set JYTHON_VERSION=%WAS855_JYTHON_VERSION%
) else if [%RUNTIME_NAME%] == [was90] (
set WAS_HOME=%WAS90_RUNTIME_HOME%
set WAS_JAVA_HOME=%WAS90_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WAS90_RUNTIME_HOME%\runtimes\com.ibm.ws.admin.client_9.0.jar;%WAS90_RUNTIME_HOME%\plugins\com.ibm.ws.security.crypto.jar
set JYTHON_VERSION=%WAS90_JYTHON_VERSION%
) else (
call :err Unknown runtime %WAS_RUNTIME%
exit /b 1
)
exit /b 0
:dir_runtimes
if exist %USERPROFILE%\.wdr\runtimes\%WAS_RUNTIME%.bat (
call %USERPROFILE%\.wdr\runtimes\%WAS_RUNTIME%.bat
) else if exist %WDR_HOME%\runtimes\%WAS_RUNTIME%.bat (
call %WDR_HOME%\runtimes\%WAS_RUNTIME%.bat
) else if exist %WDR_HOME%\runtimes.default\%WAS_RUNTIME%.bat (
call %WDR_HOME%\runtimes.default\%WAS_RUNTIME%.bat
) else (
call :err Unknown runtime %WAS_RUNTIME%
exit /b 1
)
set RUNTIME_NAME=%WAS_RUNTIME%
exit /b 0
:runtimes
if exist "%WDR_HOME%\runtimes.bat" (
call :file_runtimes || exit /b
) else (
call :dir_runtimes || exit /b
)
if [%WAS_JAVA_HOME%] == [] (
set WAS_JAVA_HOME=%WAS_HOME%\java
)
if [%JYTHON_HOME%] == [] (
set JYTHON_HOME=%WAS_HOME%/optionalLibraries/jython
)
if [%JYTHON_PATH%] == [] (
set JYTHON_PATH=%JYTHON_HOME%\Lib
if exist %JYTHON_HOME%\Lib\site-packages (
set JYTHON_PATH=%JYTHON_PATH%;%JYTHON_HOME%\Lib\site-packages
)
)
exit /b
:setup
call :runtimes || exit /b 1
set JAVA_HOME=%WAS_JAVA_HOME%
set WSADMIN_CLASS_PATH=%WSADMIN_CLASS_PATH%
set JYTHON_VERSION=%JYTHON_VERSION%
if [%PERFJAVAOPTIONS%] == [] (
set PERFJAVAOPTIONS=-Xms128m -Xmx512m -Xj9 -Xquickstart
)
set JYTHON_CACHEDIR=%USERPROFILE%\.wdr\cache\%RUNTIME_NAME%
set TMPDIR=%USERPROFILE%\.wdr\tmp\%TARGET_ENV%
set WORKSPACE=%USERPROFILE%\.wdr\wstemp\%TARGET_ENV%
set USER_ROOT=%USERPROFILE%\.wdr\environments\%TARGET_ENV%
set WSADMIN_PROPERTIES=%USER_ROOT%\wsadmin.properties
set SOAP_PROPERTIES=%USER_ROOT%\soap.properties
set SSL_CLIENT_PROPS=%USER_ROOT%\ssl.client.props
if not exist %USER_ROOT% (
call :err Environment %TARGET_ENV% does not exist
exit /b 1
) else (
if not exist %WSADMIN_PROPERTIES% (
call :err Environment %TARGET_ENV% is incomplete
call :err %WSADMIN_PROPERTIES% not found
exit /b 1
)
if not exist %SOAP_PROPERTIES% (
call :err Environment %TARGET_ENV% is incomplete
call :err %SOAP_PROPERTIES% not found
exit /b 1
)
if not exist %SSL_CLIENT_PROPS% (
call :err Environment %TARGET_ENV% is incomplete
call :err %SSL_CLIENT_PROPS% not found
exit /b 1
)
)
if [%CUSTOM_PROFILE%] == [] (
set WDR_PROFILE=%WDR_HOME%\profile.py
) else (
set WDR_PROFILE=%WDR_HOME%\profile.py;%CUSTOM_PROFILE%
)
set JYTHON_PATH=%JYTHON_PATH%;%WDR_HOME%\lib\common
if [%JYTHON_VERSION%] == [2.1] (
set USE_JYTHON_21=true
set JYTHON_PATH=%JYTHON_PATH%;%WDR_HOME%\lib\legacy
) else (
set USE_JYTHON_21=false
)
if exist %USERPROFILE%\.wdr\lib (
for /d %%L in (%USERPROFILE%\.wdr\lib\*) do set JYTHON_PATH=%JYTHON_PATH%;%%L
)
if [%EXTRA_PYTHON_PATH%] == [] (
set JYTHON_PATH=%JYTHON_PATH%;%EXTRA_PYTHON_PATH%
)
set JYTHON_PATH=%JYTHON_PATH%;.
exit /b &(
set JAVA_HOME=%JAVA_HOME%
)
:run_interactive
"%JAVA_HOME%\jre\bin\java" ^
-Dcom.ibm.ws.scripting.defaultLang=jython ^
-Dcom.ibm.ws.scripting.usejython21=%USE_JYTHON_21% ^
-Dcom.ibm.ws.scripting.traceString=com.ibm.*=all=disabled ^
-Duser.root=%USER_ROOT:\=/% ^
-Dpython.path=%JYTHON_PATH% ^
-Dpython.home=%JYTHON_HOME% ^
-Dpython.cachedir=%JYTHON_CACHEDIR% ^
-Djava.io.tmpdir=%TMPDIR% ^
-Dwebsphere.workspace.root=%WORKSPACE% ^
-Dcom.ibm.ws.scripting.profiles=%WDR_PROFILE% ^
-Dcom.ibm.SOAP.ConfigURL=file:///%SOAP_PROPERTIES:\=/% ^
-Dcom.ibm.SSL.ConfigURL=file:///%SSL_CLIENT_PROPS:\=/% ^
%WAS_DEBUG% ^
-Dws.output.encoding=console ^
-Dcom.ibm.ws.scripting.apptimeout=1800 ^
-Djava.util.logging.manager=com.ibm.ws.bootstrap.WsLogManager ^
-Djava.util.logging.configureByServer=true ^
-Dcom.ibm.websphere.thinclient=true ^
%PERFJAVAOPTIONS% ^
-Dcom.ibm.ws.scripting.wsadminprops=%WSADMIN_PROPERTIES% ^
-Duser.install.root=%WAS_HOME:\=/% ^
-Dwas.install.root=%WAS_HOME:\=/% ^
-Dcom.ibm.ws.scripting.exceptionPropagation=thrown ^
-cp %WSADMIN_CLASS_PATH% ^
com.ibm.ws.scripting.WasxShell
exit /b
:run_script
"%JAVA_HOME%\jre\bin\java" ^
-Dcom.ibm.ws.scripting.defaultLang=jython ^
-Dcom.ibm.ws.scripting.usejython21=%USE_JYTHON_21% ^
-Dcom.ibm.ws.scripting.traceString=com.ibm.*=all=disabled ^
-Duser.root=%USER_ROOT:\=/% ^
-Dpython.path=%JYTHON_PATH% ^
-Dpython.home=%JYTHON_HOME% ^
-Dpython.cachedir=%JYTHON_CACHEDIR% ^
-Djava.io.tmpdir=%TMPDIR% ^
-Dwebsphere.workspace.root=%WORKSPACE% ^
-Dcom.ibm.ws.scripting.profiles=%WDR_PROFILE% ^
-Dcom.ibm.SOAP.ConfigURL=file:///%SOAP_PROPERTIES:\=/% ^
-Dcom.ibm.SSL.ConfigURL=file:///%SSL_CLIENT_PROPS:\=/% ^
%WAS_DEBUG% ^
-Dws.output.encoding=console ^
-Dcom.ibm.ws.scripting.apptimeout=1800 ^
-Djava.util.logging.manager=com.ibm.ws.bootstrap.WsLogManager ^
-Djava.util.logging.configureByServer=true ^
-Dcom.ibm.websphere.thinclient=true ^
%PERFJAVAOPTIONS% ^
-Dcom.ibm.ws.scripting.wsadminprops=%WSADMIN_PROPERTIES% ^
-Duser.install.root=%WAS_HOME:\=/% ^
-Dwas.install.root=%WAS_HOME:\=/% ^
-Dcom.ibm.ws.scripting.exceptionPropagation=thrown ^
-cp %WSADMIN_CLASS_PATH% ^
com.ibm.ws.scripting.WasxShell ^
-f %WDR_SCRIPT% ^
%1 %2 %3 %4 %5 %6 %7 %8 %9
exit /b
:run
if [%WDR_SCRIPT%] == [] (
call :run_interactive
) else (
call :run_script %1 %2 %3 %4 %5 %6 %7 %8 %9
)
exit /b
:main
setlocal
set WDR_HOME=%~dp0
set WAS_DEBUG=
set WAS_RUNTIME=%1
shift
set TARGET_ENV=%1
shift
set WDR_SCRIPT=%1
shift
if [%TARGET_ENV%] == [] (
call :usage
exit /b 1
)
call :setup || exit /b
call :run %1 %2 %3 %4 %5 %6 %7 %8 %9
exit /b