build.gradle

plugins {
	id 'java'
	id 'java-library'
	id 'maven-publish'
	id 'checkstyle'
	id 'com.diffplug.spotless' version '6.12.0'
	id 'com.github.johnrengelman.shadow' version '7.1.2'
}

def ENV = System.getenv()

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

checkstyle {
	configFile = project.rootProject.file('checkstyle.xml')
	toolVersion = project.checkstyle_tool_version
}

spotless {
	java {
		licenseHeaderFile(rootProject.file('HEADER'))
	}
}

repositories {
	mavenCentral()
	maven {
		name = 'FlexVer'
		url = 'https://repo.sleeping.town/'
	}
}

configurations {
	include

	implementation {
		extendsFrom include
	}
}

dependencies {
	include "com.unascribed:flexver-java:${project.flexver_version}"

	testCompileOnly "org.jetbrains:annotations:${project.jetbrains_annotations_version}"
	testImplementation "org.junit.jupiter:junit-jupiter:${project.junit_jupiter_version}"
}

test {
	useJUnitPlatform()
}

java {
	withSourcesJar()
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = 'UTF-8'

	if (JavaVersion.current().isJava9Compatible()) {
		it.options.release = 8
	}
}

shadowJar {
	// Has stupid defaults, make our own
	enabled = false
}

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

task fatJar(type: ShadowJar) {
	from sourceSets.main.output

	manifest {
		attributes('Automatic-Module-Name': "${project.group}.${archivesBaseName}")
	}

	archiveClassifier = 'fat'
	configurations = [project.configurations.include]

	relocate 'com.unascribed.flexver', 'net.fabricmc.semver.impl.lib.flexver'

	outputs.upToDateWhen { false }
}

build.dependsOn(fatJar)

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact(jar)
			artifact(fatJar)
			artifact(sourcesJar)
		}
	}

	repositories {
		if (ENV.MAVEN_URL) {
			maven {
				name 'fabric'
				url ENV.MAVEN_URL
				credentials {
					username ENV.MAVEN_USERNAME
					password ENV.MAVEN_PASSWORD
				}
			}
		}
	}
}