build.gradle

import com.vanniktech.maven.publish.SonatypeHost

plugins {
    id('java-library')
    id('com.github.johnrengelman.shadow') version('8.1.1')
    id('com.vanniktech.maven.publish') version('0.29.0')
}

group('eu.koboo')
version('3.1.10')

repositories {
    mavenCentral()
}

dependencies {
    // The driver itself
    api("org.mongodb:mongodb-driver-sync:$mongoDriverVersion")
    testImplementation("org.mongodb:mongodb-driver-sync:$mongoDriverVersion")

    // Eliminate boilerplate code
    compileOnly("org.projectlombok:lombok:$lombokVersion")
    annotationProcessor("org.projectlombok:lombok:$lombokVersion")
    testImplementation("org.projectlombok:lombok:$lombokVersion")
    testAnnotationProcessor("org.projectlombok:lombok:$lombokVersion")

    // Test-Suite runtime
    testImplementation("org.junit.jupiter:junit-jupiter-engine:$jupiterVersion")

    // SLF4j logger for test-suite
    testImplementation("org.slf4j:slf4j-jdk14:$slf4jVersion")
}

test {
    useJUnitPlatform()
}

compileJava {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    options.fork = true
    options.encoding = 'UTF-8'
    options.release.set(11)
}

tasks.register('sourcesJar', Jar) {
    from sourceSets.main.allJava
    archiveClassifier.set('sources')
}
tasks.register('javadocJar', Jar) {
    from javadoc.destinationDir
    archiveClassifier.set('javadoc')
}

artifacts {
    archives(shadowJar)
    archives(sourcesJar)
    archives(javadocJar)
}

mavenPublishing {
    coordinates(project.group.toString(), "${project.name}", project.version.toString())

    pom {
        name = 'En2do'
        description = 'MongoDB entity to document wrapper'
        inceptionYear = '2022'
        url = 'https://github.com/Koboo/en2do'
        licenses {
            license {
                name = 'The Apache License, Version 2.0'
                url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                distribution = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
            }
        }
        developers {
            developer {
                id = 'koboo'
                name = 'Koboo'
                email = 'admin@koboo.eu'
                url = 'https://github.com/Koboo/'
            }
        }
        scm {
            url = 'https://github.com/Koboo/en2do'
            connection = 'scm:git:https://github.com/Koboo/en2do'
            developerConnection = 'scm:git:https://github.com/Koboo/en2do'
        }
    }

    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
    signAllPublications()
}