CLJS-2061: Support ns :require for JS libs, allow strings along with symbols

The strategy employed by this patch is to defer processing JS modules until
after we have found the sources and computed the "missing modules" in NS
declarations. `cljs.analyzer/parse-ns` returns the extra `:missing-js-modules`
key, which it infers by looking at string declarations in dependencies.

Author: anmonteiro

samples/string-requires-npm-deps/.gitignore

@@ -0,0 +1 @@
+out/

samples/string-requires-npm-deps/README.md

@@ -0,0 +1,13 @@
+# ClojureScript string-based requires demo
+
+Running:
+
+1. At the root of the ClojureScript repo, run `./script/bootstrap`
+2. Switch into this directory: `cd samples/string-requires-npm-deps`
+3. Build the project:
+
+``` shell
+$ java -cp `ls ../../lib/*.jar | paste -sd ":" -`:../../src/main/cljs:../../src/main/clojure:src clojure.main build.clj
+```
+
+4. run the generated JavaScript with `node out/main.js`

samples/string-requires-npm-deps/build.clj

@@ -0,0 +1,13 @@
+(require '[cljs.build.api :as b])
+
+(b/build "src"
+  {:output-dir "out"
+   :output-to "out/main.js"
+   :optimizations :none
+   :verbose true
+   :target :nodejs
+   :compiler-stats true
+   :main 'foo.core
+   :npm-deps {:react "15.6.1"
+              :react-dom "15.6.1"}
+   :closure-warnings {:non-standard-jsdoc :off}})

samples/string-requires-npm-deps/package.json

@@ -0,0 +1,3 @@
+{
+  "name": "string-requires-npm-deps"
+}

samples/string-requires-npm-deps/src/foo/core.cljs

@@ -0,0 +1,10 @@
+(ns foo.core
+  (:require [react :refer [createElement]]
+            ["react-dom/server" :as rds :refer [renderToString]]
+            "create-react-class"))
+
+(enable-console-print!)
+
+(println "resolves single exports" create-react-class)
+
+(println (renderToString (createElement "div" nil "Hello World!")))

src/main/cljs/cljs/module_deps.js

@@ -30,7 +30,7 @@ md.on('package', function (pkg) {
     };
 
     if (pkg.name != null) {
-      pkgJson.provided = [ pkg.name ];
+      pkgJson.provides = [ pkg.name ];
     }
 
     if (pkg.main != null) {
@@ -49,16 +49,26 @@ md.on('end', function() {
   for (var i = 0; i < pkgJsons.length; i++) {
     var pkgJson = pkgJsons[i];
 
-    if (deps_files[pkgJson.main] != null && pkgJson.provided != null) {
-      deps_files[pkgJson.main].provides = pkgJson.provided;
+    if (deps_files[pkgJson.main] != null && pkgJson.provides != null) {
+      deps_files[pkgJson.main].provides = pkgJson.provides;
     }
 
     deps_files[pkgJson.file] = { file: pkgJson.file };
   }
 
   var values = [];
   for (var key in deps_files) {
-    values.push(deps_files[key]);
+    var dep = deps_files[key];
+
+    if (dep.provides == null && !/node_modules\/[^/]*?\/package.json$/.test(dep.file)) {
+      var match = dep.file.match(/node_modules\/(.*)\.js(on)*$/)
+
+      if (match != null){
+        dep.provides = [ match[1] ];
+      }
+    }
+
+    values.push(dep);
   }
 
   process.stdout.write(JSON.stringify(values));

src/main/clojure/cljs/analyzer.cljc

@@ -2106,13 +2106,13 @@
   (str msg "; offending spec: " (pr-str spec)))
 
 (defn basic-validate-ns-spec [env macros? spec]
-  (when-not (or (symbol? spec) (sequential? spec))
+  (when-not (or (symbol? spec) (string? spec) (sequential? spec))
     (throw
       (error env
         (parse-ns-error-msg spec
           "Only [lib.ns & options] and lib.ns specs supported in :require / :require-macros"))))
   (when (sequential? spec)
-    (when-not (symbol? (first spec))
+    (when-not (or (symbol? (first spec)) (string? (first spec)))
       (throw
         (error env
           (parse-ns-error-msg spec
@@ -2210,7 +2210,7 @@
               (recur fs ret true)))))
 
 (defn parse-require-spec [env macros? deps aliases spec]
-  (if (symbol? spec)
+  (if (or (symbol? spec) (string? spec))
     (recur env macros? deps aliases [spec])
     (do
       (basic-validate-ns-spec env macros? spec)
@@ -2222,7 +2222,11 @@
             [lib js-module-provides] (if-some [js-module-name (get-in @env/*compiler* [:js-module-index (str lib)])]
                                        [(symbol js-module-name) lib]
                                        [lib nil])
-            {alias :as referred :refer renamed :rename :or {alias lib}} (apply hash-map opts)
+            {alias :as referred :refer renamed :rename
+             :or {alias (if (string? lib)
+                          (symbol (munge lib))
+                          lib)}}
+            (apply hash-map opts)
             referred-without-renamed (seq (remove (set (keys renamed)) referred))
             [rk uk renk] (if macros? [:require-macros :use-macros :rename-macros] [:require :use :rename])]
         (when-not (or (symbol? alias) (nil? alias))
@@ -3565,7 +3569,14 @@
                                                    (= "cljc" (util/ext src)))
                                             'cljs.core$macros
                                             ns-name)
-                                  deps (merge (:uses ast) (:requires ast))]
+                                  deps (merge (:uses ast) (:requires ast))
+                                  missing-js-modules (into #{}
+                                                       (comp
+                                                         (filter (fn [[k v]]
+                                                                   (and (or (string? k) (string? v))
+                                                                     (not (js-module-exists? k)))))
+                                                         (map val))
+                                                       deps)]
                               (merge
                                 {:ns           (or ns-name 'cljs.user)
                                  :provides     [ns-name]
@@ -3574,6 +3585,7 @@
                                                  (cond-> (conj (set (vals deps)) 'cljs.core)
                                                    (get-in @env/*compiler* [:options :emit-constants])
                                                    (conj constants-ns-sym)))
+                                 :missing-js-modules missing-js-modules
                                  :file         dest
                                  :source-file  (when rdr src)
                                  :source-forms (when-not rdr src)

src/main/clojure/cljs/closure.clj

@@ -1977,13 +1977,14 @@
     #(ensure-cljs-base-module % opts)))
 
 (defn add-implicit-options
-  [{:keys [optimizations output-dir npm-deps]
+  [{:keys [optimizations output-dir npm-deps missing-js-modules]
     :or {optimizations :none
          output-dir "out"}
     :as opts}]
   (let [opts (cond-> (update opts :foreign-libs
                        (fn [libs]
-                         (into (index-node-modules npm-deps opts)
+                         (into (index-node-modules
+                                 (into missing-js-modules (keys npm-deps)) opts)
                            (expand-libs libs))))
                (:closure-defines opts)
                (assoc :closure-defines
@@ -2003,7 +2004,7 @@
           :optimizations optimizations
           :output-dir output-dir
           :ups-libs libs
-          :ups-foreign-libs (into (index-node-modules (compute-upstream-npm-deps opts) opts)
+          :ups-foreign-libs (into (index-node-modules (keys (compute-upstream-npm-deps opts)) opts)
                               (expand-libs foreign-libs))
           :ups-externs externs
           :emit-constants emit-constants
@@ -2134,15 +2135,15 @@
    (into [] (distinct (mapcat #(node-module-deps % opts) entries)))))
 
 (defn index-node-modules
-  ([npm-deps]
+  ([modules]
    (index-node-modules
-     npm-deps
+     modules
      (when env/*compiler*
        (:options @env/*compiler*))))
-  ([npm-deps opts]
+  ([modules opts]
    (let [node-modules (io/file "node_modules")]
-     (if (and (not (empty? npm-deps)) (.exists node-modules) (.isDirectory node-modules))
-       (let [modules (map name (keys npm-deps))
+     (if (and (not (empty? modules)) (.exists node-modules) (.isDirectory node-modules))
+       (let [modules (into #{} (map name) modules)
              deps-file (io/file (str (util/output-directory opts) File/separator
                                   "cljs$node_modules.js"))]
          (util/mkdirs deps-file)
@@ -2252,15 +2253,21 @@
      (env/with-compiler-env compiler-env
        ;; we want to warn about NPM dep conflicts before installing the modules
        (check-npm-deps opts)
+       (maybe-install-node-deps! opts)
        (let [compiler-stats (:compiler-stats opts)
              static-fns? (or (and (= (:optimizations opts) :advanced)
-                                  (not (false? (:static-fns opts))))
-                             (:static-fns opts)
-                             ana/*cljs-static-fns*)
-             all-opts (-> opts
-                          maybe-install-node-deps!
-                          add-implicit-options
-                          process-js-modules)]
+                               (not (false? (:static-fns opts))))
+                           (:static-fns opts)
+                           ana/*cljs-static-fns*)
+             sources (-find-sources source opts)
+             missing-js-modules (into #{}
+                                  (comp
+                                    (map :missing-js-modules)
+                                    cat)
+                                  sources)
+             all-opts (-> (assoc opts :missing-js-modules missing-js-modules)
+                        add-implicit-options
+                        process-js-modules)]
          (check-output-to opts)
          (check-output-dir opts)
          (check-source-map opts)
@@ -2275,7 +2282,7 @@
              (assoc :target (:target opts))
              (assoc :js-dependency-index (deps/js-dependency-index all-opts))
              ;; Save list of sources for cljs.analyzer/locate-src - Juho Teperi
-             (assoc :sources (-find-sources source all-opts))))
+             (assoc :sources sources)))
          (binding [comp/*recompiled* (when-not (false? (:recompile-dependents opts))
                                        (atom #{}))
                    ana/*cljs-static-fns* static-fns?

src/test/clojure/cljs/analyzer_tests.clj

@@ -766,6 +766,18 @@
         (catch Exception _))
       (is (= ["cljs.core/aset, arguments must be an array, followed by numeric indices, followed by a value, got [object string number] instead (consider goog.object/set for object access)"] @ws)))))
 
+(deftest cljs-2061
+  (let [test-cenv (atom
+                    (merge @(e/default-compiler-env)
+                      {:js-module-index {"react" "module$src$test$cljs$react"}}))
+        ast (e/with-compiler-env test-cenv
+              (a/parse-ns
+                '[(ns test.cljs-2061
+                    (:require ["react" :as react]
+                              ["react-dom/server" :refer [renderToString]]))]))]
+    (is (= (:missing-js-modules ast) #{"react-dom/server"}))
+    (is (= (:requires ast) '#{cljs.core module$src$test$cljs$react "react-dom/server"}))))
+
 (comment
   (binding [a/*cljs-ns* a/*cljs-ns*]
     (a/no-warn