Tutorial_08_DaysAndDates.ipynb

{
 "cells": [
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "# Days and Dates\n",
    "\n",
    "This notebook *(a)* introduces the `Date` type; *(b)* discusses how to convert from other date formats (for instance, Excel and Matlab) to Julia dates; *(c)* and how to do date arithmetics."
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "## Load Packages and Extra Functions"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 1,
   "metadata": {},
   "outputs": [],
   "source": [
    "using Printf, Dates\n",
    "\n",
    "include(\"src/printmat.jl\");"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "## Building a Calendar"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 2,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "         date  day of week\n",
      "   2014-01-31        5    \n",
      "   2014-02-28        5    \n",
      "   2014-03-31        1    \n",
      "   2014-04-30        3    \n",
      "   2014-05-31        6    \n",
      "   2014-06-30        1    \n",
      "   2014-07-31        4    \n",
      "   2014-08-31        7    \n",
      "   2014-09-30        2    \n",
      "   2014-10-31        5    \n",
      "   2014-11-30        7    \n",
      "   2014-12-31        3    \n",
      "\n"
     ]
    }
   ],
   "source": [
    "dNb = Date(2014,1,31):Month(1):Date(2014,12,31)    #build a monthly calendar\n",
    "\n",
    "printmat([dNb dayofweek.(dNb)];colNames=[\"date\",\"day of week\"],width=13)"
   ]
  },
  {
   "attachments": {},
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "# Converting from Other Date Formats\n",
    "\n",
    "## Converting from yyyymmdd\n",
    "\n",
    "Background: financial data is often downloaded as CSV files (eg. from finance.yahoo), where the date may look like 20160331. The next cell shows a simple way to create a Julia Date."
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 3,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "Original date   Julia date\n",
      " 20160331       2016-03-31\n",
      " 20160401       2016-04-01\n",
      "\n"
     ]
    }
   ],
   "source": [
    "csvDate = [20160331;20160401]                #two dates\n",
    "\n",
    "jlDate = Date.(string.(csvDate),\"yyyymmdd\")  #convert to string and then Julia Date\n",
    "\n",
    "printmat(csvDate,jlDate;colNames=[\"Original date\",\"Julia date\"],width=13)"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "## Converting from DateTime (Excel) to Date\n",
    "\n",
    "Background: importing xls sheets with XLSX.jl gives an `Any` vector, if the sheet contains a column with dates. If needed, this can be converted to a vector of Dates."
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 4,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "Vector{Any}\n",
      "Vector{Date}\n"
     ]
    }
   ],
   "source": [
    "xlsDate = Any[Date(2016,3,31);Date(2016,4,1)]     #to be converted\n",
    "\n",
    "jlDate  = Date.(xlsDate)                          #convert to vector of Dates\n",
    "println(typeof(xlsDate),\"\\n\",typeof(jlDate))"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "## Converting from Matlab's datenum\n",
    "\n",
    "Background: in Matlab `datenum(2016,3,31)` gives 736420.0. In contrast, in Julia (which follows the ISO 8601 standard), `Dates.value(Date(2016,3,31))` gives 736054, which is 366 less, and it is an integer. A conversion is therefore required."
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 5,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "       Matlab        Julia\n",
      "   736420.000   2016-03-31\n",
      "   736421.000   2016-04-01\n",
      "\n"
     ]
    }
   ],
   "source": [
    "dNml = [736420.0;736421.0]            #to be converted, 2016-03-31;2016-04-01\n",
    "\n",
    "jlDate = Date.(rata2datetime.(round.(Int,dNml) .- 366))  #to Julia Date from matlab datenum\n",
    "\n",
    "#mlDate = Dates.datetime2rata.(jlDate)[:,:] .+ 366.0     #to matlab datenum from Julia Date\n",
    "\n",
    "printmat([dNml jlDate];colNames=[\"Matlab\",\"Julia\"],width=13)"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "# Time Arithmetics\n",
    "\n",
    "You can add and subtract Dates from each other."
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 6,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "difference between two dates: 30 days\n",
      "as a fraction of the year:      0.082\n"
     ]
    }
   ],
   "source": [
    "d1 = Date(2016,3,31)\n",
    "d2 = Date(2016,4,30)\n",
    "\n",
    "dif    = d2 - d1                           #count the number of days between d2 and d1\n",
    "difRel = Dates.value(dif)/daysinyear(d1)   #Dates.value() is the datenumber, needs prefix Dates\n",
    "\n",
    "println(\"difference between two dates: \",dif)\n",
    "printlnPs(\"as a fraction of the year: \",difRel)"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 7,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "d1 and one month later: 2016-03-31 2016-04-30\n"
     ]
    }
   ],
   "source": [
    "d3 = d1 + Month(1)          #one month after d1\n",
    "\n",
    "println(\"d1 and one month later: \",d1,\" \",d3)"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "# Looking up Day of the Week and More"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 8,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "day of the week of date: 2016-03-31 4\n",
      "day of the year of date: 2016-03-31 91\n",
      "\n",
      "Splitting up a date: 2016 3 31\n"
     ]
    }
   ],
   "source": [
    "println(\"day of the week of date: \",d1,\" \",dayofweek(d1))\n",
    "println(\"day of the year of date: \",d1,\" \",dayofyear(d1))\n",
    "\n",
    "(y,m,d)= yearmonthday(d1)            #splitting up a date\n",
    "println(\"\\nSplitting up a date: \",y,\" \",m,\" \",d)"
   ]
  },
  {
   "cell_type": "markdown",
   "metadata": {},
   "source": [
    "# Printing a Date\n",
    "\n",
    "with your own formatting (see the manual for many other formatting options)"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": 9,
   "metadata": {},
   "outputs": [
    {
     "name": "stdout",
     "output_type": "stream",
     "text": [
      "31 Mar 2016\n",
      "31-03-2016\n"
     ]
    }
   ],
   "source": [
    "println(Dates.format(d1,\"d u yyyy\"))                #needs prefix Dates\n",
    "println(Dates.format(d1,\"dd-mm-yyyy\"))"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "metadata": {},
   "outputs": [],
   "source": []
  }
 ],
 "metadata": {
  "@webio": {
   "lastCommId": null,
   "lastKernelId": null
  },
  "anaconda-cloud": {},
  "kernelspec": {
   "display_name": "Julia 1.11.1",
   "language": "julia",
   "name": "julia-1.11"
  },
  "language_info": {
   "file_extension": ".jl",
   "mimetype": "application/julia",
   "name": "julia",
   "version": "1.11.1"
  }
 },
 "nbformat": 4,
 "nbformat_minor": 4
}