Add support to case templates

Author: José Valim

lib/ex_unit/lib/ex_unit.ex

@@ -35,9 +35,13 @@ defmodule ExUnit do
 
       bin/elixir assertion_test.exs
 
-  ## Assertions
+  ## Case, callbacks and assertions
 
-  Check ExUnit.Assertions for assertions documentation.
+  Check `ExUnit.Case` and `ExUnit.Callbacks` for more information about
+  defining test cases.
+
+  The `ExUnit.Assertions` module contains a set of macros to easily
+  generate assertions with appropriate error messages.
 
   ## User config
 

lib/ex_unit/lib/ex_unit/callbacks.ex

@@ -34,7 +34,9 @@ defmodule ExUnit.Callbacks do
   """
 
   @doc false
-  defmacro __using__(_) do
+  defmacro __using__(opts) do
+    parent = opts[:parent]
+
     quote do
       @exunit_setup []
       @exunit_teardown []
@@ -45,23 +47,27 @@ defmodule ExUnit.Callbacks do
       @after_compile unquote(__MODULE__)
       import unquote(__MODULE__)
 
+      def __exunit__(:parent) do
+        unquote(parent)
+      end
+
       def __exunit__(:setup, context) do
-        context = __exunit_setup__(context)
+        context = __exunit_setup__ unquote(parent).__exunit__(:setup, context)
         ExUnit.Callbacks.__setup__(__MODULE__, context)
       end
 
       def __exunit__(:teardown, context) do
-        context = __exunit_teardown__(context)
+        context = unquote(parent).__exunit__(:teardown, __exunit_teardown__ context)
         ExUnit.Callbacks.__teardown__(__MODULE__, context)
       end
 
       def __exunit__(:setup_all, context) do
-        context = __exunit_setup_all__(context)
+        context = __exunit_setup_all__ unquote(parent).__exunit__(:setup_all, context)
         ExUnit.Callbacks.__setup_all__(__MODULE__, context)
       end
 
       def __exunit__(:teardown_all, context) do
-        context = __exunit_teardown_all__(context)
+        context = unquote(parent).__exunit__(:teardown_all, __exunit_teardown_all__ context)
         ExUnit.Callbacks.__teardown_all__(__MODULE__, context)
       end
     end

lib/ex_unit/lib/ex_unit/case.ex

@@ -26,7 +26,8 @@ defmodule ExUnit.Case do
 
   @doc false
   defmacro __using__(opts // []) do
-    async = Keyword.get(opts, :async, false)
+    async  = Keyword.get(opts, :async, false)
+    parent = Keyword.get(opts, :parent, __MODULE__)
 
     quote do
       if unquote(async) do
@@ -35,12 +36,18 @@ defmodule ExUnit.Case do
         ExUnit.Server.add_sync_case(__MODULE__)
       end
 
+      use ExUnit.Callbacks, parent: unquote(parent)
+
       import ExUnit.Assertions
       import ExUnit.Case
-      use ExUnit.Callbacks
     end
   end
 
+  @doc false
+  def __exunit__(kind, context) when kind in [:setup, :teardown, :setup_all, :teardown_all] do
+    context
+  end
+
   @doc """
   Provides a convenient macro that allows a test to be
   defined with a string. This macro automatically inserts

lib/ex_unit/lib/ex_unit/case_template.ex

@@ -0,0 +1,69 @@
+defmodule ExUnit.CaseTemplate do
+  @moduledoc """
+  This module allows a developer to define a test case
+  template to be used throughout his tests. This is useful
+  when there are a set of functions that should be shared
+  between tests or a set of setup/teardown callbacks.
+
+  By using this module, the callbacks and assertions
+  available for regular test cases will also be available.
+
+  ## Example
+
+      defmodule MyCase do
+        use ExUnit.CaseTemplate
+
+        setup do
+          IO.puts "This will run before each test that uses this case"
+        end
+      end
+
+      defmodule MyTest do
+        use MyCase, async: true
+
+        test "truth" do
+          assert true
+        end
+      end
+
+  """
+
+  @doc false
+  defmacro __using__(_) do
+    quote do
+      use ExUnit.Callbacks, parent: ExUnit.Case
+
+      import unquote(__MODULE__)
+      import ExUnit.Assertions
+
+      defmacro __using__(opts) do
+        unquote(__MODULE__).__parent__(__MODULE__, opts)
+      end
+
+      defoverridable [__using__: 1]
+    end
+  end
+
+  @doc false
+  def __parent__(module, opts) do
+    opts = Keyword.put(opts, :parent, module)
+
+    quote do
+      use ExUnit.Case, unquote(opts)
+    end
+  end
+
+  @doc """
+  Allows a developer to code to be invoked when
+  this module is used.
+  """
+  defmacro using(var // quote(do: _), do: block) do
+    quote location: :keep do
+      defmacro __using__(unquote(var) = opts) do
+        parent = unquote(__MODULE__).__parent__(__MODULE__, opts)
+        result = unquote(block)
+        { :__block__, [], [parent, result] }
+      end
+    end
+  end
+end

lib/ex_unit/test/ex_unit/callbacks_test.exs

@@ -1,14 +1,20 @@
 Code.require_file "../../test_helper.exs", __FILE__
 
 defmodule ExUnit.CallbacksTest do
-  use ExUnit.Case, sync: false
+  use ExUnit.Case
 
   setup_all do
-    [my_context: :setup_all]
+    [context: :setup_all]
   end
 
   setup do
-    [first_setup: true]
+    [initial_setup: true]
+  end
+
+  setup context do
+    assert context[:initial_setup]
+    assert context[:context] == :setup_all
+    [context: :setup]
   end
 
   setup context do
@@ -17,32 +23,30 @@ defmodule ExUnit.CallbacksTest do
     else
       Process.put(:ex_unit_callback, context[:test])
     end
+    []
+  end
 
-    assert context[:first_setup]
-    assert context[:my_context] == :setup_all
-
-    [my_context: :setup]
+  teardown context do
+    assert context[:context] == :setup
+    []
   end
 
   teardown context do
-    assert context[:my_context] == :setup
     assert Process.get(:ex_unit_callback) == context[:test]
     Process.delete(:ex_unit_callback)
     []
   end
 
   teardown_all context do
-    assert context[:my_context] == :setup_all
+    assert context[:context] == :setup_all
     []
   end
 
-  test :callback, context do
-    assert context[:my_context] == :setup
-    assert Process.get(:ex_unit_callback) == :test_callback
+  test "callbacks can run custom code" do
+    assert Process.get(:ex_unit_callback) == :"test callbacks can run custom code"
   end
 
-  # Ensure we run at least two tests, so setup is run twice
-  test :ok do
-    assert :ok == :ok
+  test "receives context from callback", context do
+    assert context[:context] == :setup
   end
 end

lib/ex_unit/test/ex_unit/case_template_test.exs

@@ -0,0 +1,46 @@
+Code.require_file "../../test_helper.exs", __FILE__
+
+defmodule ExUnit.SampleCase do
+  use ExUnit.CaseTemplate
+
+  using _ do
+    quote do
+      import unquote(__MODULE__)
+    end
+  end
+
+  def hello do
+    "world"
+  end
+
+  setup_all do
+    [context: :setup_all]
+  end
+
+  setup context do
+    assert context[:context] == :setup_all
+    [context: :setup]
+  end
+
+  teardown context do
+    assert context[:context] == :setup
+    []
+  end
+
+  teardown_all context do
+    assert context[:context] == :setup_all
+    []
+  end
+end
+
+defmodule ExUnit.CaseTemplateTest do
+  use ExUnit.SampleCase, async: true
+
+  test "receives context from parent case", context do
+    assert context[:context] == :setup
+  end
+
+  test "using code is executed" do
+    assert hello == "world"
+  end
+end