Flatten nested query and form parameter maps (#44)

Brought over flattening code from clj-http but not the options to
enable/disable flattening.

For us, for now, it is always enabled.

See updates to README for examples.

Closes #43

Author: lread

CHANGELOG.md

@@ -2,7 +2,9 @@
 
 - If specified, request's body encoding is now applied, else defaults to UTF-8 ([#18](https://github.com/clj-commons/clj-http-lite/issues/18)) ([@lread](https://github.com/lread))
 - User info from request URL now applied to basic auth ([#34](https://github.com/clj-commons/clj-http-lite/issues/34)) ([@lread](https://github.com/lread))
+- Nested query and form parameters are now automatically flattened ([#43](https://github.com/clj-commons/clj-http-lite/issues/43)) ([@lread](https://github.com/lread))
 - Quality
+  - Docstrings reviewed and updated
   - Automated CI testing added for Windows ([#21](https://github.com/clj-commons/clj-http-lite/issues/21)) ([@lread](https://github.com/lread))
 
 ### 0.4.384

README.md

@@ -18,11 +18,14 @@ A Clojure HTTP library similar to [clj-http](http://github.com/dakrone/clj-http)
 
 - Instead of Apache HttpClient, clj-http-lite uses HttpURLConnection
 - No automatic JSON decoding for response bodies
+- No automatic request body encoding beyond charset and url encoding of form params
 - No cookie support
 - No multipart form uploads
 - No persistent connection support
+- Fewer options
 - namespace rename clj-http.* -> clj-http.lite.*
 
+Like its namesake, clj-http-lite is light and simple, but ping us if there is some clj-http feature you'd like to see in clj-http-lite. We can discuss.
 ## History
 
 - Sep 2011 - [dakrone/clj-http](https://github.com/dakrone/clj-http) created (and is still actively maintained)
@@ -92,6 +95,41 @@ codes.
 The client transparently accepts and decompresses the `gzip` and
 `deflate` content encodings.
 
+### Nested params
+
+Nested parameter `{:a {:b 1}}` in `:form-params` or `:query-params` is automatically flattened to `a[b]=1`.
+We'll use `httpbin.org` to demonstrate:
+
+```clojure
+(-> (client/get "https://httpbin.org/get" 
+                {:query-params {:one {:two 2 :three 3}}})
+    :body
+    println)
+{
+  "args": {
+    "one[three]": "3",
+    "one[two]": "2"
+  },
+  ...
+}
+
+(-> (client/post "https://httpbin.org/post"
+                 {:form-params {:one {:two 2
+                                      :three {:four {:five 5}}}
+                                :six 6}})
+    :body
+    println)
+{
+  ...
+  "form": {
+    "one[three][four][five]": "5",
+    "one[two]": "2",
+    "six": "6"
+  },
+  ...
+}
+```
+
 ### Input coercion
 
 ```clojure
@@ -188,18 +226,11 @@ such), check out the
 
 ## Known Issues
 
-- Nested form params [aren't serialized correctly](https://github.com/hiredman/clj-http-lite/issues/15). There's an easy workaround however:
-
-    ```clojure
-    :form-params {"toplevel" {"nested" some-data}} ; doesn't work
-    :form-params {"toplevel[nested]" some-data}    ; works
-    ```
-
 - If you issue HTTPS connections, [Native Image](https://www.graalvm.org/docs/reference-manual/native-image/) compilation requires an additional parameter in order to enable its support in the generated image.
 
   If you get the following kind of error:
 
-      Exception in thread "main" java.net.MalformedURLException: Accessing an URL protocol that was not enabled.  
+      Exception in thread "main" java.net.MalformedURLException: Accessing an URL protocol that was not enabled.
       The URL protocol https is supported but not enabled by default. It must be enabled by adding the
       -H:EnableURLProtocols=https option to the native-image command.
 

src/clj_http/lite/client.clj

@@ -7,7 +7,8 @@
             [clj-http.lite.links :refer [wrap-links]]
             [clj-http.lite.util :as util]
             [clojure.java.io :as io]
-            [clojure.string :as str])
+            [clojure.string :as str]
+            [clojure.walk :as walk])
   (:import (java.net UnknownHostException)
            (java.nio.charset Charset))
   (:refer-clojure :exclude (get update)))
@@ -212,6 +213,27 @@
                          :body (generate-query-string form-params))))
       (client req))))
 
+(defn- nest-params
+  [req param-key]
+  (if-let [params (req param-key)]
+    (let [nested (walk/prewalk
+                   #(if (and (vector? %) (map? (second %)))
+                      (let [[fk m] %]
+                        (reduce
+                          (fn [m [sk v]]
+                            (assoc m (str (name fk)
+                                          \[ (name sk) \]) v))
+                          {}
+                          m))
+                      %)
+                   params)]
+      (assoc req param-key nested))
+    req))
+
+(defn wrap-nested-params [client]
+  (fn [req]
+    (client (-> req (nest-params :form-params) (nest-params :query-params)))))
+
 (defn wrap-url [client]
   (fn [req]
     (if-let [url (:url req)]
@@ -255,6 +277,7 @@
       wrap-accept-encoding
       wrap-content-type
       wrap-form-params
+      wrap-nested-params
       wrap-method
       wrap-links
       wrap-unknown-host))

test/clj_http/test/client_test.clj

@@ -299,6 +299,23 @@
       (is (= "untouched" (:body resp)))
       (is (not (contains? resp :content-type))))))
 
+(deftest apply-on-nest-params
+  (let [param-client (client/wrap-nested-params identity)
+        params {:a
+                {:b
+                 {:c 5}
+                 :e
+                 {:f 6}}
+                :g 7}
+        resp (param-client {:form-params params :query-params params})]
+    (is (= {"a[b][c]" 5 "a[e][f]" 6 :g 7} (:form-params resp) (:query-params resp)))))
+
+(deftest pass-on-no-nest-params
+  (let [m-client (client/wrap-nested-params identity)
+        in {:key :val}
+        out (m-client in)]
+    (is (= out in))))
+
 (deftest t-ignore-unknown-host
   (is (thrown? UnknownHostException (client/get "http://aorecuf892983a.com")))
   (is (nil? (client/get "http://aorecuf892983a.com"