build.gradle

import org.springframework.boot.gradle.plugin.SpringBootPlugin

plugins {
    id 'org.springframework.boot' version '3.4.3' apply false
    id 'io.spring.dependency-management' version '1.1.7' apply false
    id 'com.google.cloud.tools.jib' version '3.4.3' apply false
    id "org.sonarqube" version "6.0.1.5171" apply false
    id 'idea'
    id "org.openapi.generator" version "7.12.0" apply false
    id 'java'
    id 'com.gorylenko.gradle-git-properties' version '2.5.0'
    id 'jacoco'
    id 'com.diffplug.spotless' version '7.0.2' apply false
}

repositories {
    maven { url 'https://broadinstitute.jfrog.io/artifactory/maven-central' }
    mavenCentral()
}

subprojects {
    group = 'org.databiosphere'
    version = '0.33.5-SNAPSHOT'

    apply plugin: 'idea'
    apply plugin: 'java'
    apply plugin: 'jvm-test-suite'

    ext {
        artifactGroup = "${group}.${rootProject.name}"
    }

    apply plugin: 'io.spring.dependency-management'

    dependencyManagement {
        imports {
            mavenBom(SpringBootPlugin.BOM_COORDINATES)
        }
        dependencies {
            // no dependencyManagement overrides at this time
        }
    }
}

idea.project.jdkName = '17'

tasks.named('test') {
    useJUnitPlatform()
    testLogging {
        events = ["passed", "failed", "skipped", "started"]
        exceptionFormat = "full"
    }
}

// to avoid prompts in Gradle build scans
if (hasProperty("buildScan")) {
    buildScan {
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
    }
}