Merge pull request microsoft#165631 from rwe/serialize-message-fish

shellIntegration.fish: escape values in "E" (executed command) and "P" (property KV) codes

Author: Tyriar

src/vs/workbench/contrib/terminal/browser/media/shellIntegration.fish

@@ -24,28 +24,40 @@ set --global VSCODE_SHELL_INTEGRATION 1
 
 # Helper function
 function __vsc_esc -d "Emit escape sequences for VS Code shell integration"
-	builtin printf "\e]633;%s\007" (string join ";" $argv)
+	builtin printf "\e]633;%s\a" (string join ";" $argv)
 end
 
 # Sent right before executing an interactive command.
 # Marks the beginning of command output.
 function __vsc_cmd_executed --on-event fish_preexec
 	__vsc_esc C
-	__vsc_esc E (__vsc_escape_cmd "$argv")
+	__vsc_esc E (__vsc_escape_value "$argv")
 
 	# Creates a marker to indicate a command was run.
 	set --global _vsc_has_cmd
 end
 
 
-# Escapes backslashes, newlines, and semicolons to serialize the command line.
-function __vsc_escape_cmd
-	set -l commandline "$argv"
-	# `string replace` automatically breaks its input apart on any newlines.
-	# Then `string join` at the end will bring it all back together.
-	string replace --all '\\' '\\\\' $commandline \
-		| string replace --all ';' '\x3b' \
-		| string join '\x0a'
+# Escape a value for use in the 'P' ("Property") or 'E' ("Command Line") sequences.
+# Backslashes are doubled and non-alphanumeric characters are hex encoded.
+function __vsc_escape_value
+	# Replace all non-alnum characters with %XX hex form.
+	string escape --style=url "$argv" \
+	# The characters [-./_~] are not encoded in the builtin url escaping, despite not being alphanumeric.
+	# See: https://github.com/fish-shell/fish-shell/blob/f82537bcdcb32f85a530395f00e7be1aa9afc592/src/common.cpp#L738
+	# For consistency, also encode those characters.
+	| string replace --all '-' '%2D' \
+	| string replace --all '.' '%2E' \
+	| string replace --all '/' '%2F' \
+	| string replace --all '_' '%5F' \
+	| string replace --all '~' '%7E' \
+	# Now everything is either alphanumeric [0-9A-Za-z] or %XX escapes.
+	# Change the hex escape representation from '%' to '\x'. (e.g. ' ' → '%20' → '\x20').
+	# Note that all '%' characters are escapes: literal '%' will already have been encoded.
+	| string replace --all '%' '\\x' \
+	# For readability, prefer to represent literal backslashes with doubling. ('\' → '%5C' → '\x5C' → '\\').
+	| string replace --all --ignore-case '%5C' '\\\\' \
+	;
 end
 
 # Sent right after an interactive command has finished executing.
@@ -63,7 +75,7 @@ end
 # Sent whenever a new fish prompt is about to be displayed.
 # Updates the current working directory.
 function __vsc_update_cwd --on-event fish_prompt
-	__vsc_esc P "Cwd=$PWD"
+	__vsc_esc P "Cwd=$(__vsc_escape_value "$PWD")"
 
 	# If a command marker exists, remove it.
 	# Otherwise, the commandline is empty and no command was run.