Jenkinsfile-security

def version = "9.1"
def slackResponse = null

def errors = []

def changeUrl = env.CHANGE_URL



// Check vulns in dependencies on repo branches
def failedBuild = false

pipeline {
    agent none
    triggers { cron('@daily') }

    stages {
        stage('deps-webapp') {
            when { not { changeRequest() } }
            agent {
                dockerfile {
                    label 'generic-docker'
                    filename 'webapp/sources/Dockerfile'
                    // and share maven cache
                    args '-u 0:0 -v /srv/cache/maven:/root/.m2'
                }
            }
            environment {
                NVD_API_KEY = credentials('NVD_API_KEY')
            }
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    dir('webapp/sources') {
                        sh script: 'mvn --batch-mode -DnvdApiKey=$NVD_API_KEY -DfailBuildOnCVSS=7 -DcveValidForHours=48 -DsuppressionFiles=dependency-check-suppression.xml -DossindexAnalyzerEnabled=false org.owasp:dependency-check-maven:aggregate', label: "check webapp dependencies"
                        sh script: 'mvn --batch-mode license:aggregate-third-party-report', label: 'list webapp dependencies'
                    }
                }
            }
            post {

                always {
                    archiveArtifacts artifacts: 'webapp/sources/target/dependency-check-report.html, webapp/sources/target/site/aggregate-third-party-report.html'
                }

                failure {
                    script {
                        errors.add("webapp")
                        failedBuild = true
                        slackResponse = updateSlack(errors, slackResponse, version, changeUrl, false)
                        slackSend(channel: slackResponse.threadId, message: "Dependency check error on webapp - <${currentBuild.absoluteUrl}console|Console>", color: "#CC3421")
                    }
                }
            }
        }

        stage('deps-npm') {
            when { not { changeRequest() } }
            agent {
                dockerfile {
                    label 'generic-docker'
                    filename 'webapp/sources/Dockerfile'
                    additionalBuildArgs "--build-arg USER_ID=${JENKINS_UID}"
                    // and share maven cache
                    args '-u 0:0 -v /srv/cache/maven:/root/.m2'
                }
            }
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    dir('webapp/sources/rudder/rudder-web/src/main/') {
                        sh script: 'npm_config_loglevel=error npm ci --no-audit', label: "install dependencies"
                        sh script: 'npx better-npm-audit audit --level high', label: "check npm dependencies"
                    }
                }
            }
            post {
                failure {
                    script {
                        errors.add("npm")
                        failedBuild = true
                        slackResponse = updateSlack(errors, slackResponse, version, changeUrl, false)
                        slackSend(channel: slackResponse.threadId, message: "Dependency check error on npm - <${currentBuild.absoluteUrl}console|Console>", color: "#CC3421")
                    }
                }
            }
        }
        stage('deps-rust') {
            when { not { changeRequest() } }
            agent {
                dockerfile {
                    label 'generic-docker'
                    filename 'relay/sources/relayd/Dockerfile'
                    // mount cache
                    args '-u 0:0 -v /srv/cache/cargo:/usr/local/cargo/registry'
                }
            }
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    sh script: 'mkdir -p target', label: 'create target directory'
                    sh script: 'cargo deny check', label: 'check relayd dependencies'
                    sh script: 'cargo deny list > target/rust-dependencies.txt', label: 'list rust dependencies'
                }
            }
            post {
                failure {
                    script {
                        errors.add("rust")
                        failedBuild = true
                        slackResponse = updateSlack(errors, slackResponse, version, changeUrl, false)
                        slackSend(channel: slackResponse.threadId, message: "Dependency check error on rust projects - <${currentBuild.absoluteUrl}console|Console>", color: "#CC3421")
                    }
                }
                always {
                    archiveArtifacts artifacts: 'target/*-dependencies.txt'
                }
            }
        }
        stage('End') {
            steps {
                script {
                    updateSlack(errors, slackResponse, version, changeUrl, true)
                    if (failedBuild) {
                        error 'End of build'
                    } else {
                        echo 'End of build '
                    }
                }
            }
        }
    }
}

def updateSlack(errors, slackResponse, version, changeUrl, isEnded) {
  def msg ="*${version} - rudder dependency check* - <"+currentBuild.absoluteUrl+"|Link>"

  if (changeUrl == null) {

      def fixed = currentBuild.resultIsBetterOrEqualTo("SUCCESS") && currentBuild.previousBuild.resultIsWorseOrEqualTo("UNSTABLE")
      if (errors.isEmpty() && isEnded && fixed) {
        msg +=  " => No security issues found! :white_check_mark:"
        def color = "good"
        slackSend(channel: "ci-security", message: msg, color: color)
      }


      if (! errors.isEmpty()) {
          msg += "\n*Errors* :x: ("+errors.size()+")\n  • " + errors.join("\n  • ")
          def color = "#CC3421"
          if (slackResponse == null) {
            slackResponse = slackSend(channel: "ci-security", message: msg, color: color)
          }
          slackSend(channel: slackResponse.channelId, message: msg, timestamp: slackResponse.ts, color: color)
      }
      return slackResponse
  }
}