-
Notifications
You must be signed in to change notification settings - Fork 9
/
Copy pathSendChat.wl
2816 lines (2316 loc) · 111 KB
/
SendChat.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Section::Closed:: *)
(*Package Header*)
BeginPackage[ "Wolfram`Chatbook`SendChat`" ];
Begin[ "`Private`" ];
(* :!CodeAnalysis::BeginBlock:: *)
Needs[ "Wolfram`Chatbook`" ];
Needs[ "Wolfram`Chatbook`Actions`" ];
Needs[ "Wolfram`Chatbook`Common`" ];
Needs[ "Wolfram`Chatbook`Personas`" ];
(* ::**************************************************************************************************************:: *)
(* ::Section::Closed:: *)
(*Configuration*)
$resizeDingbats = True;
splitDynamicTaskFunction = createFETask;
$defaultHandlerKeys = { "Body", "BodyChunk", "BodyChunkProcessed", "StatusCode", "TaskStatus", "EventName" };
$chatSubmitDroppedHandlers = { "ChatPost", "ChatPre", "Resolved" };
(* ::**************************************************************************************************************:: *)
(* ::Subsection::Closed:: *)
(*Severity Tag String Patterns*)
$$whitespace = Longest[ WhitespaceCharacter... ];
$$severityTag = "ERROR"|"WARNING"|"INFO";
$$tagPrefix = StartOfString~~$$whitespace~~"["~~$$whitespace~~$$severityTag~~$$whitespace~~"]"~~$$whitespace;
$maxTagLength = Max[ StringLength /@ (List @@ $$severityTag) ] + 2;
(* ::**************************************************************************************************************:: *)
(* ::Subsection::Closed:: *)
(*Initialization*)
$dynamicTrigger = 0;
$lastDynamicUpdate = 0;
$buffer = "";
(* ::**************************************************************************************************************:: *)
(* ::Section::Closed:: *)
(*SendChat*)
(* ::**************************************************************************************************************:: *)
(* ::Subsection::Closed:: *)
(*sendChat*)
sendChat // beginDefinition;
sendChat[ evalCell_, nbo_, settings0_ ] /; $useLLMServices := catchTopAs[ ChatbookAction ] @ Enclose[
Module[ { settings, cells0, cells, target, messages, data, persona, cellTags, cell, cellObject, container, task },
initFETaskWidget @ nbo;
resolveInlineReferences @ evalCell;
settings = ConfirmBy[ resolveAutoSettings @ settings0, AssociationQ, "ResolveSettings" ];
cells0 = ConfirmMatch[ selectChatCells[ settings, evalCell, nbo ], { __CellObject }, "SelectChatCells" ];
{ cells, target } = ConfirmMatch[
chatHistoryCellsAndTarget @ cells0 // LogChatTiming[ "ChatHistoryCellsAndTarget" ],
{ { __CellObject }, _CellObject | None },
"HistoryAndTarget"
];
$finishReason = None;
$multimodalMessages = TrueQ @ settings[ "Multimodal" ];
$chatIndicatorSymbol = chatIndicatorSymbol @ settings;
If[ TrueQ @ settings[ "EnableChatGroupSettings" ],
AppendTo[ settings, "ChatGroupSettings" -> getChatGroupSettings @ evalCell ];
$currentChatSettings = settings;
];
ConfirmBy[ initializeProgressContainer @ container, AssociationQ, "InitializeProgress" ];
$reformattedCell = None;
cellTags = CurrentValue[ evalCell, CellTags ];
cell = activeAIAssistantCell[
container,
Association[ settings, "Container" :> container, "CellObject" :> cellObject, "Task" :> task ],
cellTags
];
Quiet[
TaskRemove @ $lastTask;
NotebookDelete @ $lastCellObject;
];
cellObject = $lastCellObject = ConfirmMatch[
createNewChatOutput[ settings, target, cell ],
_CellObject,
"CreateOutput"
] // LogChatTiming[ "CreateChatOutput" ];
If[ ! settings[ "IncludeHistory" ], cells = { evalCell } ];
{ messages, data } = Reap[
ConfirmMatch[
constructMessages[ settings, cells ] // LogChatTiming[ "ConstructMessages" ],
{ __Association },
"ConstructMessages"
],
$chatDataTag
] // withApproximateProgress[ "Creating messages", 0.3 ];
data = ConfirmBy[ Association @ Flatten @ data, AssociationQ, "Data" ];
If[ data[ "RawOutput" ],
persona = ConfirmBy[ GetCachedPersonaData[ "RawModel" ], AssociationQ, "NonePersona" ];
If[ AssociationQ @ settings[ "LLMEvaluator" ],
settings[ "LLMEvaluator" ] = Association[ settings[ "LLMEvaluator" ], persona ],
settings = Association[ settings, persona ]
];
$currentChatSettings = settings;
];
AppendTo[ settings, "Data" -> data ];
CurrentChatSettings[ cellObject, "Data" ] = data;
$resultCellCache = <| |>;
$debugLog = Internal`Bag[ ];
If[ settings[ "SetCellDingbat" ] && ! TrueQ @ $cloudNotebooks && chatInputCellQ @ evalCell,
SetOptions[
evalCell,
CellDingbat -> ReplaceAll[
CurrentValue[ evalCell, CellDingbat ],
TemplateBox[ { }, "ChatInputActiveCellDingbat" ] -> TemplateBox[ { }, "ChatInputCellDingbat" ]
]
] // LogChatTiming[ "SetCellDingbat" ]
];
applyHandlerFunction[
settings,
"ChatPre",
<|
"EvaluationCell" -> evalCell,
"Messages" -> messages,
"CellObject" -> cellObject,
"Container" :> container
|>
];
task = $lastTask = chatSubmit[
container,
prepareMessagesForLLM @ messages,
cellObject,
settings
] // withApproximateProgress[ "Sending chat", 0.4 ];
addHandlerArguments[ "Task" -> task ];
CurrentChatSettings[ cellObject, "CellObject" ] = cellObject;
CurrentChatSettings[ cellObject, "Task" ] = task;
If[ FailureQ @ task, throwTop @ writeErrorCell[ cellObject, task ] ];
setProgressDisplay[ "Waiting for response", 1.0 ];
If[ task === $Canceled, StopChat @ cellObject ];
task
],
throwInternalFailure
];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
sendChat[ evalCell_, nbo_, settings0_ ] := catchTopAs[ ChatbookAction ] @ Enclose[
Module[
{
settings, cells0, cells, target, id, key, messages, req, data, persona,
cellTags, cell, cellObject, container, task
},
initFETaskWidget @ nbo;
resolveInlineReferences @ evalCell;
settings = ConfirmBy[ resolveAutoSettings @ settings0, AssociationQ, "ResolveSettings" ];
cells0 = ConfirmMatch[ selectChatCells[ settings, evalCell, nbo ], { __CellObject }, "SelectChatCells" ];
{ cells, target } = ConfirmMatch[
chatHistoryCellsAndTarget @ cells0,
{ { __CellObject }, _CellObject | None },
"HistoryAndTarget"
];
$finishReason = None;
$multimodalMessages = TrueQ @ settings[ "Multimodal" ];
$chatIndicatorSymbol = chatIndicatorSymbol @ settings;
If[ TrueQ @ settings[ "EnableChatGroupSettings" ],
AppendTo[ settings, "ChatGroupSettings" -> getChatGroupSettings @ evalCell ];
$currentChatSettings = settings;
];
id = Lookup[ settings, "ID" ];
key = toAPIKey[ Automatic, id ];
If[ ! settings[ "IncludeHistory" ], cells = { evalCell } ];
If[ ! StringQ @ key, throwFailure[ "NoAPIKey" ] ];
settings[ "OpenAIKey" ] = key;
{ req, data } = Reap[
ConfirmMatch[
makeHTTPRequest[ settings, messages = constructMessages[ settings, cells ] ],
_HTTPRequest,
"MakeHTTPRequest"
],
$chatDataTag
];
data = ConfirmBy[ Association @ Flatten @ data, AssociationQ, "Data" ];
If[ data[ "RawOutput" ],
persona = ConfirmBy[ GetCachedPersonaData[ "RawModel" ], AssociationQ, "NonePersona" ];
If[ AssociationQ @ settings[ "LLMEvaluator" ],
settings[ "LLMEvaluator" ] = Association[ settings[ "LLMEvaluator" ], persona ],
settings = Association[ settings, persona ]
];
$currentChatSettings = settings;
];
AppendTo[ settings, "Data" -> data ];
container = <|
"DynamicContent" -> ProgressIndicator[ Appearance -> "Percolate" ],
"FullContent" -> ProgressIndicator[ Appearance -> "Percolate" ],
"UUID" -> CreateUUID[ ]
|>;
$reformattedCell = None;
cellTags = CurrentValue[ evalCell, CellTags ];
cell = activeAIAssistantCell[
container,
Association[ settings, "Container" :> container, "CellObject" :> cellObject, "Task" :> task ],
cellTags
];
Quiet[
TaskRemove @ $lastTask;
NotebookDelete @ $lastCellObject;
];
$resultCellCache = <| |>;
$debugLog = Internal`Bag[ ];
If[ settings[ "SetCellDingbat" ] && ! TrueQ @ $cloudNotebooks && chatInputCellQ @ evalCell,
SetOptions[
evalCell,
CellDingbat -> ReplaceAll[
CurrentValue[ evalCell, CellDingbat ],
TemplateBox[ { }, "ChatInputActiveCellDingbat" ] -> TemplateBox[ { }, "ChatInputCellDingbat" ]
]
]
];
cellObject = $lastCellObject = ConfirmMatch[
createNewChatOutput[ settings, target, cell ],
_CellObject,
"CreateOutput"
];
applyHandlerFunction[
settings,
"ChatPre",
<|
"EvaluationCell" -> evalCell,
"Messages" -> messages,
"CellObject" -> cellObject,
"Container" :> container
|>
];
task = $lastTask = chatSubmit[ container, req, cellObject, settings ];
addHandlerArguments[ "Task" -> task ];
CurrentValue[ cellObject, { TaggingRules, "ChatNotebookSettings", "CellObject" } ] = cellObject;
CurrentValue[ cellObject, { TaggingRules, "ChatNotebookSettings", "Task" } ] = task;
If[ FailureQ @ task, throwTop @ writeErrorCell[ cellObject, task ] ];
If[ task === $Canceled, StopChat @ cellObject ];
task
],
throwInternalFailure
];
sendChat // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsection::Closed:: *)
(*makeHTTPRequest*)
makeHTTPRequest // beginDefinition;
makeHTTPRequest[ settings_Association? AssociationQ, messages: { __Association } ] :=
Enclose @ Module[
{ key, stream, model, tokens, temperature, topP, freqPenalty, presPenalty, data, body, apiCompletionURL },
key = ConfirmBy[ Lookup[ settings, "OpenAIKey" ], StringQ ];
stream = True;
apiCompletionURL = ConfirmBy[ Lookup[ settings, "OpenAIAPICompletionURL" ], StringQ ];
(* model parameters *)
model = Lookup[ settings, "Model" , $DefaultModel ];
tokens = Lookup[ settings, "MaxTokens" , Automatic ];
temperature = Lookup[ settings, "Temperature" , 0.7 ];
topP = Lookup[ settings, "TopP" , 1 ];
freqPenalty = Lookup[ settings, "FrequencyPenalty", 0.1 ];
presPenalty = Lookup[ settings, "PresencePenalty" , 0.1 ];
data = DeleteCases[
<|
"messages" -> prepareMessagesForHTTPRequest @ messages,
"temperature" -> temperature,
"max_tokens" -> tokens,
"top_p" -> topP,
"frequency_penalty" -> freqPenalty,
"presence_penalty" -> presPenalty,
"model" -> toModelName @ model,
"stream" -> stream,
"stop" -> makeStopTokens @ settings
|>,
Automatic|_Missing
];
body = ConfirmBy[ Developer`WriteRawJSONString[ data, "Compact" -> True ], StringQ ];
$lastHTTPParameters = data;
$lastRequest = HTTPRequest[
apiCompletionURL,
<|
"Headers" -> <|
"Content-Type" -> "application/json",
"Authorization" -> "Bearer "<>key
|>,
"Body" -> body,
"Method" -> "POST"
|>
]
];
makeHTTPRequest // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessagesForLLM*)
prepareMessagesForLLM // beginDefinition;
prepareMessagesForLLM[ messages: { ___Association } ] := ReplaceAll[
messages,
s_String :> RuleCondition @ StringTrim @ StringReplace[
s,
"\nENDRESULT(" ~~ Repeated[ LetterCharacter|DigitCharacter, $tinyHashLength ] ~~ ")\n" :> "\nENDRESULT\n"
]
];
prepareMessagesForLLM // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*makeStopTokens*)
makeStopTokens // beginDefinition;
makeStopTokens[ settings_Association ] := makeStopTokens[ settings, settings[ "StopTokens" ] ];
makeStopTokens[ settings_, None | { } ] := Missing[ ];
makeStopTokens[ settings_, tokens: { __String } ] := tokens;
makeStopTokens // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*chatIndicatorSymbol*)
chatIndicatorSymbol // beginDefinition;
chatIndicatorSymbol[ settings_Association ] := chatIndicatorSymbol @ settings[ "ChatInputIndicator" ];
chatIndicatorSymbol[ $$unspecified ] := $chatIndicatorSymbol;
chatIndicatorSymbol[ None|"" ] := None;
chatIndicatorSymbol[ string_String? StringQ ] := string;
chatIndicatorSymbol // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessagesForHTTPRequest*)
prepareMessagesForHTTPRequest // beginDefinition;
prepareMessagesForHTTPRequest[ messages_List ] :=
$lastHTTPMessages = prepareMessagesForLLM[ prepareMessageForHTTPRequest /@ messages ];
prepareMessagesForHTTPRequest // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessageForHTTPRequest*)
prepareMessageForHTTPRequest // beginDefinition;
prepareMessageForHTTPRequest[ message_Association? AssociationQ ] := AssociationMap[ prepareMessageRule, message ];
prepareMessageForHTTPRequest // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessageRule*)
prepareMessageRule // beginDefinition;
prepareMessageRule[ "Role"|"role" -> role_String ] := "role" -> ToLowerCase @ role;
prepareMessageRule[ "Content"|"content" -> content_ ] := "content" -> prepareMessageContent @ content;
prepareMessageRule[ key_String -> value_ ] := ToLowerCase @ key -> value;
prepareMessageRule // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessageContent*)
prepareMessageContent // beginDefinition;
prepareMessageContent[ content_String ] := content;
prepareMessageContent[ content_List ] := prepareMessagePart /@ content;
prepareMessageContent // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareMessagePart*)
prepareMessagePart // beginDefinition;
prepareMessagePart[ text_String ] := prepareMessagePart @ <| "Type" -> "Text" , "Data" -> text |>;
prepareMessagePart[ image_? graphicsQ ] := prepareMessagePart @ <| "Type" -> "Image", "Data" -> image |>;
prepareMessagePart[ file_File ] := prepareMessagePart @ <| "Type" -> partType @ file, "Data" -> file |>;
prepareMessagePart[ url_URL ] := prepareMessagePart @ <| "Type" -> partType @ url , "Data" -> url |>;
prepareMessagePart[ part_? AssociationQ ] := prepareMessagePart0 @ KeyMap[ ToLowerCase, part ];
prepareMessagePart // endDefinition;
prepareMessagePart0 // beginDefinition;
prepareMessagePart0[ part_Association ] := <|
KeyDrop[ part, "data" ],
prepareMessagePart0[ part[ "type" ], part[ "data" ] ]
|>;
prepareMessagePart0[ "Text" , text_ ] := <| "type" -> "text" , "text" -> prepareTextPart @ text |>;
prepareMessagePart0[ "Image", img_ ] := <| "type" -> "image_url", "image_url" -> prepareImageURLPart @ img |>;
prepareMessagePart0 // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareImageURLPart*)
prepareImageURLPart // beginDefinition;
prepareImageURLPart[ URL[ url_String ] ] := <| "url" -> url |>;
prepareImageURLPart[ file_File ] := With[ { img = importImage @ file }, prepareImageURLPart @ img /; graphicsQ @ img ];
prepareImageURLPart[ image_ ] := prepareImageURLPart @ URL @ toImageURI @ image;
prepareImageURLPart // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsubsection::Closed:: *)
(*importImage*)
importImage // beginDefinition;
importImage[ file_File ] := importImage[ file, fastFileHash @ file ];
importImage[ file_, hash_Integer ] := With[ { img = $importImageCache[ file, hash ] }, img /; image2DQ @ img ];
importImage[ file_, hash_Integer ] := $importImageCache[ file ] = <| hash -> importImage0 @ file |>;
importImage // endDefinition;
$importImageCache = <| |>;
importImage0 // beginDefinition;
importImage0[ file_ ] := importImage0[ file, Import[ file, "Image" ] ];
importImage0[ file_, img_? graphicsQ ] := img;
importImage0 // endDefinition;
(* TODO: if an "ExternalFile" type of chat cell is defined, this should throw appropriate error text here *)
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*prepareTextPart*)
prepareTextPart // beginDefinition;
prepareTextPart[ text_String? StringQ ] := text;
prepareTextPart[ file_File? FileExistsQ ] := prepareTextPart @ readString @ file;
prepareTextPart[ url_URL ] := prepareTextPart @ URLRead[ url, "Body" ];
prepareTextPart[ failure_Failure ] := makeFailureString @ failure;
prepareTextPart // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*partType*)
partType // beginDefinition;
partType[ url_URL ] := "Image"; (* this could determine type automatically, but it would likely be too slow *)
partType[ file_File ] := partType[ file, fastFileHash @ file ];
partType[ file_, hash_Integer ] := With[ { type = $partTypeCache[ file, hash ] }, type /; StringQ @ type ];
partType[ file_, hash_Integer ] := With[ { t = partType0 @ file }, $partTypeCache[ file ] = <| hash -> t |>; t ];
partType // endDefinition;
$partTypeCache = <| |>;
partType0 // beginDefinition;
partType0[ file_ ] := partType0[ file, FileFormat @ file ];
partType0[ file_, fmt_String ] := partType0[ file, fmt, FileFormatProperties[ fmt, "ImportElements" ] ];
partType0[ file_, fmt_, { ___, "Image", ___ } ] := "Image";
partType0[ file_, fmt_, _List ] := "Text";
partType0 // endDefinition;
(* TODO: if an "ExternalFile" type of chat cell is defined, this should throw appropriate error text here *)
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*toImageURI*)
toImageURI // beginDefinition;
toImageURI[ image_? image2DQ ] :=
toImageURI[ image, "JPEG" ];
toImageURI[ image_ ] :=
toImageURI[ image, "PNG" ];
toImageURI[ image_, fmt_ ] := Enclose[
Module[ { resized, uri },
resized = ConfirmBy[ resizeMultimodalImage @ image, image2DQ, "Resized" ];
uri = ConfirmBy[ exportDataURI[ resized, fmt ], StringQ, "URI" ];
toImageURI[ image ] = uri
],
throwInternalFailure[ toImageURI @ image, ## ] &
];
toImageURI // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsection::Closed:: *)
(*chatSubmit*)
chatSubmit // beginDefinition;
chatSubmit // Attributes = { HoldFirst };
chatSubmit[ args__ ] := Quiet[
rasterizeBlock @ chatSubmit0 @ args,
{
ServiceConnections`SavedConnections::wname,
ServiceConnections`ServiceConnections::wname,
URLSubmit::invm,
URLSubmit::invk
}
];
chatSubmit // endDefinition;
(* TODO: chatHandlers could probably filter valid keys instead of quieting URLSubmit::invm, but the list of available
events is defined via a private symbol that might not be safe to use:
URLUtilities`Submit`PackagePrivate`$eventNames
*)
chatSubmit0 // beginDefinition;
chatSubmit0 // Attributes = { HoldFirst };
(* Currently used for o1 models since they don't support streaming: *)
chatSubmit0[
container_,
messages: { __Association },
cellObject_,
settings_
] /; settings[ "ForceSynchronous" ] := Enclose[
Module[ { auth, stop, result },
auth = settings[ "Authentication" ];
stop = makeStopTokens @ settings;
setProgressDisplay[ "Waiting for response", 1.0 ];
result = ConfirmMatch[
Quiet[
LLMServices`Chat[
standardizeMessageKeys @ messages,
makeLLMConfiguration @ settings,
Authentication -> auth
],
{ LLMServices`Chat::unsupported }
],
_Association | _Failure,
"ChatResult"
];
If[ FailureQ @ result, throwTop @ writeErrorCell[ cellObject, result ] ];
writeChunk[ Dynamic @ container, cellObject, <| "BodyChunkProcessed" -> result[ "Content" ] |> ];
logUsage @ container;
trimStopTokens[ container, stop ];
checkResponse[ settings, Unevaluated @ container, cellObject, <| |> ];
(* This cannot return a TaskObject: *)
None
],
throwInternalFailure
];
chatSubmit0[ container_, messages: { __Association }, cellObject_, settings_ ] := Quiet[
Needs[ "LLMServices`" -> None ];
$lastChatSubmitResult = ReleaseHold[
$lastChatSubmit = HoldForm @ applyProcessingFunction[
settings,
"ChatSubmit",
HoldComplete[
standardizeMessageKeys @ messages,
makeLLMConfiguration @ settings,
Authentication -> settings[ "Authentication" ],
HandlerFunctions -> chatHandlers[ container, cellObject, settings ],
HandlerFunctionsKeys -> chatHandlerFunctionsKeys @ settings,
"TestConnection" -> False
],
<|
"Container" :> container,
"Messages" -> messages,
"CellObject" -> cellObject,
"DefaultSubmitFunction" -> LLMServices`ChatSubmit
|>,
LLMServices`ChatSubmit
]
],
{ LLMServices`ChatSubmit::unsupported }
];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
chatSubmit0[ container_, req: HoldPattern[ _HTTPRequest ], cellObject_, settings_ ] := (
$buffer = "";
applyProcessingFunction[
settings,
"ChatSubmit",
HoldComplete[
req,
HandlerFunctions -> chatHandlers[ container, cellObject, settings ],
HandlerFunctionsKeys -> chatHandlerFunctionsKeys @ settings,
CharacterEncoding -> "UTF8"
],
<|
"Container" :> container,
"Request" -> req,
"CellObject" -> cellObject,
"DefaultSubmitFunction" -> URLSubmit
|>,
URLSubmit
]
);
chatSubmit0 // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*makeLLMConfiguration*)
makeLLMConfiguration // beginDefinition;
makeLLMConfiguration[ as: KeyValuePattern[ "Model" -> model_String ] ] :=
makeLLMConfiguration @ Append[ as, "Model" -> { "OpenAI", model } ];
makeLLMConfiguration[ as_Association ] :=
$lastLLMConfiguration = LLMConfiguration @ DeleteMissing @ Association[
KeyTake[ as, { "Model", "MaxTokens", "Temperature", "PresencePenalty" } ],
"StopTokens" -> makeStopTokens @ as
];
makeLLMConfiguration // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*chatHandlerFunctionsKeys*)
chatHandlerFunctionsKeys // beginDefinition;
chatHandlerFunctionsKeys[ as_? AssociationQ ] := chatHandlerFunctionsKeys[ as, as[ "HandlerFunctionsKeys" ] ];
chatHandlerFunctionsKeys[ as_, $$unspecified ] := $defaultHandlerKeys;
chatHandlerFunctionsKeys[ as_, keys_List ] := Union[ Select[ Flatten @ keys, StringQ ], $defaultHandlerKeys ];
chatHandlerFunctionsKeys[ as_, key_String ] := chatHandlerFunctionsKeys[ as, { key } ];
chatHandlerFunctionsKeys[ as_, invalid_ ] := (messagePrint[ "InvalidHandlerKeys", invalid ]; $defaultHandlerKeys);
chatHandlerFunctionsKeys // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*chatHandlers*)
chatHandlers // beginDefinition;
chatHandlers // Attributes = { HoldFirst };
chatHandlers[ container_, cellObject_, settings_ ] :=
$lastHandlers = With[
{
autoOpen = TrueQ @ $autoOpen,
alwaysOpen = TrueQ @ $alwaysOpen,
autoAssist = $AutomaticAssistance,
dynamicSplit = dynamicSplitQ @ settings,
handlers = getHandlerFunctions @ settings,
useTasks = feTaskQ @ settings,
toolFormatter = getToolFormatter @ settings,
stop = makeStopTokens @ settings
},
{
bodyChunkHandler = Lookup[ handlers, "BodyChunkReceived", None ],
taskFinishedHandler = Lookup[ handlers, "TaskFinished" , None ]
},
<|
KeyDrop[ handlers, $chatSubmitDroppedHandlers ],
"BodyChunkReceived" -> Function @ catchAlways[
withFETasks[ useTasks ] @ Block[
{
$alwaysOpen = alwaysOpen,
$AutomaticAssistance = autoAssist,
$autoOpen = autoOpen,
$customToolFormatter = toolFormatter,
$dynamicSplit = dynamicSplit,
$settings = settings
},
bodyChunkHandler[ #1 ];
Internal`StuffBag[ $debugLog, $lastStatus = #1 ];
checkFinishReason[ #1 ];
writeChunk[ Dynamic @ container, cellObject, #1 ]
]
],
"TaskFinished" -> Function @ catchAlways[
withFETasks[ useTasks ] @ Block[
{
$alwaysOpen = alwaysOpen,
$AutomaticAssistance = autoAssist,
$autoOpen = autoOpen,
$customToolFormatter = toolFormatter,
$dynamicSplit = dynamicSplit,
$settings = settings
},
taskFinishedHandler[ #1 ];
Internal`StuffBag[ $debugLog, $lastStatus = #1 ];
checkFinishReason[ #1 ];
logUsage @ container;
trimStopTokens[ container, stop ];
checkResponse[ $settings, Unevaluated @ container, cellObject, #1 ]
]
]
|>
];
chatHandlers // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*trimStopTokens*)
trimStopTokens // beginDefinition;
trimStopTokens // Attributes = { HoldFirst };
trimStopTokens[ container_, stop: { ___String } ] :=
With[ { full = container[ "FullContent" ], dynamic = container[ "DynamicContent" ] },
(
container[ "DynamicContent" ] = StringDelete[ dynamic, stop~~EndOfString ];
container[ "FullContent" ] = StringDelete[ full , stop~~EndOfString ];
) /; StringQ @ full
];
trimStopTokens[ container_, { ___String } | _Missing ] :=
Null;
trimStopTokens // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*checkFinishReason*)
checkFinishReason // beginDefinition;
checkFinishReason[ as_Association ] := checkFinishReason @ as[ "BodyChunk" ];
checkFinishReason[ _Missing ] := Null;
checkFinishReason[ chunk_String ] :=
Module[ { reasons },
reasons = StringCases[ chunk, "\"finish_reason\":\"" ~~ reason: Except[ "\"" ].. ~~ "\"" :> reason ];
If[ MatchQ[ reasons, { ___, _String } ], $finishReason = Last @ reasons ]
];
checkFinishReason // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*feTaskQ*)
feTaskQ // beginDefinition;
feTaskQ[ settings_ ] := feTaskQ[ settings, settings[ "NotebookWriteMethod" ] ];
feTaskQ[ settings_, "ServiceLink" ] := False;
feTaskQ[ settings_, "PreemptiveLink" ] := True;
feTaskQ[ settings_, $$unspecified ] := True;
feTaskQ[ settings_, invalid_ ] := (messagePrint[ "InvalidWriteMethod", invalid ]; True);
feTaskQ // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*withFETasks*)
withFETasks // beginDefinition;
withFETasks[ False ] := Function[ eval, Block[ { createFETask = #1 & }, eval ], HoldFirst ];
withFETasks[ True ] := #1 &;
withFETasks // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*writeChunk*)
writeChunk // beginDefinition;
writeChunk[ container_, cell_, as: KeyValuePattern[ "BodyChunkProcessed" -> chunks_ ] ] :=
With[ { strings = extractBodyChunks @ chunks },
Which[
FailureQ @ strings,
throwFailureToChatOutput @ strings,
MatchQ[ strings, { __String } ],
With[ { chunk = StringJoin @ strings }, writeChunk0[ container, cell, chunk, chunk ] ],
True,
Null
]
];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk[ container_, cell_, KeyValuePattern[ "BodyChunk" -> chunk_String ] ] :=
writeChunk[ container, cell, $buffer <> chunk ];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk[ container_, cell_, chunk_String ] :=
Module[ { ws, sep, parts, buffer },
ws = WhitespaceCharacter...;
sep = "\n\n" | "\r\n\r\n";
parts = StringTrim @ StringCases[ chunk, "data:" ~~ ws ~~ json: Except[ "\n" ].. ~~ sep :> json ];
buffer = StringDelete[ StringDelete[ chunk, "data:" ~~ ws ~~ parts ~~ sep ], StartOfString ~~ "\n".. ];
$buffer = buffer;
writeChunk0[ container, cell, #1 ] & /@ parts
];
writeChunk // endDefinition;
writeChunk0 // beginDefinition;
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk0[ container_, cell_, "" | "[DONE]" | "[DONE]\n\n" ] :=
Null;
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk0[ container_, cell_, chunk_String ] :=
writeChunk0[ container, cell, chunk, Quiet @ Developer`ReadRawJSONString @ chunk ];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk0[
container_,
cell_,
chunk_String,
KeyValuePattern[ "choices" -> { KeyValuePattern[ "delta" -> KeyValuePattern[ "content" -> text_String ] ], ___ } ]
] := writeChunk0[ container, cell, chunk, text ];
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk0[
container_,
cell_,
chunk_String,
KeyValuePattern[ "choices" -> { KeyValuePattern @ { "delta" -> <| |>, "finish_reason" -> "stop" }, ___ } ]
] := Null;
(* TODO: this definition is obsolete once LLMServices is widely available: *)
writeChunk0[
container_,
cell_,
chunk_String,
KeyValuePattern[ "completion" -> text_String ]
] := writeChunk0[ container, cell, chunk, text ];
writeChunk0[ Dynamic[ container_ ], cell_, chunk_String, text_String ] := (
appendStringContent[ container[ "FullContent" ], text ];
appendStringContent[ container[ "DynamicContent" ], text ];
(* FIXME: figure out what to do here when there's a custom formatter *)
If[ TrueQ @ $dynamicSplit,
(* Convert as much of the dynamic content as possible to static boxes and write to cell: *)
splitDynamicContent[ container, cell ]
];
If[ AbsoluteTime[ ] - $lastDynamicUpdate > 0.05,
(* Trigger updating of dynamic content in current chat output cell *)
$dynamicTrigger++;
$lastDynamicUpdate = AbsoluteTime[ ]
];
(* Handle auto-opening of assistant cells: *)
Which[
errorTaggedQ @ container, processErrorCell[ container, cell ],
warningTaggedQ @ container, processWarningCell[ container, cell ],
infoTaggedQ @ container, processInfoCell[ container, cell ],
untaggedQ @ container, openChatCell @ cell,
True, Null
]
);
writeChunk0[ Dynamic[ container_ ], cell_, chunk_String, other_ ] :=
Internal`StuffBag[ $chunkDebug, <| "chunk" -> chunk, "other" -> other |> ];
writeChunk0 // endDefinition;
$chunkDebug = Internal`Bag[ ];
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*appendStringContent*)
appendStringContent // beginDefinition;
appendStringContent // Attributes = { HoldFirst };
appendStringContent[ container_, text_String ] := Quiet[
If[ StringQ @ container,
container = autoCorrect @ StringDelete[ container <> convertUTF8 @ text, StartOfString~~Whitespace ],
container = autoCorrect @ convertUTF8 @ text
],
$CharacterEncoding::utf8
];
appendStringContent // endDefinition;
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*autoCorrect*)
autoCorrect // beginDefinition;
autoCorrect[ string_String ] := StringReplace[ string, $llmAutoCorrectRules ];
autoCorrect // endDefinition;
$$specialBoxName = "AudioBox"|"MarkdownImageBox"|"VideoBox";
$llmAutoCorrectRules := $llmAutoCorrectRules = Flatten @ {
StartOfLine ~~ WhitespaceCharacter... ~~ "/command\ncode:" :> "/wl\ncode:",
"```" ~~ code: Except[ "\n" ].. ~~ "```" :> "``"<>code<>"``",
"wolfram_language_evaliator" -> "wolfram_language_evaluator",
"\\!\\(\\*"~~$$specialBoxName~~"[\"" ~~ Shortest[ uri__ ] ~~ "\"]\\)" :> uri,
"\\!\\("~~$$specialBoxName~~"[\"" ~~ Shortest[ uri__ ] ~~ "\"]\\)" :> uri,
"\"\\\\!\\\\(\\\\*"~~$$specialBoxName~~"[\\\"" ~~ Shortest[ uri__ ] ~~ "\\\"]\\\\)\"" :> uri,
"\"\\\\!\\\\("~~$$specialBoxName~~"[\\\"" ~~ Shortest[ uri__ ] ~~ "\\\"]\\\\)\"" :> uri,
"<" ~~ Shortest[ scheme: LetterCharacter.. ~~ "://" ~~ id: Except[ "!" ].. ] ~~ ">" :>
"<!" <> scheme <> "://" <> id <> "!>",
"\\uf351" -> "\[FreeformPrompt]",
"\n<|image_sentinel|>\n" :> "\n",
"<|image_sentinel|>" :> "",
$longNameCharacters
};
(* TODO:
Automatically rewrite these as WL tool calls:
Sure! I will use `EmbeddedService` to show a map of Tokyo by utilizing the OpenStreetMap service.
```wl
EmbeddedService[{\"OpenStreetMap\", GeoPosition[\[FreeformPrompt][\"Tokyo\"]]}]
``` /exec
=====
To show a map of the United States with all its state capitals, we can use the [GeoGraphics](paclet:ref/GeoGraphics) function along with [Entity](paclet:ref/Entity) to get the positions of the capitals. Here's how you can do it:
```wl
GeoGraphics[
{Red, PointSize[Large],
Point[GeoPosition /@ EntityValue[
EntityClass["AdministrativeDivision", "USStates"],
"CapitalLocation"
]]
},
GeoRange -> Entity["Country", "UnitedStates"]
]
```
Let me create this map for you. /wl
*)
(* ::**************************************************************************************************************:: *)
(* ::Subsubsection::Closed:: *)
(*splitDynamicContent*)
splitDynamicContent // beginDefinition;
splitDynamicContent // Attributes = { HoldFirst };
(* NotebookLocationSpecifier isn't available before 13.3 and splitting isn't yet supported in cloud: *)
splitDynamicContent[ container_, cell_ ] /; Or[
$InlineChat,
! $dynamicSplit,
insufficientVersionQ[ "DynamicSplit" ],
$cloudNotebooks
] := Null;
splitDynamicContent[ container_, cell_ ] :=
splitDynamicContent[ container, container[ "DynamicContent" ], cell, container[ "UUID" ] ];
splitDynamicContent[ container_, text_String, cell_, uuid_String ] :=
splitDynamicContent[ container, DeleteCases[ StringSplit[ text, $dynamicSplitRules ], "" ], cell, uuid ];
splitDynamicContent[ container_, { static__String, dynamic_String }, cell_, uuid_String ] := Enclose[
Catch @ Module[ { boxObject, settings, reformatted, write, nbo },
boxObject = ConfirmMatch[
getBoxObjectFromBoxID[ cell, uuid ],
_BoxObject | Missing[ "CellRemoved", ___ ],
"BoxObject"
];
If[ MatchQ[ boxObject, Missing[ "CellRemoved", ___ ] ],
throwTop[ Quiet[ TaskRemove @ $lastTask, TaskRemove::timnf ]; Null ]
];
settings = ConfirmBy[ $ChatHandlerData[ "ChatNotebookSettings" ], AssociationQ, "Settings" ];
reformatted = ConfirmMatch[
If[ TrueQ @ settings[ "AutoFormat" ],
Block[ { $dynamicText = False }, reformatTextData @ StringJoin @ static ],
{ StringJoin @ static }
],
$$textDataList,
"ReformatTextData"
];
write = Cell[ TextData @ reformatted, "ChatOutput", Background -> None, CellFrame -> 0 ];
nbo = ConfirmMatch[ parentNotebook @ cell, _NotebookObject, "ParentNotebook" ];
container[ "DynamicContent" ] = dynamic;
With[ { boxObject = boxObject, write = write },
splitDynamicTaskFunction @ NotebookWrite[
System`NotebookLocationSpecifier[ boxObject, "Before" ],
write,
None,
AutoScroll -> False
]