build.gradle

plugins {
    id 'jacoco'
    id 'project-report'
    id 'ru.vyarus.java-lib' version '1.0.4'
    id 'ru.vyarus.github-info' version '1.1.0'
    id 'ru.vyarus.animalsniffer' version '1.2.0'
    id 'ru.vyarus.quality' version '2.1.0'
    id 'com.github.kt3k.coveralls' version '2.7.1'
    id 'com.jfrog.bintray' version '1.7.3'
    id 'net.researchgate.release' version '2.5.0'
    id 'com.github.ben-manes.versions' version '0.13.0'
}

wrapper {
    gradleVersion = 3.3
}

description = 'Domo API Lab'

github {
    user = 'domoinc'
    license = 'MIT'
}

allprojects {
    group = 'com.domo'

    repositories {
        jcenter();
        mavenCentral();
        mavenLocal()
        flatDir {
            dirs 'libs'
        }
    }
    apply plugin: 'java'
    apply plugin: "ru.vyarus.java-lib"

    sourceCompatibility = 1.8

}

dependencies {
    compile name: 'domo-java-sdk-all-0.1.0-SNAPSHOT'
    compile group: 'com.squareup.okhttp3', name: 'okhttp', version: '3.6.0'
    compile group: 'com.squareup.okhttp3', name: 'logging-interceptor', version: '3.6.0'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.0'

    compile group: 'com.opencsv', name: 'opencsv', version: '3.8'
    compile group: 'org.xerial', name: 'sqlite-jdbc', version: '3.16.1'


    compile 'org.slf4j:slf4j-api:1.7.21'

    testCompile 'ch.qos.logback:logback-classic:1.1.7'
    testCompile 'org.slf4j:jul-to-slf4j:1.7.21'

    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.assertj', name: 'assertj-core', version: '2.6.0'
}

test {
    testLogging {
        events 'skipped', 'failed', 'standard_error'
        exceptionFormat 'full'
    }
    maxHeapSize = '512m'
}


afterReleaseBuild {
    dependsOn = [bintrayUpload]
    doLast {
        logger.warn "RELEASED $project.group:$project.name:$project.version"
    }
}


dependencyUpdates.revision = 'release'
jacocoTestReport.reports.xml.enabled = true


task showDependenciesTree(dependsOn: 'htmlDependencyReport', group: 'help', description:
        'Generates dependencies tree report and opens it in browser') {
    doLast {
        java.awt.Desktop.getDesktop().open(file('build/reports/project/dependencies/root.html'))
    }
}