Merge pull request microsoft#165633 from rwe/serialize-message-zsh

shellIntegration-rc.zsh: escape values in "E" (executed command) and "P" (property KV) codes

Author: Tyriar

src/vs/workbench/contrib/terminal/browser/media/shellIntegration-rc.zsh

@@ -34,48 +34,81 @@ if [ -z "$VSCODE_SHELL_INTEGRATION" ]; then
 	builtin return
 fi
 
+# The property (P) and command (E) codes embed values which require escaping.
+# Backslashes are doubled. Non-alphanumeric characters are converted to escaped hex.
+__vsc_escape_value() {
+	builtin emulate -L zsh
+
+	# Process text byte by byte, not by codepoint.
+	builtin local LC_ALL=C str="$1" i byte token out=''
+
+	for (( i = 0; i < ${#str}; ++i )); do
+		byte="${str:$i:1}"
+
+		# Backslashes must be doubled.
+		if [ "$byte" = "\\" ]; then
+			token="\\\\"
+		# Conservatively pass alphanumerics through.
+		elif [[ "$byte" == [0-9A-Za-z] ]]; then
+			token="$byte"
+		# Hex-encode anything else.
+		# (Importantly including: semicolon, newline, and control chars).
+		else
+			token="\\x${(l:2::0:)$(( [##16] #byte ))}"
+			#            | |  |       |/|/ |_____|
+			#            | |  |       | |     |
+			# left-pad --+ |  |       | |     +- the byte value of the character
+			# two digits --+  |       | +------- in hexadecimal
+			# with '0' -------+       +--------- with no prefix
+		fi
+
+		out+="$token"
+	done
+
+	builtin print -r "$out"
+}
+
 __vsc_in_command_execution="1"
 __vsc_current_command=""
 
 __vsc_prompt_start() {
-	builtin printf "\033]633;A\007"
+	builtin printf '\e]633;A\a'
 }
 
 __vsc_prompt_end() {
-	builtin printf "\033]633;B\007"
+	builtin printf '\e]633;B\a'
 }
 
 __vsc_update_cwd() {
-	builtin printf "\033]633;P;Cwd=%s\007" "$PWD"
+	builtin printf '\e]633;P;Cwd=%s\a' "$(__vsc_escape_value "${PWD}")"
 }
 
 __vsc_command_output_start() {
-	builtin printf "\033]633;C\007"
-	# Send command line, escaping printf format chars %
-	builtin printf "\033]633;E;%s\007" "$__vsc_current_command"
+	builtin printf '\e]633;C\a'
+	builtin printf '\e]633;E;%s\a' "$(__vsc_escape_value "${__vsc_current_command}")"
 }
 
 __vsc_continuation_start() {
-	builtin printf "\033]633;F\007"
+	builtin printf '\e]633;F\a'
 }
 
 __vsc_continuation_end() {
-	builtin printf "\033]633;G\007"
+	builtin printf '\e]633;G\a'
 }
 
 __vsc_right_prompt_start() {
-	builtin printf "\033]633;H\007"
+	builtin printf '\e]633;H\a'
 }
 
 __vsc_right_prompt_end() {
-	builtin printf "\033]633;I\007"
+	builtin printf '\e]633;I\a'
 }
 
 __vsc_command_complete() {
 	if [[ "$__vsc_current_command" == "" ]]; then
-		builtin printf "\033]633;D\007"
+		builtin printf '\e]633;D\a'
 	else
-		builtin printf "\033]633;D;%s\007" "$__vsc_status"
+		builtin printf '\e]633;D;%s\a' "$__vsc_status"
 	fi
 	__vsc_update_cwd
 }