Current-Activity/app/build.gradle at main · codehasan/Current-Activity · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'

android {
    namespace "io.github.ratul.topactivity"

    compileSdk {
        version = release(36)
    }

    defaultConfig {
        applicationId "io.github.ratul.topactivity"
        minSdk {
            version = release(24)
        }
        targetSdk {
            version = release(36)
        }
        versionCode 25
        versionName "2.2.0"
    }

    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.debug
        }
    }

    buildFeatures {
        buildConfig true
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    kotlin {
        compilerOptions {
            jvmTarget.set(JvmTarget.JVM_11)
        }
    }

    dependenciesInfo {
        // Disables dependency metadata when building APKs (for IzzyOnDroid/F-Droid)
        includeInApk = false
        // Enables dependency metadata when building Android App Bundles (for Google Play)
        // Allows Google to scan dependencies for policy compliance
        includeInBundle = true
    }

    flavorDimensions 'version'
    productFlavors {
        global {
            dimension 'version'
        }
        playStore {
            dimension 'version'
        }
    }

    android.applicationVariants.all { variant ->
        variant.outputs.all { output ->
            def flavor = variant.flavorName
            def apkName = "current-activity_${flavor}_v${variant.versionName}.apk"
            output.outputFileName = apkName
        }
    }
}

dependencies {
    implementation 'com.google.android.material:material:1.13.0'
    implementation 'androidx.appcompat:appcompat:1.7.1'
    implementation 'androidx.fragment:fragment-ktx:1.8.9'
    implementation 'androidx.preference:preference-ktx:1.2.1'
    implementation 'com.android.volley:volley:1.2.1'
}

configurations.all {
    resolutionStrategy {
        force('org.jetbrains.kotlin:kotlin-stdlib-jdk8:2.2.0')
    }
}