|
| 1 | +{ |
| 2 | + * This Source Code Form is subject to the terms of the Mozilla Public License, |
| 3 | + * v. 2.0. If a copy of the MPL was not distributed with this file, You can |
| 4 | + * obtain one at https://mozilla.org/MPL/2.0/ |
| 5 | + * |
| 6 | + * Copyright (C) 2025, Peter Johnson (gravatar.com/delphidabbler). |
| 7 | + * |
| 8 | + * Saves information about a snippet to disk in rich text format. Only routine |
| 9 | + * snippet kinds are supported. |
| 10 | +} |
| 11 | + |
| 12 | + |
| 13 | +unit USaveInfoMgr; |
| 14 | + |
| 15 | +interface |
| 16 | + |
| 17 | +uses |
| 18 | + // Project |
| 19 | + UEncodings, |
| 20 | + UView; |
| 21 | + |
| 22 | + |
| 23 | +type |
| 24 | + /// <summary>Method-only record that saves information about a snippet to |
| 25 | + /// file in rich text format. The snippet is obtained from a view. Only |
| 26 | + /// snippet views are supported.</summary> |
| 27 | + TSaveInfoMgr = record |
| 28 | + strict private |
| 29 | + /// <summary>Attempts to name of the file to be written from the user. |
| 30 | + /// </summary> |
| 31 | + /// <param name="AFileName"><c>string</c> [out] Set to the name of the file |
| 32 | + /// entered by the user. Undefined if the user cancelled.</param> |
| 33 | + /// <returns><c>Boolean</c>. <c>True</c> if the user entered and accepted a |
| 34 | + /// file name of <c>False</c> if the user cancelled.</returns> |
| 35 | + class function TryGetFileNameFromUser(out AFileName: string): Boolean; |
| 36 | + static; |
| 37 | + /// <summary>Returns encoded data containing a RTF representation of |
| 38 | + /// information about the snippet represented by the given view.</summary> |
| 39 | + class function GenerateRichText(View: IView): TEncodedData; static; |
| 40 | + public |
| 41 | + /// <summary>Saves information about the snippet referenced by the a given |
| 42 | + /// view to file.</summary> |
| 43 | + /// <remarks>The view must be a snippet view.</remarks> |
| 44 | + class procedure Execute(View: IView); static; |
| 45 | + /// <summary>Checks if a given view can be saved to the clipboard. Returns |
| 46 | + /// True only if the view represents a snippet.</summary> |
| 47 | + class function CanHandleView(View: IView): Boolean; static; |
| 48 | + |
| 49 | + end; |
| 50 | + |
| 51 | +implementation |
| 52 | + |
| 53 | +uses |
| 54 | + // Delphi |
| 55 | + SysUtils, |
| 56 | + Dialogs, |
| 57 | + // Project |
| 58 | + Hiliter.UAttrs, |
| 59 | + Hiliter.UGlobals, |
| 60 | + UIOUtils, |
| 61 | + UOpenDialogHelper, |
| 62 | + URTFSnippetDoc, |
| 63 | + URTFUtils, |
| 64 | + USaveDialogEx; |
| 65 | + |
| 66 | +{ TSaveInfoMgr } |
| 67 | + |
| 68 | +class function TSaveInfoMgr.CanHandleView(View: IView): Boolean; |
| 69 | +begin |
| 70 | + Result := Supports(View, ISnippetView); |
| 71 | +end; |
| 72 | + |
| 73 | +class procedure TSaveInfoMgr.Execute(View: IView); |
| 74 | +var |
| 75 | + FileName: string; |
| 76 | + RTF: TRTF; |
| 77 | +begin |
| 78 | + Assert(Assigned(View), 'TSaveInfoMgr.Execute: View is nil'); |
| 79 | + Assert(CanHandleView(View), 'TSaveInfoMgr.Execute: View not supported'); |
| 80 | + if not TryGetFileNameFromUser(FileName) then |
| 81 | + Exit; |
| 82 | + RTF := TRTF.Create(GenerateRichText(View)); |
| 83 | + TFileIO.WriteAllBytes(FileName, RTF.ToBytes); |
| 84 | +end; |
| 85 | + |
| 86 | +class function TSaveInfoMgr.GenerateRichText(View: IView): TEncodedData; |
| 87 | +var |
| 88 | + Doc: TRTFSnippetDoc; // object that generates RTF document |
| 89 | + HiliteAttrs: IHiliteAttrs; // syntax highlighter formatting attributes |
| 90 | +begin |
| 91 | + Assert(Supports(View, ISnippetView), |
| 92 | + 'TSaveInfoMgr.GenerateRichText: View is not a snippet view'); |
| 93 | + if (View as ISnippetView).Snippet.HiliteSource then |
| 94 | + HiliteAttrs := THiliteAttrsFactory.CreateUserAttrs |
| 95 | + else |
| 96 | + HiliteAttrs := THiliteAttrsFactory.CreateNulAttrs; |
| 97 | + Doc := TRTFSnippetDoc.Create(HiliteAttrs); |
| 98 | + try |
| 99 | + // TRTFSnippetDoc generates stream of ASCII bytes |
| 100 | + Result := Doc.Generate((View as ISnippetView).Snippet); |
| 101 | + Assert(Result.EncodingType = etASCII, |
| 102 | + 'TSaveInfoMgr.GenerateRichText: ASCII encoded data expected'); |
| 103 | + finally |
| 104 | + Doc.Free; |
| 105 | + end; |
| 106 | +end; |
| 107 | + |
| 108 | +class function TSaveInfoMgr.TryGetFileNameFromUser( |
| 109 | + out AFileName: string): Boolean; |
| 110 | +var |
| 111 | + Dlg: TSaveDialogEx; |
| 112 | +resourcestring |
| 113 | + sCaption = 'Save Snippet Information'; // dialogue box caption |
| 114 | + sFilter = 'Rich Text File (*.rtf)|*.rtf|' // file filter |
| 115 | + + 'All files (*.*)|*.*'; |
| 116 | +begin |
| 117 | + Dlg := TSaveDialogEx.Create(nil); |
| 118 | + try |
| 119 | + Dlg.Title := sCaption; |
| 120 | + Dlg.Options := [ofShowHelp, ofNoTestFileCreate, ofEnableSizing]; |
| 121 | + Dlg.Filter := sFilter; |
| 122 | + Dlg.FilterIndex := 1; |
| 123 | + Dlg.HelpKeyword := 'SnippetInfoFileDlg'; |
| 124 | + Result := Dlg.Execute; |
| 125 | + if Result then |
| 126 | + AFileName := FileOpenFileNameWithExt(Dlg) |
| 127 | + finally |
| 128 | + Dlg.Free; |
| 129 | + end; |
| 130 | +end; |
| 131 | + |
| 132 | +end. |
0 commit comments