-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathyacc.y
1677 lines (1543 loc) · 53.1 KB
/
yacc.y
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
Copyright (C) 1997-2016 Vladimir Makarov.
Written by Vladimir Makarov <[email protected]>
This file is part of the tool MSTA.
This is free software; you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2, or (at your option)
any later version.
This software is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
General Public License for more details.
You should have received a copy of the GNU General Public License
along with GNU CC; see the file COPYING. If not, write to the Free
Software Foundation, 59 Temple Place - Suite 330, Boston, MA
02111-1307, USA.
*/
/* Grammar for the input to MSTA (syntax description translator). */
%{
#ifdef HAVE_CONFIG_H
#include "config.h"
#endif /* #ifdef HAVE_CONFIG_H */
#include <ctype.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include "position.h"
#include "errors.h"
#include "ird.h"
#include "common.h"
#include "tab.h"
#include "yacc.h"
#include <assert.h>
#include <limits.h>
/* The following variables and forward definitions of functions are
used in actions of YACC grammar. */
/* The following variable value is begin position of the last lexema returned
by the function `yylex'. */
static position_t current_lexema_position;
static IR_node_t form_new_sequence (IR_node_t cyclic_sequence,
IR_node_t last_code_insertion_atom);
static void syntax_error (const char *s);
%}
/* Attributes of all YACC symbols (token and nonterminals) will be
`node'. Some construction YACC action will be `position'. */
%union
{
IR_node_t node;
position_t position;
struct
{
IR_node_t code_insertion;
IR_node_t precedence_identifier_or_literal;
IR_node_t look_ahead_number;
} precedence_and_code_insertion_and_la;
}
/* The following are recognized by the lexical analyzer. The
attributes of the following tokens are defined and used. */
%token <node> IDENTIFIER_OR_LITERAL /* identifier (including '.')
and literal */
%token <node> C_IDENTIFIER /* identifier followed by a : */
%token <node> NUMBER /* [0-9][0-9]* */
%token <node> STRING /* "..." of C syntax */
%token <node> CODE_INSERTION /* { ... } */
%token <node> YACC_CODE_INSERTION /* %{ ... %} */
%token <node> ADDITIONAL_C_CODE /* code after second %% */
/* Reserved words : %type=>TYPE %left=>LEFT, etc. The attributes of
the following tokens are not defined and not used. */
%token LEFT RIGHT NONASSOC TOKEN PREC TYPE START
UNION LOCAL IMPORT EXPORT SCANNER EXPECT CP LA
%token PERCENTS /* the %% mark */
%token SEMICOLON /* ; */
%token BAR /* | */
%token SLASH /* / */
%token STAR /* * */
%token PLUS /* + */
%token LESS /* < */
%token GREATER /* > */
%token LEFT_PARENTHESIS /* ) */
%token RIGHT_PARENTHESIS /* ( */
%token LEFT_SQUARE_BRACKET /* [ */
%token RIGHT_SQUARE_BRACKET /* ] */
%token AT /* @ */
%token RANGE /* - */
%token RANGE_NO_LEFT_BOUND /* <- */
%token RANGE_NO_RIGHT_BOUND /* -> */
%token RANGE_NO_LEFT_RIGHT_BOUNDS /* <-> */
%type <node> description tail definitions definition
%type <node> symbol_list_start tag symbol_list symbol
%type <node> rules rule pattern alternatives alternative
%type <node> sequence sequence_element nonamed_sequence_element unit
%type <position> fix_position
%type <precedence_and_code_insertion_and_la> prec_la
%type <position> code_insertion_semicolon_list
/* 8-bit character literals stand for themselves; */
/* tokens have to be defined for multibyte characters */
%start description
%%
description : definitions PERCENTS rules tail
{
IR_node_t first_definition;
IR_node_t first_rule;
position_t position;
/* Transform cyclic definition list to usual list. */
if ($1 != NULL)
{
first_definition = IR_next_definition ($1);
IR_set_next_definition ($1, NULL);
$1 = first_definition;
}
/* Transform cyclic rule list to usual list. */
if ($3 != NULL)
{
first_rule = IR_next_rule ($3);
IR_set_next_rule ($3, NULL);
$3 = first_rule;
}
position.column_number = 1;
position.line_number = 1;
description = IR_new_description (position, $1, $3, $4);
}
;
tail : /* empty */ {$$ = NULL;}
| ADDITIONAL_C_CODE {$$ = $1;}
;
definitions : /* empty */ {$$ = NULL;}
| definitions definition definition_tail
{
if ($1 == NULL)
/* Make cycle. */
IR_set_next_definition ($2, $2);
else
{
/* Add element to cyclic list */
IR_set_next_definition ($2, IR_next_definition ($1));
IR_set_next_definition ($1, $2);
}
$$ = $2;
}
| definitions error
{
syntax_error ("syntax error in declaration");
$$ = $1; /* Ignore error declaration. */
}
;
definition_tail :
| definition_semicolon_list
;
definition_semicolon_list
: SEMICOLON
{
if (yacc_input_flag)
{
if (strict_flag)
error (FALSE, current_lexema_position,
"POSIX YACC prohibits ';' after a definition");
else if (!w_flag)
warning
(current_lexema_position,
"warning: POSIX YACC prohibits ';' after a definition");
}
}
| definition_semicolon_list SEMICOLON
;
definition : START
{
$<position>$ = current_lexema_position;
}
IDENTIFIER_OR_LITERAL
{
$$ = IR_new_start_definition ($<position>2, NULL, $3);
}
| UNION {$<position>$ = current_lexema_position;} CODE_INSERTION
{
$$ = IR_new_union_code ($<position>2, NULL, $3);
}
| YACC_CODE_INSERTION
{
$$ = IR_new_yacc_code (current_lexema_position, NULL, $1);
}
| LOCAL {$<position>$ = current_lexema_position;} CODE_INSERTION
{
$$ = IR_new_local_code ($<position>2, NULL, $3);
}
| IMPORT {$<position>$ = current_lexema_position;} CODE_INSERTION
{
$$ = IR_new_import_code ($<position>2, NULL, $3);
}
| EXPORT {$<position>$ = current_lexema_position;} CODE_INSERTION
{
$$ = IR_new_export_code ($<position>2, NULL, $3);
}
| SCANNER
{
$$ = IR_new_scanner_definition
(current_lexema_position, NULL);
}
| EXPECT {$<position>$ = current_lexema_position;} NUMBER
{
$$ = IR_new_expect_definition ($<position>2, NULL, $3);
}
| symbol_list_start tag symbol_list
{
IR_node_t first_symbol;
/* Transform cyclic symbol list to usual list. */
if ($3 != NULL)
{
first_symbol = IR_next_symbol ($3);
IR_set_next_symbol ($3, NULL);
$3 = first_symbol;
}
IR_set_symbol_list ($1, $3);
IR_set_tag ($1, $2);
$$ = $1;
}
;
symbol_list_start : TOKEN
{
$$ = IR_new_token_definition (current_lexema_position,
NULL, NULL, NULL);
}
| LEFT
{
$$ = IR_new_left_definition (current_lexema_position,
NULL, NULL, NULL);
}
| RIGHT
{
$$ = IR_new_right_definition (current_lexema_position,
NULL, NULL, NULL);
}
| NONASSOC
{
$$
= IR_new_nonassoc_definition
(current_lexema_position, NULL, NULL, NULL);
}
| TYPE
{
$$ = IR_new_type_definition (current_lexema_position,
NULL, NULL, NULL);
}
;
tag : /* empty */ {$$ = NULL;}
| LESS IDENTIFIER_OR_LITERAL GREATER {$$ = $2;}
;
symbol_list : symbol
{
/* Make cycle. */
IR_set_next_symbol ($1, $1);
$$ = $1;
}
| symbol_list symbol
{
/* Add element to cyclic list */
IR_set_next_symbol ($2, IR_next_symbol ($1));
IR_set_next_symbol ($1, $2);
$$ = $2;
}
;
symbol : IDENTIFIER_OR_LITERAL
{
$$ = IR_new_symbol (IR_position ($1), $1, NULL, NULL);
}
| IDENTIFIER_OR_LITERAL NUMBER
{
$$ = IR_new_symbol (IR_position ($1), $1, $2, NULL);
}
;
/* Rule section */
rules : rule semicolons
{
if ($1 != NULL)
/* NULL is possible because of syntax errors -- Make cycle. */
IR_set_next_rule ($1, $1);
$$ = $1;
}
| rules rule semicolons
{
if ($2 == NULL)
$$ = $1;
else
{
if ($1 == NULL)
/* It is possible because of syntax errors -- Make cycle. */
IR_set_next_rule ($2, $2);
else
{
/* Add element to cyclic list */
IR_set_next_rule ($2, IR_next_rule ($1));
IR_set_next_rule ($1, $2);
}
$$ = $2;
}
}
;
rule : C_IDENTIFIER {$<position>$ = current_lexema_position;} pattern
{
$$ = IR_new_rule ($<position>2, $1, $3, NULL);
}
| error
{
syntax_error ("syntax error in rule");
$$ = NULL; /* Ignore error rule. */
}
;
pattern : alternatives
{
IR_node_t first_alternative;
/* Transform cyclic alternative list to usual list. */
assert ($1 != NULL);
first_alternative = IR_next_alternative ($1);
IR_set_next_alternative ($1, NULL);
$1 = first_alternative;
$$ = IR_new_pattern (IR_position ($1), $1);
}
;
alternatives : alternatives BAR alternative
{
/* Add element to cyclic list */
$$ = $3;
IR_set_next_alternative ($$, IR_next_alternative ($1));
IR_set_next_alternative ($1, $$);
}
| alternative
{
/* Make cyclic list. */
$$ = $1;
IR_set_next_alternative ($$, $$);
}
;
alternative : fix_position sequence prec_la
{
$$ = IR_new_sequence ($1, NULL,
form_new_sequence ($2,
$3.code_insertion),
$3.precedence_identifier_or_literal,
$3.look_ahead_number);
}
| fix_position sequence prec_la SLASH
{
$<position>$ = current_lexema_position;
}
sequence prec_la
{
$$
= IR_new_separator_iteration
($<position>5, NULL,
form_new_sequence ($2, $3.code_insertion),
$3.precedence_identifier_or_literal,
$3.look_ahead_number,
form_new_sequence ($6, $7.code_insertion),
$7.precedence_identifier_or_literal,
$7.look_ahead_number);
}
;
fix_position : {$$ = current_lexema_position;}
;
sequence : /* empty */ {$$ = NULL;}
| sequence sequence_element
{
if ($1 == NULL)
/* It is possible because of syntax errors -- Make cycle. */
IR_set_next_sequence_element ($2, $2);
else
{
/* Add element to cyclic list */
IR_set_next_sequence_element
($2, IR_next_sequence_element ($1));
IR_set_next_sequence_element ($1, $2);
}
$$ = $2;
}
;
sequence_element : CP
{
$$ = IR_new_control_point (current_lexema_position,
NULL, NULL);
}
| nonamed_sequence_element {$$ = $1;}
| nonamed_sequence_element AT IDENTIFIER_OR_LITERAL
{
IR_set_sequence_element_identifier ($1, $3);
$$ = $1;
}
;
nonamed_sequence_element
: LEFT_SQUARE_BRACKET
{
$<position>$ = current_lexema_position;
}
pattern RIGHT_SQUARE_BRACKET
{
$$ = IR_new_default ($<position>2, NULL,
NULL, $3);
}
| unit STAR
{
$$
= IR_new_star_iteration
(current_lexema_position, NULL, NULL, $1);
}
| unit PLUS
{
$$
= IR_new_plus_iteration
(current_lexema_position, NULL, NULL, $1);
}
| CODE_INSERTION code_insertion_tail
{
$$
= IR_new_code_insertion_atom
(IR_position ($1), NULL, NULL, $1);
}
| unit {$$ = $1;}
;
code_insertion_tail
:
| code_insertion_semicolon_list
{
if (yychar != C_IDENTIFIER
&& yychar != ADDITIONAL_C_CODE
&& yychar != 0 && yacc_input_flag)
{
if (strict_flag)
error (FALSE, $1,
"POSIX YACC prohibits ';' after a code insertion");
else if (!w_flag)
warning
($1,
"warning: POSIX YACC prohibits ';' after a code insertion");
}
}
;
code_insertion_semicolon_list
: SEMICOLON {$$ = current_lexema_position;}
| code_insertion_semicolon_list SEMICOLON {$$ = $1;}
;
unit : LEFT_PARENTHESIS
{
$<position>$ = current_lexema_position;
}
pattern RIGHT_PARENTHESIS
{
$$ = IR_new_group ($<position>2, NULL, NULL, $3);
}
| IDENTIFIER_OR_LITERAL
{
$$ = IR_new_identifier_or_literal_atom (IR_position ($1),
NULL, NULL, $1);
}
| STRING
{
$$ = IR_new_string_atom (IR_position ($1), NULL, NULL, $1);
}
| IDENTIFIER_OR_LITERAL RANGE
{
$<position>$ = current_lexema_position;
}
IDENTIFIER_OR_LITERAL
{
$$ = IR_new_range_atom ($<position>3, NULL, NULL, $1, $4);
}
| IDENTIFIER_OR_LITERAL RANGE_NO_LEFT_BOUND
{
$<position>$ = current_lexema_position;
}
IDENTIFIER_OR_LITERAL
{
$$ = IR_new_range_no_left_bound_atom
($<position>3, NULL, NULL, $1, $4);
}
| IDENTIFIER_OR_LITERAL RANGE_NO_RIGHT_BOUND
{
$<position>$ = current_lexema_position;
}
IDENTIFIER_OR_LITERAL
{
$$ = IR_new_range_no_right_bound_atom
($<position>3, NULL, NULL, $1, $4);
}
| IDENTIFIER_OR_LITERAL RANGE_NO_LEFT_RIGHT_BOUNDS
{
$<position>$ = current_lexema_position;
}
IDENTIFIER_OR_LITERAL
{
$$ = IR_new_range_no_left_right_bounds_atom
($<position>3, NULL, NULL, $1, $4);
}
;
prec_la : /* empty */
{
$$.code_insertion = NULL;
$$.precedence_identifier_or_literal = NULL;
$$.look_ahead_number = NULL;
}
| PREC IDENTIFIER_OR_LITERAL
{
$$.code_insertion = NULL;
$$.precedence_identifier_or_literal = $2;
$$.look_ahead_number = NULL;
}
| PREC IDENTIFIER_OR_LITERAL CODE_INSERTION code_insertion_tail
{
$$.code_insertion = IR_new_code_insertion_atom (IR_position ($3),
NULL, NULL, $3);
$$.precedence_identifier_or_literal = $2;
$$.look_ahead_number = NULL;
}
| LA NUMBER
{
$$.code_insertion = NULL;
$$.precedence_identifier_or_literal = NULL;
$$.look_ahead_number = $2;
if (max_look_ahead_number < IR_number_value ($2))
max_look_ahead_number = IR_number_value ($2);
}
| PREC IDENTIFIER_OR_LITERAL LA NUMBER
{
$$.code_insertion = NULL;
$$.precedence_identifier_or_literal = $2;
$$.look_ahead_number = $4;
if (max_look_ahead_number < IR_number_value ($4))
max_look_ahead_number = IR_number_value ($4);
}
| LA NUMBER PREC IDENTIFIER_OR_LITERAL
{
$$.code_insertion = NULL;
$$.precedence_identifier_or_literal = $4;
$$.look_ahead_number = $2;
if (max_look_ahead_number < IR_number_value ($2))
max_look_ahead_number = IR_number_value ($2);
}
| LA NUMBER CODE_INSERTION code_insertion_tail
{
$$.code_insertion = IR_new_code_insertion_atom (IR_position ($3),
NULL, NULL, $3);
$$.precedence_identifier_or_literal = NULL;
$$.look_ahead_number = $2;
if (max_look_ahead_number < IR_number_value ($2))
max_look_ahead_number = IR_number_value ($2);
}
| PREC IDENTIFIER_OR_LITERAL LA NUMBER
CODE_INSERTION code_insertion_tail
{
$$.code_insertion = IR_new_code_insertion_atom (IR_position ($5),
NULL, NULL, $5);
$$.precedence_identifier_or_literal = $2;
$$.look_ahead_number = $4;
if (max_look_ahead_number < IR_number_value ($4))
max_look_ahead_number = IR_number_value ($4);
}
| LA NUMBER PREC IDENTIFIER_OR_LITERAL
CODE_INSERTION code_insertion_tail
{
$$.code_insertion = IR_new_code_insertion_atom (IR_position ($5),
NULL, NULL, $5);
$$.precedence_identifier_or_literal = $4;
$$.look_ahead_number = $2;
if (max_look_ahead_number < IR_number_value ($2))
max_look_ahead_number = IR_number_value ($2);
}
;
semicolons : /* empty */
| semicolons SEMICOLON
;
%%
static IR_node_t
form_new_sequence (IR_node_t cyclic_sequence,
IR_node_t last_code_insertion_atom)
{
IR_node_t first_sequence_element;
if (last_code_insertion_atom != NULL)
{
if (cyclic_sequence == NULL)
/* It is possible because of syntax errors -- Make cycle. */
IR_set_next_sequence_element (last_code_insertion_atom,
last_code_insertion_atom);
else
{
/* Add element to cyclic sequence */
IR_set_next_sequence_element
(last_code_insertion_atom,
IR_next_sequence_element (cyclic_sequence));
IR_set_next_sequence_element (cyclic_sequence,
last_code_insertion_atom);
}
cyclic_sequence = last_code_insertion_atom;
}
/* Transform cyclic sequence to usual list. */
if (cyclic_sequence != NULL)
{
first_sequence_element = IR_next_sequence_element (cyclic_sequence);
IR_set_next_sequence_element (cyclic_sequence, NULL);
cyclic_sequence = first_sequence_element;
}
return cyclic_sequence;
}
/* This page contains abstract data `scanner'. This abstract data
divides input stream characters on tokens (lexemas). */
/* The following structure describes current input stream and scanner
state. */
struct input_stream_state
{
FILE *input_file;
/* The following member is TRUE if the first `%%' in given input stream
was already processed or FALSE otherwise. */
int it_is_first_percents;
/* The following member is TRUE if the ADDITIONAL_CODE lexema was already
returned by the scanner or FALSE otherwise. */
int additional_c_code_was_returned;
};
/* The following structure contains current input stream and
scanner state. If the member `input_file' value is NULL
then input stream is not defined. */
static struct input_stream_state current_input_stream_state;
static int
find_keyword (const char *str, int length)
{
switch (length)
{
case 2:
if (*str == 'c')
return (strcmp (str, "cp") == 0 ? CP : 0);
else
return (strcmp (str, "la") == 0 ? LA : 0);
case 4:
switch (*str)
{
case 'l':
return (strcmp (str, "left") == 0 ? LEFT : 0);
case 'p':
return (strcmp (str, "prec") == 0 ? PREC : 0);
case 't':
return (strcmp (str, "type") == 0 ? TYPE : 0);
default:
return 0;
}
case 5:
switch (*str)
{
case 'r':
return (strcmp (str, "right") == 0 ? RIGHT : 0);
case 't':
return (strcmp (str, "token") == 0 ? TOKEN : 0);
case 's':
return (strcmp (str, "start") == 0 ? START : 0);
case 'u':
return (strcmp (str, "union") == 0 ? UNION : 0);
case 'l':
return (strcmp (str, "local") == 0 ? LOCAL : 0);
default:
return 0;
}
case 6:
switch (*str)
{
case 'i':
return (strcmp (str, "import") == 0 ? IMPORT : 0);
case 'e':
if (str [3] == 'o')
return (strcmp (str, "export") == 0 ? EXPORT : 0);
else
return (strcmp (str, "expect") == 0 ? EXPECT : 0);
default:
return 0;
}
case 7:
return (strcmp (str, "scanner") == 0 ? SCANNER : 0);
case 8:
return (strcmp (str, "nonassoc") == 0 ? NONASSOC : 0);
default:
return 0;
}
}
/* The following value is used if previous_char does not contain an
input char */
#define EMPTY_PREVIOUS_CHAR (-2000)
/* The following variable is used for storing '\r'. */
static int previous_char;
/* The following two functions for replacing "\r\n" onto "\n". */
static int
getch (FILE *f)
{
int c;
if (previous_char != '\r')
c = getc (f);
else
{
c = previous_char;
previous_char = EMPTY_PREVIOUS_CHAR;
}
if (c == '\r')
{
c = getc (f);
if (c != '\n')
{
ungetc (c, f);
c = '\r';
}
}
return c;
}
static void
ungetch (int c, FILE *f)
{
if (c != '\r')
ungetc (c, f);
else
previous_char = c;
}
static int
skip_commentary (int store_flag)
{
int input_char;
current_position.column_number++;
if (store_flag)
IR_TOP_ADD_BYTE ('*');
for (;;)
{
input_char = getch (current_input_stream_state.input_file);
/* Here `current_position' corresponds to `input_char'. */
if (input_char == '*')
{
if (store_flag)
IR_TOP_ADD_BYTE (input_char);
input_char = getch (current_input_stream_state.input_file);
current_position.column_number++;
/* Here `current_position' corresponds to `input_char'. */
if (input_char == '/')
{
if (store_flag)
IR_TOP_ADD_BYTE (input_char);
current_position.column_number++;
return TRUE;
}
else
{
ungetch (input_char, current_input_stream_state.input_file);
continue;
}
}
else if (input_char == EOF)
{
ungetch (input_char, current_input_stream_state.input_file);
return FALSE;
}
if (input_char == '\n')
{
current_position.column_number = 1;
current_position.line_number++;
}
else if (input_char == '\t')
current_position.column_number
= ((current_position.column_number - 1) / TAB_STOP + 1)
* TAB_STOP + 1;
else
current_position.column_number++;
if (store_flag)
IR_TOP_ADD_BYTE (input_char);
}
}
static int
skip_string_code (int input_char, int *correct_new_line)
{
if (input_char == EOF || input_char == '\n')
{
ungetch (input_char, current_input_stream_state.input_file);
return FALSE;
}
*correct_new_line = FALSE;
IR_TOP_ADD_BYTE (input_char);
if (input_char == '\\')
{
current_position.column_number++;
input_char = getch (current_input_stream_state.input_file);
IR_TOP_ADD_BYTE (input_char);
if (input_char == 'n' || input_char == 't' || input_char == 'v'
|| input_char == 'b' || input_char == 'r' || input_char == 'f'
|| input_char == '\\' || input_char == '\'' || input_char == '\"')
current_position.column_number++;
else if (input_char == '\n')
{
current_position.column_number = 1;
current_position.line_number++;
*correct_new_line = TRUE;
}
else if (isdigit (input_char) && input_char != '8'
&& input_char != '9')
{
current_position.column_number++;
input_char = getch (current_input_stream_state.input_file);
if (!isdigit (input_char) || input_char == '8'
|| input_char == '9')
ungetch (input_char, current_input_stream_state.input_file);
else
{
current_position.column_number++;
IR_TOP_ADD_BYTE (input_char);
input_char = getch (current_input_stream_state.input_file);
if (!isdigit (input_char) || input_char == '8'
|| input_char == '9')
ungetch (input_char, current_input_stream_state.input_file);
else
{
current_position.column_number++;
IR_TOP_ADD_BYTE (input_char);
}
}
}
else
current_position.column_number++;
}
else if (input_char == '\t')
current_position.column_number
= ((current_position.column_number - 1) / TAB_STOP + 1) * TAB_STOP + 1;
else
current_position.column_number++;
return TRUE;
}
static const char *
get_string_code (const char *code_representation,
int *character_code, int *correct_new_line)
{
*correct_new_line = FALSE;
*character_code = *code_representation;
if (*code_representation == '\\')
{
code_representation++;
if (*code_representation == 'n' || *code_representation == 't'
|| *code_representation == 'v' || *code_representation == 'b'
|| *code_representation == 'r' || *code_representation == 'f'
|| *code_representation == '\\' || *code_representation == '\''
|| *code_representation == '\"')
{
if (*code_representation == 'n')
*character_code = '\n';
else if (*code_representation == 't')
*character_code = '\t';
else if (*code_representation == 'v')
*character_code = '\v';
else if (*code_representation == 'b')
*character_code = '\b';
else if (*code_representation == 'r')
*character_code = '\r';
else if (*code_representation == 'f')
*character_code = '\f';
else if (*code_representation == '\\')
*character_code = '\\';
else if (*code_representation == '\'')
*character_code = '\'';
else if (*code_representation == '\"')
*character_code = '\"';
else
assert (FALSE);
}
else if (isdigit (*code_representation) && *code_representation != '8'
&& *code_representation != '9')
{
*character_code = *code_representation - '0';
code_representation++;
if (!isdigit (*code_representation) || *code_representation == '8'
|| *code_representation == '9')
code_representation--;
else
{
*character_code
= *character_code * 8 + *code_representation - '0';
code_representation++;
if (!isdigit (*code_representation)
|| *code_representation == '8'
|| *code_representation == '9')
code_representation--;
else
{
*character_code
= *character_code * 8 + *code_representation - '0';
current_position.column_number++;
}
}
}
else if (*code_representation != '\n')
*character_code = *code_representation;
else
*correct_new_line = TRUE;
}
return code_representation;
}
static void
skip_C_character (void)
{
int input_char;
int correct_new_line;
int error_flag;
error_flag = FALSE;
input_char = getch (current_input_stream_state.input_file);
/* Here `current_position' corresponds to `input_char'. */
if (input_char == '\'')
{
IR_TOP_ADD_BYTE (input_char);
error (FALSE, current_position, "invalid character constant");
current_position.column_number++;
error_flag = TRUE;
}
else
{
if (!skip_string_code (input_char, &correct_new_line)
|| correct_new_line)
{
error (FALSE, current_position, "invalid character constant");