avm2.intrinsics.memory.li8 and SWC

[pol2095]

Hello,

I have a strange behavior using avm2.intrinsics.memory.li8 in a swc, I have ths warning :
Warning: The definition avm2.intrinsics.memory.si8 depended on by com.utils.MyClass in the SWC C:\Users\user\myProjet\libs\MySwc.swc could not be found

using directly com.utils.MyClass without swc, I don't have this warning ?

Thanks

[ajwfrost]

I think you can ignore this .. we get that warning too, when linking in one of the SWC files for AIR SDK Manager. Will have to look at some point as to where it comes from; afaik the intrinsics are only used when doing the crossbridge compilations!

[pol2095]

Thanks
I needed to convert ARGB to RGBA for a 4K image and intrinsics can be 10x faster that ByteArray.readByte() and ByteArray.writeByte().
It use Domain Memory like crossbridge, it work only with ASC 2.0 compiler.

[ajwfrost]

Oh, I hadn't realised it was intentional usage! Interesting...
We had been looking at adding some accelerated functions for ByteArray data manipulation. For example on Android we have to do ARGB/RGBA conversion sometimes when doing font rendering from a Canvas into a TextField, and are using SIMD instructions (via neon intrinsics) - we were thinking it could be handy to expose those sorts of things to the ActionScript code too!

[pol2095]

I find a workaround here to remove this warning, avm2.intrinsics.memory work using ASC 1.0 in a swc too, very strange...

[pol2095]

I don't have the same result on Android (1,5x faster) vs 6x faster on Windows ?

[pol2095]

I don't understand this difference in performance between Windows and Android for ByteArray.readByte() and ByteArray.writeByte(), ByteArray on Android use AOT like on IOS ?

[ajwfrost]

What performance differences are you seeing? I wasn't 100% sure what your comparisons/factors referred to in your posts from last year?

Android doesn't use AOT, but those are native implementations anyway i.e. on all platforms they would be handled in the C++ runtime. There are additional checks and restrictions in byte array access to try to avoid vulnerabilities which may make it a little slower than an intrinsic access to domain memory (e.g. checking the bounds are okay, plus things like the size and memory pointers are hidden to avoid some of the old Flash Player exploits).

[pol2095]

to convert ARGB to RGBA I use :

package
{
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.system.ApplicationDomain;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.utils.ByteArray;
	import flash.utils.getTimer;
	
	import avm2.intrinsics.memory.li8;
	import avm2.intrinsics.memory.si8;

	public class Main extends Sprite
	{
		private var textField:TextField = new TextField();
		
		[Embed(source = "./Image4K.jpg")]
		private static const Image:Class;
		
		public function Main()
		{
			this.addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
		}
		
		private function addedToStageHandler(e:Event):void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			textField.background = true;
			textField.border = true;
			textField.wordWrap = true;
			textField.multiline = true;
			textField.y = 40;
			textField.width = 300;
			var format:TextFormat = new TextFormat();
			format.size = 40;
			textField.defaultTextFormat = format;
			this.addChild(textField);
			
			var sprite:Sprite = new Sprite();
			sprite.graphics.beginFill(0x0000FF);
			sprite.graphics.drawRect( 0, 0, 200, 200);
			sprite.graphics.endFill();
			sprite.y = textField.y + textField.height + 20;
			sprite.buttonMode = true;
			sprite.addEventListener(MouseEvent.CLICK, mouseClickIntrinsicsHandler);
			this.addChild( sprite );
			
			var sprite2:Sprite = new Sprite();
			sprite2.graphics.beginFill(0x00FF00);
			sprite2.graphics.drawRect( 220, 0, 200, 200);
			sprite2.graphics.endFill();
			sprite2.y = textField.y + textField.height + 20;
			sprite2.buttonMode = true;
			sprite2.addEventListener(MouseEvent.CLICK, mouseClickHandler);
			this.addChild( sprite2 );
		}
		
		private function mouseClickIntrinsicsHandler(event : MouseEvent) : void
		{
			var bitmapData:BitmapData = new Image().bitmapData;
			var bytes:ByteArray = bitmapData.getPixels( bitmapData.rect );
			bytes.position = 0;
			
			ApplicationDomain.currentDomain.domainMemory = bytes;
			
			var startTimer:int = getTimer();
			
			argb2rgbaIntrinsics( bytes );
			
			textField.text = "time intrinsics : " + ( getTimer() - startTimer );
			bytes.position = 0;
			
			ApplicationDomain.currentDomain.domainMemory = null;
		}
		
		private function mouseClickHandler(event : MouseEvent) : void
		{
			var bitmapData:BitmapData = new Image().bitmapData;
			var bytes:ByteArray = bitmapData.getPixels( bitmapData.rect );
			bytes.position = 0;
			
			var startTimer:int = getTimer();
			
			argb2rgba( bytes );
			
			textField.text = "time : " + ( getTimer() - startTimer );
			bytes.position = 0;
		}
		
		private function argb2rgbaIntrinsics(bytes:ByteArray):void
		{
			var len:int = bytes.length / 4;
			var A:int, R:int, G:int, B:int;
			var pos:int;
			for( var i:int = 0; i < len; i++ )
			{
				pos = i * 4;
				A = li8(pos);
				R = li8(pos + 1);
				G = li8(pos + 2);
				B = li8(pos + 3);
				
				si8(R, pos);
				si8(G, pos + 1);
				si8(B, pos + 2);
				si8(A, pos + 3);
			}
		}
		
		private function argb2rgba(bytes:ByteArray):void
		{
			var len:int = bytes.length / 4;
			var A:int, R:int, G:int, B:int;
			for( var i:int = 0; i < len; i++ )
			{
				A = bytes.readByte();
				R = bytes.readByte();
				G = bytes.readByte();
				B = bytes.readByte();
				
				bytes.position = i * 4;
				bytes.writeByte( R );
				bytes.writeByte( G );
				bytes.writeByte( B );
				bytes.writeByte( A );
			}
		}
	}
}

on Windows :
using intrinsics : 30 ms
using readByte() writeByte() : 900 ms

on Android :
using intrinsics : 330 ms
using readByte() writeByte() : 440 ms

Image4K