build.gradle

plugins {
    id "org.jetbrains.gradle.plugin.idea-ext" version "1.1.7"
}
subprojects {
    apply plugin: 'java-library'
    apply plugin: 'idea'
    
    java.toolchain.languageVersion = JavaLanguageVersion.of(21)

    version = "${minecraft_version}-${mod_version}"

    jar {
        manifest {
            attributes([
                'Specification-Title'     : mod_name,
                'Specification-Vendor'    : mod_author,
                'Specification-Version'   : project.jar.archiveVersion,
                'Implementation-Title'    : project.name,
                'Implementation-Version'  : project.jar.archiveVersion,
                'Implementation-Vendor'   : mod_author,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Timestampe'              : System.currentTimeMillis(),
                'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                'Build-On-Minecraft'      : minecraft_version,
            ])
        }
    }
    
    repositories {
        mavenLocal()
//        mavenCentral()

        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }

        maven {
            name = "Modrinth"
            url = "https://api.modrinth.com/maven"
            content {
                includeGroup "maven.modrinth"
            }
        }
    }

    dependencies {
        compileOnly "org.projectlombok:lombok:${project.lombok_version}"
        annotationProcessor "org.projectlombok:lombok:${project.lombok_version}"
        testCompileOnly "org.projectlombok:lombok:${project.lombok_version}"
        testAnnotationProcessor "org.projectlombok:lombok:${project.lombok_version}"
    }

    tasks.withType(JavaCompile).configureEach {

        it.options.encoding = 'UTF-8'
        it.options.release = 21
    }

    // Disables Gradle's custom module metadata from being published to maven. The
    // metadata includes mapped dependencies which are not reasonably consumable by
    // other mod developers.
//    tasks.withType(GenerateModuleMetadata) {
//
//        enabled = false
//    }

    idea {
        module {
            downloadSources = true
            downloadJavadoc = true
        }
    }
}