AA-521 EntryPoint support for eip-7702 (eth-infinitism#529)

Author: drortirosh

.solcover.js

@@ -1,8 +1,8 @@
 module.exports = {
   skipFiles: [
     "test",
-    "samples/bls/lib",
-    "utils/Exec.sol"
+    "utils/Exec.sol",
+    "samples"
   ],
   configureYulOptimizer: true,
 };

contracts/core/Eip7702Support.sol

@@ -0,0 +1,67 @@
+pragma solidity ^0.8;
+// SPDX-License-Identifier: MIT
+// solhint-disable no-inline-assembly
+
+import "../interfaces/PackedUserOperation.sol";
+import "../core/UserOperationLib.sol";
+
+library Eip7702Support {
+
+    // EIP-7702 code prefix before delegate address.
+    bytes3 internal constant EIP7702_PREFIX = 0xef0100;
+
+    // EIP-7702 initCode marker, to specify this account is EIP-7702.
+    bytes2 internal constant INITCODE_EIP7702_MARKER = 0x7702;
+
+    using UserOperationLib for PackedUserOperation;
+
+    //get alternate InitCodeHash (just for UserOp hash) when using EIP-7702
+    function _getEip7702InitCodeHashOverride(PackedUserOperation calldata userOp) internal view returns (bytes32) {
+        bytes calldata initCode = userOp.initCode;
+        if (!_isEip7702InitCode(initCode)) {
+            return 0;
+        }
+        address delegate = _getEip7702Delegate(userOp.getSender());
+        if (initCode.length <= 20)
+            return keccak256(abi.encodePacked(delegate));
+        else
+            return keccak256(abi.encodePacked(delegate, initCode[20 :]));
+    }
+
+    // check if this initCode is EIP-7702: starts with INITCODE_EIP7702_MARKER.
+    function _isEip7702InitCode(bytes calldata initCode) internal pure returns (bool) {
+
+        if (initCode.length < 2) {
+            return false;
+        }
+        bytes20 initCodeStart;
+        // non-empty calldata bytes are always zero-padded to 32-bytes, so can be safely casted to "bytes20"
+        assembly ("memory-safe") {
+            initCodeStart := calldataload(initCode.offset)
+        }
+        // make sure first 20 bytes of initCode are "0x7702" (padded with zeros)
+        return initCodeStart == bytes20(INITCODE_EIP7702_MARKER);
+    }
+
+    /**
+     * get the EIP-7702 delegate from contract code.
+     * must only be used if _isEip7702InitCode(initCode) is true.
+     */
+    function _getEip7702Delegate(address sender) internal view returns (address) {
+
+        bytes32 senderCode;
+
+        assembly ("memory-safe") {
+            extcodecopy(sender, 0, 0, 23)
+            senderCode := mload(0)
+        }
+        // To be a valid EIP-7702 delegate, the first 3 bytes are EIP7702_PREFIX
+        // followed by the delegate address
+        if (bytes3(senderCode) != EIP7702_PREFIX) {
+            // instead of just "not an EIP-7702 delegate", if some info.
+            require(sender.code.length > 0, "sender has no code");
+            revert("not an EIP-7702 delegate");
+        }
+        return address(bytes20(senderCode << 24));
+    }
+}

contracts/core/EntryPoint.sol

@@ -14,6 +14,7 @@ import "./NonceManager.sol";
 import "./SenderCreator.sol";
 import "./StakeManager.sol";
 import "./UserOperationLib.sol";
+import "./Eip7702Support.sol";
 
 import "@openzeppelin/contracts/utils/ReentrancyGuardTransient.sol";
 import "@openzeppelin/contracts/utils/introspection/ERC165.sol";
@@ -381,8 +382,9 @@ contract EntryPoint is IEntryPoint, StakeManager, NonceManager, ReentrancyGuardT
     function getUserOpHash(
         PackedUserOperation calldata userOp
     ) public view returns (bytes32) {
+        bytes32 overrideInitCodeHash = Eip7702Support._getEip7702InitCodeHashOverride(userOp);
         return
-            MessageHashUtils.toTypedDataHash(getDomainSeparatorV4(), userOp.hash());
+            MessageHashUtils.toTypedDataHash(getDomainSeparatorV4(), userOp.hash(overrideInitCodeHash));
     }
 
     /**
@@ -444,6 +446,13 @@ contract EntryPoint is IEntryPoint, StakeManager, NonceManager, ReentrancyGuardT
     ) internal {
         if (initCode.length != 0) {
             address sender = opInfo.mUserOp.sender;
+            if ( Eip7702Support._isEip7702InitCode(initCode) ) {
+                if (initCode.length>20 ) {
+                    //already validated it is an EIP-7702 delegate (and hence, already has code)
+                    senderCreator().initEip7702Sender(sender, initCode[20:]);
+                }
+                return;
+            }
             if (sender.code.length != 0)
                 revert FailedOp(opIndex, "AA10 sender already constructed");
             address sender1 = senderCreator().createSender{

contracts/core/EntryPointSimulations.sol

@@ -215,4 +215,7 @@ contract EntryPointSimulations is EntryPoint, IEntryPointSimulations {
         return __domainSeparatorV4;
     }
 
+    function supportsInterface(bytes4) public view virtual override returns (bool) {
+        return false;
+    }
 }

contracts/core/SenderCreator.sol

@@ -1,7 +1,11 @@
 // SPDX-License-Identifier: GPL-3.0
 pragma solidity ^0.8.23;
+/* solhint-disable avoid-low-level-calls */
+/* solhint-disable no-inline-assembly */
 
 import "../interfaces/ISenderCreator.sol";
+import "../interfaces/IEntryPoint.sol";
+import "../utils/Exec.sol";
 
 /**
  * Helper contract for EntryPoint, to call userOp.initCode from a "neutral" address,
@@ -14,6 +18,8 @@ contract SenderCreator is ISenderCreator {
         entryPoint = msg.sender;
     }
 
+    uint256 private constant REVERT_REASON_MAX_LEN = 2048;
+
     /**
      * Call the "initCode" factory to create and return the sender account address.
      * @param initCode - The initCode value from a UserOp. contains 20 bytes of factory address,
@@ -23,13 +29,11 @@ contract SenderCreator is ISenderCreator {
     function createSender(
         bytes calldata initCode
     ) external returns (address sender) {
-        if (msg.sender != entryPoint) {
-            revert("AA97 should call from EntryPoint");
-        }
-        address factory = address(bytes20(initCode[0:20]));
-        bytes memory initCallData = initCode[20:];
+        require(msg.sender == entryPoint, "AA97 should call from EntryPoint");
+        address factory = address(bytes20(initCode[0 : 20]));
+
+        bytes memory initCallData = initCode[20 :];
         bool success;
-        /* solhint-disable no-inline-assembly */
         assembly ("memory-safe") {
             success := call(
                 gas(),
@@ -40,10 +44,23 @@ contract SenderCreator is ISenderCreator {
                 0,
                 32
             )
-            sender := mload(0)
+            if success {
+                sender := mload(0)
+            }
         }
+    }
+
+    // use initCallData to initialize an EIP-7702 account
+    // caller (EntryPoint) already verified it is an EIP-7702 account.
+    function initEip7702Sender(
+        address sender,
+        bytes calldata initCallData
+    ) external {
+        require(msg.sender == entryPoint, "AA97 should call from EntryPoint");
+        bool success = Exec.call(sender, 0, initCallData, gasleft());
         if (!success) {
-            sender = address(0);
+            bytes memory result = Exec.getReturnData(REVERT_REASON_MAX_LEN);
+            revert IEntryPoint.FailedOpWithRevert(0, "AA13 EIP7702 sender init failed", result);
         }
     }
 }

contracts/core/UserOperationLib.sol

@@ -55,13 +55,15 @@ library UserOperationLib {
     /**
      * Pack the user operation data into bytes for hashing.
      * @param userOp - The user operation data.
+     * @param overrideInitCodeHash - If set, encode this instead of the initCode field in the userOp.
      */
     function encode(
-        PackedUserOperation calldata userOp
+        PackedUserOperation calldata userOp,
+        bytes32 overrideInitCodeHash
     ) internal pure returns (bytes memory ret) {
         address sender = getSender(userOp);
         uint256 nonce = userOp.nonce;
-        bytes32 hashInitCode = calldataKeccak(userOp.initCode);
+        bytes32 hashInitCode = overrideInitCodeHash != 0 ? overrideInitCodeHash : calldataKeccak(userOp.initCode);
         bytes32 hashCallData = calldataKeccak(userOp.callData);
         bytes32 accountGasLimits = userOp.accountGasLimits;
         uint256 preVerificationGas = userOp.preVerificationGas;
@@ -136,10 +138,12 @@ library UserOperationLib {
     /**
      * Hash the user operation data.
      * @param userOp - The user operation data.
+     * @param overrideInitCodeHash - If set, the initCode hash will be replaced with this value just for UserOp hashing.
      */
     function hash(
-        PackedUserOperation calldata userOp
+        PackedUserOperation calldata userOp,
+        bytes32 overrideInitCodeHash
     ) internal pure returns (bytes32) {
-        return keccak256(encode(userOp));
+        return keccak256(encode(userOp, overrideInitCodeHash));
     }
 }

contracts/interfaces/ISenderCreator.sol

@@ -8,4 +8,7 @@ interface ISenderCreator {
      * @return sender Address of the newly created sender contract.
      */
     function createSender(bytes calldata initCode) external returns (address sender);
+
+    // call initCode to initialize an EIP-7702 account
+    function initEip7702Sender(address sender, bytes calldata initCode) external;
 }

contracts/test/TestEip7702DelegateAccount.sol

@@ -0,0 +1,53 @@
+pragma solidity ^0.8.23;
+// SPDX-License-Identifier: MIT
+import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
+import "../core/BaseAccount.sol";
+import "../core/Eip7702Support.sol";
+
+contract TestEip7702DelegateAccount is BaseAccount {
+
+    IEntryPoint private immutable _entryPoint;
+    bool public testInitCalled;
+
+    constructor(IEntryPoint anEntryPoint) {
+        _entryPoint = anEntryPoint;
+    }
+
+    function testInit() public {
+        testInitCalled = true;
+    }
+
+    function entryPoint() public view override virtual returns (IEntryPoint) {
+        return _entryPoint;
+    }
+
+    // Require the function call went through EntryPoint or owner
+    function _requireFromEntryPointOrOwner() internal view {
+        require(msg.sender == address(this) || msg.sender == address(entryPoint()), "account: not Owner or EntryPoint");
+    }
+
+    /**
+     * execute a transaction (called directly from owner, or by entryPoint)
+     * @param dest destination address to call
+     * @param value the value to pass in this call
+     * @param func the calldata to pass in this call
+     */
+    function execute(address dest, uint256 value, bytes calldata func) external {
+        _requireFromEntryPointOrOwner();
+        (bool success,) = dest.call{value: value}(func);
+        require(success, "call failed");
+    }
+
+    function _validateSignature(
+        PackedUserOperation calldata userOp,
+        bytes32 userOpHash
+    ) internal virtual override returns (uint256 validationData) {
+        if (userOp.initCode.length > 20) {
+            require(testInitCalled, "testInit not called");
+        }
+        if (ECDSA.recover(userOpHash, userOp.signature) == address(this)) {
+            return 0;
+        }
+        return 1;
+    }
+}

contracts/test/TestUtil.sol

@@ -2,13 +2,16 @@
 pragma solidity ^0.8.23;
 
 import "../interfaces/PackedUserOperation.sol";
-import "../core/UserOperationLib.sol";
+import "../core/Eip7702Support.sol";
 
 contract TestUtil {
     using UserOperationLib for PackedUserOperation;
 
     function encodeUserOp(PackedUserOperation calldata op) external pure returns (bytes memory){
-        return op.encode();
+        return op.encode(0);
     }
 
+    function isEip7702InitCode(bytes calldata initCode) external pure returns (bool) {
+        return Eip7702Support._isEip7702InitCode(initCode);
+    }
 }

reports/gas-checker.txt

@@ -12,36 +12,36 @@
 ║                                │       │               │     (delta for │        (compared to ║
 ║                                │       │               │    one UserOp) │     account.exec()) ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple                         │     1 │         77468 │                │                     ║
+║ simple                         │     1 │         77824 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple - diff from previous    │     2 │               │          41604 │               12345 ║
+║ simple - diff from previous    │     2 │               │          41996 │               12737 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple                         │    10 │        452160 │                │                     ║
+║ simple                         │    10 │        455792 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple - diff from previous    │    11 │               │          41677 │               12418 ║
+║ simple - diff from previous    │    11 │               │          42033 │               12774 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple paymaster               │     1 │         83307 │                │                     ║
+║ simple paymaster               │     1 │         83675 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple paymaster with diff     │     2 │               │          40156 │               10897 ║
+║ simple paymaster with diff     │     2 │               │          40524 │               11265 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple paymaster               │    10 │        444914 │                │                     ║
+║ simple paymaster               │    10 │        448582 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ simple paymaster with diff     │    11 │               │          40177 │               10918 ║
+║ simple paymaster with diff     │    11 │               │          40593 │               11334 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ big tx 5k                      │     1 │        167233 │                │                     ║
+║ big tx 5k                      │     1 │        167613 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ big tx - diff from previous    │     2 │               │         130871 │               16169 ║
+║ big tx - diff from previous    │     2 │               │         131215 │               16513 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ big tx 5k                      │    10 │       1345038 │                │                     ║
+║ big tx 5k                      │    10 │       1348706 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ big tx - diff from previous    │    11 │               │         130896 │               16194 ║
+║ big tx - diff from previous    │    11 │               │         131228 │               16526 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ paymaster+postOp               │     1 │         84690 │                │                     ║
+║ paymaster+postOp               │     1 │         85070 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ paymaster+postOp with diff     │     2 │               │          41574 │               12315 ║
+║ paymaster+postOp with diff     │     2 │               │          41930 │               12671 ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ paymaster+postOp               │    10 │        458869 │                │                     ║
+║ paymaster+postOp               │    10 │        462525 │                │                     ║
 ╟────────────────────────────────┼───────┼───────────────┼────────────────┼─────────────────────╢
-║ paymaster+postOp with diff     │    11 │               │          41577 │               12318 ║
+║ paymaster+postOp with diff     │    11 │               │          41993 │               12734 ║
 ╚════════════════════════════════╧═══════╧═══════════════╧════════════════╧═════════════════════╝