Merge pull request rust-lang#16 from richo/playpen-support

Add rudimentary support for the playpen

Author: brson

autoload/rust.vim

@@ -359,6 +359,56 @@ function! s:system(pwd, cmd)
 	return system(cmd)
 endfunction
 
+" Playpen Support {{{1
+" Parts of gist.vim by Yasuhiro Matsumoto <[email protected]> reused
+" gist.vim available under the BSD license, available at
+" http://github.com/mattn/gist-vim
+function! s:has_webapi()
+  if !exists("*webapi#http#post")
+    try
+      call webapi#http#post()
+    catch
+    endtry
+  endif
+  return exists("*webapi#http#post")
+endfunction
+
+function! rust#Play(count, line1, line2, ...) abort
+  redraw
+
+  let l:rust_playpen_url = get(g:, 'rust_playpen_url', 'https://play.rust-lang.org/')
+  let l:rust_shortener_url = get(g:, 'rust_shortener_url', 'https://is.gd/')
+
+  if !s:has_webapi()
+    echohl ErrorMsg | echomsg ':RustPlay depends on webapi.vim (https://github.com/mattn/webapi-vim)' | echohl None
+    return
+  endif
+
+  let bufname = bufname('%')
+  if a:count < 1
+    let content = join(getline(a:line1, a:line2), "\n")
+  else
+    let save_regcont = @"
+    let save_regtype = getregtype('"')
+    silent! normal! gvy
+    let content = @"
+    call setreg('"', save_regcont, save_regtype)
+  endif
+
+  let body = l:rust_playpen_url."?code=".webapi#http#encodeURI(content)
+
+  if strlen(body) > 5000
+    echohl ErrorMsg | echomsg 'Buffer too large, max 5000 encoded characters ('.strlen(body).')' | echohl None
+    return
+  endif
+
+  let payload = "format=simple&url=".webapi#http#encodeURI(body)
+  let res = webapi#http#post(l:rust_shortener_url.'create.php', payload, {})
+  let url = res.content
+
+  redraw | echomsg 'Done: '.url
+endfunction
+
 " }}}1
 
 " vim: set noet sw=4 ts=4:

doc/rust.txt

@@ -95,6 +95,19 @@ g:cargo_manifest_name~
 	    let g:cargo_manifest_name = 'Cargo.toml'
 <
 
+                                                          *g:rust_playpen_url*
+g:rust_playpen_url~
+	Set this option to override the url for the playpen to use: >
+	    let g:rust_playpen_url = 'https://play.rust-lang.org/'
+<
+
+                                                        *g:rust_shortener_url*
+g:rust_shortener_url~
+	Set this option to override the url for the url shortener: >
+	    let g:rust_shortener_url = 'https://is.gd/'
+<
+
+
 ==============================================================================
 COMMANDS                                                       *rust-commands*
 
@@ -157,6 +170,20 @@ COMMANDS                                                       *rust-commands*
 		If |g:rustc_path| is defined, it is used as the path to rustc.
 		Otherwise it is assumed rustc can be found in $PATH.
 
+:RustPlay                                                          *:RustPlay*
+		This command will only work if you have web-api.vim installed
+		(available at https://github.com/mattn/webapi-vim).  It sends the
+		current selection, or if nothing is selected, the entirety of the
+		current buffer to the Rust playpen, and emits a message with the
+		shortened URL to the playpen.
+
+		|g:rust_playpen_url| is the base URL to the playpen, by default
+		"https://play.rust-lang.org/".
+
+		|g:rust_shortener_url| is the base url for the shorterner, by
+		default "https://is.gd/"
+
+
 ==============================================================================
 MAPPINGS                                                       *rust-mappings*
 

ftplugin/rust.vim

@@ -106,6 +106,9 @@ command! -nargs=* -buffer RustEmitIr call rust#Emit("llvm-ir", <q-args>)
 " See |:RustEmitAsm| for docs
 command! -nargs=* -buffer RustEmitAsm call rust#Emit("asm", <q-args>)
 
+" See |:RustPlay| for docs
+command! -range=% RustPlay :call rust#Play(<count>, <line1>, <line2>, <f-args>)
+
 " Mappings {{{1
 
 " Bind ⌘R in MacVim to :RustRun
@@ -142,6 +145,7 @@ let b:undo_ftplugin = "
 		\|delcommand RustExpand
 		\|delcommand RustEmitIr
 		\|delcommand RustEmitAsm
+		\|delcommand RustPlay
 		\|nunmap <buffer> <D-r>
 		\|nunmap <buffer> <D-R>
 		\|nunmap <buffer> [[